800A0401-ожидаемый конец заявления

Я создал .файл vbs для создания папки в Outlook. Я скопировал большую часть сценария прямо из MSDN и получить "ожидаемый конец оператора" код ошибки 800A0401 ответ.

Option Explicit
Dim myNameSpace As Outlook.NameSpace
Dim myFolder As Outlook.Folder
Dim myNewFolder As Outlook.Folder

Set myNameSpace = Application.GetNamespace("MAPI")
Set myFolder = myNameSpace.GetDefaultFolder(olFolderInbox)
Set myNewFolder = myFolder.Folders.Add("Postini")

Wscript.Echo "Folder created"
Wscript.Quit

никогда не создавал .сценарий vbs раньше. Не знаю, что я упускаю.

64-разрядная версия Windows 7 и Outlook 2010. Запуск от имени локального администратора.

11
outlook-2010 vba vbscript

1 ответов

эта ошибка заключается в том, что вы не можете затемнять переменные как что-то конкретное в VBS. Более явно сказано, что оператор " Dim " используется без определения типа переменной в VBScript, потому что все переменные в VBScript автоматически имеют тип Variant. Если вы попытаетесь затемнить переменную как что-либо, она выдаст ошибку.

вместо этого вы хотите:

Dim myNameSpace
Dim myFolder
Dim myNewFolder

кроме того, вы, похоже, только что скопировали некоторые VBA из Outlook и попытались запустить его как VBS.

VBscript не знает, как интерпретировать Application.GetNameSpace("MAPI").

вам также необходимо создать приложение Outlook.

dim myOutlook
set myOUtlook = CreateObject("Outlook.Application")

кроме того, поскольку вы не можете предоставить ссылки в VBS, вы должны использовать позднюю привязку для любых объектов (поэтому я использовал CreateObject.) Так переписать код следующим образом:

Option Explicit
Dim myOutlook
Dim myNameSpace
Dim myFolder
Dim myNewFolder

set myOUtlook = CreateObject("Outlook.Application")
Set myNameSpace = myOutlook.GetNamespace("MAPI")
Set myFolder = myNameSpace.GetDefaultFolder(6) '6 is the value of olFolderInbox
Set myNewFolder = myFolder.Folders.Add("Postini")  
Wscript.Echo "Folder created"
Wscript.Quit
25