Есть ли способ очистить вывод из PL/SQL в Oracle?
У меня есть SQL-скрипт, который вызывается из сценария оболочки и занимает много времени для запуска. В настоящее время он содержит dbms_output.put_line
заявления в разных точках. Выходные данные этих операторов печати отображаются в файлах журнала, но только после завершения сценария.
есть ли способ убедиться, что вывод отображается в файле журнала по мере выполнения скрипта?
5 ответов
Не совсем так. Способ работы DBMS_OUTPUT таков: ваш блок PL/SQL выполняется на сервере базы данных без взаимодействия с клиентом. Поэтому, когда вы вызываете PUT_LINE, он просто помещает этот текст в буфер в памяти на сервере. Когда ваш блок PL/SQL завершается, управление возвращается клиенту (я предполагаю, что SQLPlus в этом случае); в этот момент клиент получает текст из буфера, вызывая GET_LINE, и отображает его.
таким образом, единственный способ сделать выход появляется в файле журнала чаще, чтобы разбить большой блок PL / SQL на несколько меньших блоков, поэтому управление возвращается клиенту чаще. Это может быть нецелесообразно в зависимости от того, что делает ваш код.
другие альтернативы - использовать UTL_FILE для записи в текстовый файл, который может быть сброшен, когда вам нравится, или использовать процедуру автономной транзакции для вставки операторов отладки в таблицу базы данных и фиксации после каждого из них.
два варианта:
вы можете вставить свои данные входа в таблицу журналов с помощью автономной транзакции. Вы можете запросить эту таблицу журналов в другом разработчике SQLPLUS/Toad / sql и т. д... сессия. Вы должны использовать автономную транзакцию, чтобы сделать возможным фиксацию журнала без вмешательства в обработку транзакций в главном сценарии sql.
Другой альтернативой является использование конвейерной функции, которая возвращает Регистрация информации. См. здесь для примера:http://berxblog.blogspot.com/2009/01/pipelined-function-vs-dbmsoutput.html когда вы используете конвейерную функцию, вам не нужно использовать другого разработчика SQLPLUS/Toad/sql и т. д... сессия.
буфер DBMS_OUTPUT
читать, когда процедура DBMS_OUTPUT.get_line
называется. Если ваше клиентское приложение SQL * Plus, это означает, что оно будет сброшено только после завершения процедуры.
вы можете применить метод, описанный в это так написать DBMS_OUTPUT
буфера в файл.
если это возможно, вы должны заменить вызовы dbms_output.put_line по вашей собственной функции.
вот код для этой функции WRITE_LOG
-- если вы хотите иметь возможность выбрать между 2 регистрации:
запись журналов в таблицу в автономные транзакции
CREATE OR REPLACE PROCEDURE to_dbg_table(p_log varchar2)
-- table mode:
-- requires
-- CREATE TABLE dbg (u varchar2(200) --- username
-- , d timestamp --- date
-- , l varchar2(4000) --- log
-- );
AS
pragma autonomous_transaction;
BEGIN
insert into dbg(u, d, l) values (user, sysdate, p_log);
commit;
END to_dbg_table;
/
или напишите непосредственно на сервер БД, на котором размещается ваш база данных
использует каталог Oracle TMP_DIR
CREATE OR REPLACE PROCEDURE to_dbg_file(p_fname varchar2, p_log varchar2)
-- file mode:
-- requires
--- CREATE OR REPLACE DIRECTORY TMP_DIR as '/directory/where/oracle/can/write/on/DB_server/';
AS
l_file utl_file.file_type;
BEGIN
l_file := utl_file.fopen('TMP_DIR', p_fname, 'A');
utl_file.put_line(l_file, p_log);
utl_file.fflush(l_file);
utl_file.fclose(l_file);
END to_dbg_file;
/
WRITE_LOG
тут WRITE_LOG
процедура которая может переключить между 2 пользами, или быть выключена для избежания потери представлений (g_DEBUG:=FALSE
).
CREATE OR REPLACE PROCEDURE write_log(p_log varchar2) AS
-- g_DEBUG can be set as a package variable defaulted to FALSE
-- then change it when debugging is required
g_DEBUG boolean := true;
-- the log file name can be set with several methods...
g_logfname varchar2(32767) := 'my_output.log';
-- choose between 2 logging solutions:
-- file mode:
g_TYPE varchar2(7):= 'file';
-- table mode:
--g_TYPE varchar2(7):= 'table';
-----------------------------------------------------------------
BEGIN
if g_DEBUG then
if g_TYPE='file' then
to_dbg_file(g_logfname, p_log);
elsif g_TYPE='table' then
to_dbg_table(p_log);
end if;
end if;
END write_log;
/
и вот как проверить вышеизложенное:
1) запустить (файл режим) от ваш SQLPLUS:
BEGIN
write_log('this is a test');
for i in 1..100 loop
DBMS_LOCK.sleep(1);
write_log('iter=' || i);
end loop;
write_log('test complete');
END;
/
2) на сервере базы данных, откройте оболочку и
tail -f -n500 /directory/where/oracle/can/write/on/DB_server/my_output.log
если у вас есть доступ к системной оболочке из среды PL / SQL, вы можете вызвать netcat:
BEGIN RUN_SHELL('echo "'||p_msg||'" | nc '||p_host||' '||p_port||' -w 5'); END;
p_msg
- это сообщение журнала
v_host
является хостом, выполняющим скрипт python, который считывает данные из сокета на порт v_port
.
я использовал этот дизайн, когда я писал aplogr для мониторинга в реальном времени оболочки и журналов pl/sql.