экспорт в Delphi stringgrid в Excel

Я пытаюсь экспортировать данные из stringgrid в delphi 7 в microsoft excel. Я использую этот код для этого:

  objExcel := TExcelApplication.Create(nil);
  objExcel.Visible[LOCALE_USER_DEFAULT] := true;
  objWB := objExcel.workbooks.add(null,LOCALE_USER_DEFAULT);
  lineNumber := 1;

  for i:=1 to stringgrid1.rowcount-1 do begin
    for j:=0 to stringgrid1.ColCount-1 do begin
      objWB.Worksheets.Application.Cells.Item[i+lineNumber,j+1] := ''''+stringgrid1.Cells[j,i];
    end;
  end;

но когда данные большие, для завершения требуется очень много времени. есть ли другой более быстрый способ экспорта данных из delphi 7 stringgrid в excel?

7
delphi export-to-excel stringgrid

3 ответов

самый быстрый способ-использовать массив Variant и просто передать весь массив в Excel:

uses OleAuto;

var
  xls, wb, Range: OLEVariant;
  arrData: Variant;
  RowCount, ColCount, i, j: Integer;
begin
  {create variant array where we'll copy our data}
  RowCount := StringGrid1.RowCount;
  ColCount := StringGrid1.ColCount;
  arrData := VarArrayCreate([1, RowCount, 1, ColCount], varVariant);

  {fill array}
  for i := 1 to RowCount do
    for j := 1 to ColCount do
      arrData[i, j] := StringGrid1.Cells[j-1, i-1];

  {initialize an instance of Excel}
  xls := CreateOLEObject('Excel.Application');

  {create workbook}
  wb := xls.Workbooks.Add;

  {retrieve a range where data must be placed}
  Range := wb.WorkSheets[1].Range[wb.WorkSheets[1].Cells[1, 1],
                                  wb.WorkSheets[1].Cells[RowCount, ColCount]];

  {copy data from allocated variant array}
  Range.Value := arrData;

  {show Excel with our data}
  xls.Visible := True;
end;
20

проблема в том, что вы вызываете объект Excel для каждой ячейки; это медленная операция в лучшем случае, поэтому выполнение этого для большого количества ячеек займет много времени. У меня был случай не так давно: 4000 строк с 9 столбцами заняло около 44 секунд, чтобы перейти в Excel.

мое текущее решение включает в себя создание файла csv, а затем импорт этого csv в Excel.

const
 fn = 'c:\windows\temp\csv.csv';

var
 csv: tstringlist;
 row, col: integer;
 s: string;

begin
 csv:= tstringlist.create;
 for row:= 1 to stringgrid1.rowcount do 
  begin
   s:= '';
   for col:= 0 to stringgrid1.ColCount-1 do 
    s:= s + stringgrid1.Cells[col, row-1] + ',';
   csv.add (s)
  end;

 csv.savetofile (fn);
 csv.free;

 objExcel := TExcelApplication.Create(nil);
 objExcel.workbooks.open (fn);
 deletefile (fn);
end;

другой способ исходит от Майк Школьник что я цитирую как есть:

var
 xls, wb, Range: OLEVariant;
 arrData: Variant;

begin
{create variant array where we'll copy our data}
 arrData := VarArrayCreate([1, yourStringGrid.RowCount, 1, yourStringGrid.ColCount], varVariant);

 {fill array}
 for i := 1 to yourStringGrid.RowCount do
  for j := 1 to yourStringGrid.ColCount do
   arrData[i, j] := yourStringGrid.Cells[j-1, i-1];

 {initialize an instance of Excel}
 xls := CreateOLEObject('Excel.Application');

 {create workbook}
 wb := xls.Workbooks.Add;

 {retrieve a range where data must be placed}
 Range := wb.WorkSheets[1].Range[wb.WorkSheets[1].Cells[1, 1],
                              wb.WorkSheets[1].Cells[yourStringGrid.RowCount, yourStringGrid.ColCount]];

 {copy data from allocated variant array}
 Range.Value := arrData;

 {show Excel with our data}
 xls.Visible := True;
end;

Я предлагаю вам попробовать оба метода и посмотреть, что быстрее для ваших целей.

3
procedure WriteToExcel();
var
  txt : TextFile;
  Str : string;
  i : integer;
begin
  try
    SaveDialog1.FileName := 'excelFile('+FormatDateTime('yyyy-dd-mm hh-nn-ss' ,(Now))+')';
    if SaveDialog1.Execute then
      begin
        AssignFile(txt, SaveDialog1.FileName+'.csv');
        try
          if FileExists(SaveDialog1.FileName) then
            Append(txt)
          else
            ReWrite(txt);
          Str := 'title1, title2, title3, title4, title5';
          WriteLn(txt, Str);
          ShowQuery.First();
          for i:=1 to StringGrid1.RowCount do
            begin
              Str := StringGrid1.Cols[i][1] + ',';
              Str := Str + StringGrid1.Cols[i][2] + ',';
              Str := Str + StringGrid1.Cols[i][3] + ',';
              Str := Str + StringGrid1.Cols[i][4] + ',';
              Str := Str + StringGrid1.Cols[i][5];
              WriteLn(txt,  Str);
            end;
        finally
          CloseFile(txt);
        end;
      end;
  except

  end;
end;
0