Delphi/ pascal: перегрузка конструктора другим прототипом

Я пытаюсь создать дочерний класс TForm с помощью

  1. специальный конструктор для определенных случаев, и
  2. конструктор по умолчанию, который будет поддерживать совместимость с существующим кодом.

это код у меня есть сейчас:

interface
  TfrmEndoscopistSearch = class(TForm)
  public
    /// original constructor kept for compatibility
    constructor Create(AOwner : TComponent); overload; override;
    /// additional constructor allows for a caller-defined base data set
    constructor Create(AOwner : TComponent; ADataSet : TDataSet; ACaption : string = ''); overload;
  end;

Кажется, что это работает, но я всегда получаю предупреждение компилятора:

[Warning] test.pas(44): Method 'Create' hides virtual method of base type 'TCustomForm'
  • добавление "overload;" после того, как второй конструктор не будет компилироваться. "[Ошибка] тест.па(44): декларация "Create" отличается от предыдущего объявления".
  • создание второго конструктора функция класса компилируется без каких-либо ошибок или предупреждений, но умирает с нарушением доступа во время выполнения (все члены vars равны нулю).
15
constructor delphi overloading

3 ответов

попробуйте добавить reintroduce перед вторым overload, например:

  TfrmEndoscopistSearch = class(TForm)
  public
    /// original constructor kept for compatibility
    constructor Create(AOwner : TComponent); overload; override;
    /// additional constructor allows for a caller-defined base data set
    constructor Create(AOwner : TComponent; ADataSet : TDataSet; ACaption : string = ''); reintroduce; overload;
  end;

это компилируется в Turbo Delphi. Мне нужно было public чтобы сделать его компилировать, потому что перегрузка published методы ограничены.

18

есть очень простой способ избежать этого. дайте вашему новому конструктору другое имя. В отличие от некоторых других популярных языков, Delphi имеет именованные конструкторы; вам не нужно называть их Create. Вы можете вызвать свой новый CreateWithDataset и вообще не вмешиваться в виртуальный конструктор Create.

TfrmEndoscopistSearch = class(TForm)
  /// original constructor kept for compatibility
  constructor Create(AOwner: TComponent); override;
  /// additional constructor allows for a caller-defined base data set
  constructor CreateWithDataset(AOwner: TComponent; ADataSet: TDataSet; ACaption: string = '');
end;

фактически, если вы не создаете экземпляр этого класса полиморфно, вам даже не нужен оригинальный конструктор. Вы могли бы объявить новый такой:

TfrmEndoscopistSearch = class(TForm)
  /// additional constructor allows for a caller-defined base data set
  constructor Create(AOwner: TComponent; ADataSet: TDataSet; ACaption: string = ''); reintroduce;
end;

попытка вызвать конструктор с одним аргументом непосредственно на TfrmEndoscopistSearch приведет к ошибке компиляции.

(создание его полиморфно, как правило, связано с использованием приложения.CreateForm:

Application.CreateForm(TfrmEndoscopistSearch, frmEndoscopistSearch);

это всегда вызывает виртуальный конструктор с одним аргументом, представленный в TComponent. Если это не ваша основная форма, вам не нужно этого делать. Я писал о мои чувства на Приложение.CreateForm раньше.)

27
constructor Create(AOwner:Tcomponent;str:string);overload;
... 
constructor TfrmEndoscopistSearch.Create(AOwner: Tcomponent; str: string);
    begin
    inherited Create(AOwner);
    showmessage(str);
    end;

это должно сделать трюк

6