Асинхронные загрузки файлов из VBA (Excel)

не уверен, является ли это стандартной процедурой или нет, но я не хотел слишком загромождать свой вопрос, чтобы люди, читающие его, могли понять его лучше.

но я нашел альтернативное решение моего вопроса, которое больше соответствует тому, что я изначально запрашивал. Еще раз спасибо Тиму, когда он поставил меня на правильный путь, и его использование ADODB.Поток-жизненно важная часть моего решения.

Это использует службы Microsoft WinHTTP 5.1 .DLL, которые должны быть включены в windows в той или иной версии, если не легко загрузить.

Я использую следующий код в классе под названием "HTTPRequest"

Option Explicit

Private WithEvents HTTP As WinHttpRequest
Private ADStream As ADODB.Stream
Private HTTPRequest As Boolean
Private I As Double
Private SaveP As String

Sub Main(ByVal URL As String)
HTTP.Open "GET", URL, True
HTTP.send
End Sub

Private Sub Class_Initialize()
Set HTTP = New WinHttpRequest
Set ADStream = New ADODB.Stream
End Sub

Private Sub HTTP_OnError(ByVal ErrorNumber As Long, ByVal ErrorDescription As String)
Debug.Print ErrorNumber
Debug.Print ErrorDescription
End Sub


Private Sub HTTP_OnResponseFinished()
    'Tim's code Starts'
    With ADStream
        .Type = 1
        .Open
        .Write HTTP.responseBody
        .SaveToFile SaveP, 2
        .Close
    End With
    'Tim's code Ends'

HTTPRequest = True
End Sub

Private Sub HTTP_OnResponseStart(ByVal Status As Long, ByVal ContentType As String)
End Sub

Private Sub Class_Terminate()
Set HTTP = Nothing
Set ADStream = Nothing
End Sub

Property Get RequestDone() As Boolean
RequestDone = HTTPRequest
End Property

Property Let SavePath(ByVal SavePath As String)
SaveP = SavePath
End Property

основное различие между этим и тем, что описывал Тим, заключается в том, что WINHTTPRequest имеет свои собственные встроенные события, которые я могу завернуть в один аккуратный маленький класс и повторно использовать везде. Для меня это более элегантное решение, чем вызов XMLHttp, а затем передача его классу, чтобы дождаться его.

имея его, завернутый в класс как будто это означает, что я могу сделать что-то в этом роде..

Dim HTTP(10) As HTTPRequest
Dim URL(2, 10) As String
Dim I As Integer, J As Integer, Z As Integer, X As Integer

    While Not J > I
        For X = 1 To I
            If Not TypeName(HTTP(X)) = "HTTPRequest" And Not URL(2, X) = Empty Then
                Set HTTP(X) = New HTTPRequest
                HTTP(X).SavePath = URL(2, X)
                HTTP(X).Main (URL(1, X))
                Z = Z + 1
            ElseIf TypeName(HTTP(X)) = "HTTPRequest" Then
                If Not HTTP(X).RequestDone Then
                    Exit For
                Else
                    J = J + 1
                    Set HTTP(X) = Nothing
                End If
            End If
        Next
        DoEvents
    Wend 

где я просто перебираю URL () с URL (1,N) - это URL, а URL(2, N) - это место сохранения.

Я признаю, что это, вероятно, может быть немного упрощено, но пока это делает работу за меня. Просто выкидываю свое решение для всех заинтересованных.

@TheFuzzyGiggler: +1: Спасибо за обмен обратно. Я знаю его старый пост, но, возможно, я сделаю кого-то счастливым с этим дополнением к коду TheFuzzyGigglers (работает только в классах):

я добавил два свойства:

Private pCallBack as string
Private pCallingObject as object

Property Let Callback(ByVal CB_Function As String)
 pCallBack = CB_Function
End Property

Property Let CallingObject(set_me As Object)
 Set pCallbackObj = set_me
End Property

'and at the end of HTTP_OnResponseFinished()

CallByName pCallbackObj, pCallback, VbMethod

в моем классе у меня есть

 Private EntryCollection As New Collection

 Private Sub Download(ByVal fromURL As String, ByVal toPath As String)
 Dim HTTPx As HTTPRequest
 Dim i As Integer
  Set HTTPx = New HTTPRequest
  HTTPx.SavePath = toPath
  HTTPx.Callback = "HTTPCallBack"
  HTTPx.CallingObject = Me
  HTTPx.Main fromURL
  pHTTPRequestCollection.Add HTTPx
End Sub

Sub HTTPCallBack()
Dim HTTPx As HTTPRequest
Dim i As Integer
For i = pHTTPRequestCollection.Count To 1 Step -1
  If pHTTPRequestCollection.Item(i).RequestDone Then pHTTPRequestCollection.Remove i
Next
End Sub

вы можете получить доступ к объекту HTTP из HTTPCallBack и сделать здесь много красивых вещей; главное: его совершенно асинхронный сейчас и простой в использовании. Надеюсь, это поможет кому-то, как OP помог мне.

я развил это дальше в класс: check мой блог