foldlWithKey в монаде

Я ищу функцию, которая похожа на foldlWithKey, но инкапсулирована в монаду.

Я ожидал бы, что он будет иметь тип

Monad m => (a -> k -> b -> m a) -> a -> Map k b -> m a

но Hoogle не дает мне ничего с этим типом.

6
haskell hoogle monads

2 ответов

foldlWithKey это уже очень близко к тому, что вы хотите. Если вы специализируетесь a to m a у вас будет что-то, что работает со значениями, инкапсулированными в монаду.

foldlWithKey :: (  a -> k -> b ->   a) ->   a -> Map k b ->   a
foldlWithKey :: (m a -> k -> b -> m a) -> m a -> Map k b -> m a
             {-  ^- you don't want these -^   -}

мы можем избавиться от двух m as вы не хотите с >>= и return.

foldlWithKeyM :: Monad m => (a -> k -> b -> m a) -> a -> Map k b -> m a
foldlWithKeyM f acc = foldlWithKey f' (return acc) 
    where
        f' ma k b = ma >>= \a -> f a k b
10

решение@Cirdec, безусловно, работает, но у него есть возможная проблема: он гнездится >>=s глубоко влево. Для многих (но не всех!) монады, это может дать взрыв стека, подобный при использовании нестрогих foldl. Поэтому я представлю другое решение, которое гнездится s вправо. Для монад, таких как IO это должно позволить действие быть построено и потреблено лениво с карты по мере ее выполнения.

это решение, вероятно, немного сложнее, так как оно использует право сложите, чтобы создать монадическую функцию, которая в конечном итоге будет потреблять начальное значение. По крайней мере, у меня были некоторые проблемы с правильными типами.

за исключением обработки ключей, это по существу тот же метод, что и Data.Foldable.foldlM.

-- Pragma needed only to give f' a type signature for sanity.  Getting it 
-- right almost took a piece of mine until I remembered typed holes.
{-# LANGUAGE ScopedTypeVariables #-}

import Data.Map

foldlWithKeyM
  :: forall m a k b. Monad m => (a -> k -> b -> m a) -> a -> Map k b -> m a
foldlWithKeyM f start m = foldrWithKey f' return m $ start
  where
    f' :: k -> b -> (a -> m a) -> (a -> m a)
    f' k b a2mb a = f a k b >>= a2mb
7