Excel VBA: добавление точечной диаграммы на лист в качестве объекта

Я ищу, чтобы создать диаграмму разброса, которая при нажатии кнопки создает диаграмму разброса в Sheet 1 и использует A2:A11 как x значения и B2:B11 как y значения.

использование кода внизу позволяет мне создать диаграмму разброса на основе значений в A1:B3 (получил от здесь). Его близко, но не совсем то, что я ищу. Как я могу настроить это в соответствии с моими потребностями?

Я настроил его сейчас, так что диаграмма составлена на основе значений, которые я хочу, но я не могу заставить ее появиться как объект в Sheet 1. Как мне это сделать? .Location xlLocationAsObject не работает.

Private Sub chartButton_Click()
    ActiveWorkbook.Charts.Add
    With ActiveWorkbook.ActiveChart
        'Data?
        .ChartType = xlXYScatter
        .SeriesCollection.NewSeries
        .SeriesCollection(1).Name = "=""Scatter Chart"""
        .SeriesCollection(1).XValues = "=Sheet1!$A:$A"
        .SeriesCollection(1).Values = "=Sheet1!$B:$B"

        'Location
        'DON'T KNOW WHAT TO PUT HERE
        '.location xlLocationAsObject doesn't work!

        'Titles
        .HasTitle = True
        .ChartTitle.Characters.Text = "Scatter Chart"
        .Axes(xlCategory, xlPrimary).HasTitle = True
        .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "X values"
        .Axes(xlValue, xlPrimary).HasTitle = True
        .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Y values"
        .Axes(xlCategory).HasMajorGridlines = True

        'Formatting
        .Axes(xlCategory).HasMinorGridlines = False
        .Axes(xlValue).HasMajorGridlines = True
        .Axes(xlValue).HasMinorGridlines = False
        .HasLegend = False

    End With
End Sub
6
charts excel excel-vba vba

2 ответов

ваш код, как написано, добавляет диаграмму как Chart Sheet, не как диаграмма на Worksheet

попробуйте это:

заменить

ActiveWorkbook.Charts.Add
With ActiveWorkbook.ActiveChart

С

Dim sh As Worksheet
Dim chrt As Chart

Set sh = ActiveWorkbook.Worksheets("Sheet1")
Set chrt = sh.Shapes.AddChart.Chart
With chrt

затем вы можете контролировать его положение и размер с

    .ChartArea.Left
    .ChartArea.Top 
    .ChartArea.Height
    .ChartArea.Width
8

при использовании Chart.Location, вам нужно указать местоположение:

.Location Where:=xlLocationAsObject, Name:="Sheet1"
0