Получить последний день месяца в SQL

Мне нужно получить последний день месяца, заданный как дата в SQL. Если у меня первый день месяца, я могу сделать что-то вроде этого:

DATEADD(DAY, DATEADD(MONTH,'2009-05-01',1), -1)

но кто-нибудь знает, как обобщить его, поэтому я могу найти последний день месяца для любой заданной даты?

39
sql sql-server tsql

19 ответов

вот моя версия. Никаких манипуляций со строками или кастинга не требуется, только один вызов каждого DATEADD, YEAR и MONTH функции:

DECLARE @test DATETIME
SET @test = GETDATE()  -- or any other date

SELECT DATEADD(month, ((YEAR(@test) - 1900) * 12) + MONTH(@test), -1)
51

из SQL Server 2012 вы можете использовать функция eomonth

46

вы можете получить дни в дате, используя день(): 

dateadd(day, -1, dateadd(month, 1, dateadd(day, 1 - day(date), date)))
12

Я знаю, это старый вопрос, но вот еще одно решение, которое работает для меня 

SET @dtDate = "your date"
DATEADD(s,-1,DATEADD(mm, DATEDIFF(m,0,@dtDate)+1,0))

и если кто-то ищет разные примеры, вот ссылка http://blog.sqlauthority.com/2007/08/18/sql-server-find-last-day-of-any-month-current-previous-next/

Я надеюсь, что это поможет кому-то еще. сайте StackOverflow скалы!!!!

3

на основании заявления: 

SELECT DATEADD(MONTH, 1, @x)           -- Add a month to the supplied date @x

и

SELECT DATEADD(DAY,  0 - DAY(@x), @x)  -- Get last day of month previous to the supplied date @x

как насчет добавления месяца к дате @x, а затем извлечения последнего дня месяца, предшествующего этому (т. е. последний день месяца поставляемой даты)

DECLARE @x  DATE = '20-Feb-2012' 
SELECT DAY(DATEADD(DAY,  0 - DAY(DATEADD(MONTH, 1, @x)), DATEADD(MONTH, 1, @x)))

Примечание: это был тест с использованием SQL Server 2008 R2

3

просто расширьте свою формулу немного:

dateadd(day, -1,
    dateadd(month, 1,
        cast(month('5/15/2009') as varchar(2)) + 
        '/1/' + 
        cast(year('5/15/2009') as varchar(4)))
2

для SQL server 2012 или выше используйте EOMONTH, чтобы получить последнюю дату месяца

SQL-запрос для отображения даты окончания текущего месяца

DECLARE @currentDate DATE = GETDATE()
SELECT EOMONTH (@currentDate) AS CurrentMonthED

SQL-запрос для отображения даты окончания следующего месяца

DECLARE @currentDate DATE = GETDATE()
SELECT EOMONTH (@currentDate, 1 ) AS NextMonthED
2

используя SQL Server, вот еще один способ найти последний день месяца:

SELECT DATEADD(MONTH,1,GETDATE())- day(DATEADD(MONTH,1,GETDATE()))
1

WinSQL, чтобы получить последний день прошлого месяца (i.e сегодня 2017-02-09, возвращает 2017-01-31: Выберите dateadd (day, - day (today ()), today ())

1

пытаюсь выполнить следующий запрос, он даст вам все, что вы хотите :)

Declare @a date =dateadd(mm, Datediff(mm,0,getdate()),0)
Print('First day of Current Month:')
Print(@a)
Print('')
set @a = dateadd(mm, Datediff(mm,0,getdate())+1,-1)
Print('Last day of Current Month:')
Print(@a)
Print('')

Print('First day of Last Month:')
set @a = dateadd(mm, Datediff(mm,0,getdate())-1,0)
Print(@a)
Print('')

Print('Last day of Last Month:') 
set @a = dateadd(mm, Datediff(mm,0,getdate()),-1)
Print(@a)
Print('')


Print('First day of Current Week:')
set @a = dateadd(ww, Datediff(ww,0,getdate()),0)
Print(@a)
Print('')

Print('Last day of Current Week:')
set @a = dateadd(ww, Datediff(ww,0,getdate())+1,-1)
Print(@a)
Print('')

Print('First day of Last Week:')
set @a =  dateadd(ww, Datediff(ww,0,getdate())-1,0)
Print(@a)
Print('')

Print('Last day of Last Week:')
set @a =  dateadd(ww, Datediff(ww,0,getdate()),-1)
Print(@a)
1

WinSQL: я хотел вернуть все записи за последний месяц:

where DATE01 between dateadd(month,-1,dateadd(day,1,dateadd(day,-day(today()),today()))) and dateadd(day,-day(today()),today())

Это одно и то же:

where month(DATE01) = month(dateadd(month,-1,today())) and year(DATE01) = year(dateadd(month,-1,today()))
1

работает в SQL server

Declare @GivenDate datetime
SET @GivenDate = GETDATE()

Select DATEADD(MM,DATEDIFF(MM, 0, @GivenDate),0) --First day of the month 

Select DATEADD(MM,DATEDIFF(MM, -1, @GivenDate),-1) --Last day of the month
1

мои 2 цента:

select DATEADD(DAY,-1,DATEADD(MONTH,1,DATEADD(day,(0-(DATEPART(dd,'2008-02-12')-1)),'2008-02-12')))

Радж

0

Если вам это нужно часто, оберните его в встроенный TVF, который очень быстрый:

http://sqlblog.com/blogs/alexander_kuznetsov/archive/2009/06/21/calculating-third-wednesday-of-the-month-with-inline-udfs.aspx ,

0

используя sql server 2005, это работает для меня:

select dateadd(dd,-1,dateadd(mm,datediff(mm,0,YOUR_DATE)+1,0))

в принципе, вы получаете количество месяцев с начала (SQL Server) времени для YOUR_DATE. Затем добавьте к нему один, чтобы получить порядковый номер следующего месяца. Затем вы добавляете это количество месяцев к 0, чтобы получить дату, которая является первым днем следующего месяца. Из этого вы вычитаете день, чтобы добраться до последнего дня YOUR_DATE.

0

это работает для меня, используя Microsoft SQL Server 2005:

DATEADD(d,-1,DATEADD(mm, DATEDIFF(m,0,'2009-05-01')+1,0))
0

возьмите некоторую базовую дату, которая является 31-й из некоторого месяца, например "20011231". Тогда используйте
следующая процедура (я привел 3 одинаковых примера ниже, только значение @dt отличается).

declare @dt datetime;

set @dt = '20140312'

SELECT DATEADD(month, DATEDIFF(month, '20011231', @dt), '20011231');



set @dt = '20140208'

SELECT DATEADD(month, DATEDIFF(month, '20011231', @dt), '20011231');



set @dt = '20140405'

SELECT DATEADD(month, DATEDIFF(month, '20011231', @dt), '20011231');
0

Я написал следующую функцию, она работает.

он возвращает тип данных datetime. Ноль часов, минут, секунд, миллисекунд. 

CREATE Function [dbo].[fn_GetLastDate]
(
    @date datetime
)
returns datetime
as
begin

declare @result datetime

 select @result = CHOOSE(month(@date),  
 DATEADD(DAY, 31 -day(@date), @date),
 IIF(YEAR(@date) % 4 = 0, DATEADD(DAY, 29 -day(@date), @date), DATEADD(DAY, 28 -day(@date), @date)), 
 DATEADD(DAY, 31 -day(@date), @date) ,
 DATEADD(DAY, 30 -day(@date), @date), 
 DATEADD(DAY, 31 -day(@date), @date),
 DATEADD(DAY, 30 -day(@date), @date), 
 DATEADD(DAY, 31 -day(@date), @date),
 DATEADD(DAY, 31 -day(@date), @date),
 DATEADD(DAY, 30 -day(@date), @date),
 DATEADD(DAY, 31 -day(@date), @date),
 DATEADD(DAY, 30 -day(@date), @date), 
 DATEADD(DAY, 31 -day(@date), @date))

 return convert(date, @result)

end

очень легко использовать. 2 пример:

select [dbo].[fn_GetLastDate]('2016-02-03 12:34:12')

select [dbo].[fn_GetLastDate](GETDATE())
0

функция LAST_DAY отлично работает для этого.

Edit: на самом деле, как упоминалось в комментариях, это, вероятно, не для всех SQL. Я оставлю сообщение в возможности того, что кто-то ищет ответ MySQL/Oracle, наткнувшись на него.

С справочное руководство mysql:

LAST_DAY(date)

принимает значение даты или времени и возвращает соответствующее значение для последнего дня месяца. Возвращает NULL, если аргумент недействительный.

mysql> SELECT LAST_DAY('2003-02-05');
        -> '2003-02-28'
mysql> SELECT LAST_DAY('2004-02-05');
        -> '2004-02-29'
mysql> SELECT LAST_DAY('2004-01-01 01:01:01');
        -> '2004-01-31'
mysql> SELECT LAST_DAY('2003-03-32');
        -> NULL

LAST_DAY () доступен с MySQL 4.1.1.

-2