Функция подсчета количества строк в текстовом файле

нужна функция, которая принимает имя файла в качестве параметра и затем возвращать количество строк в этом файле.

должно занять менее 30 секунд, чтобы получить количество 10 миллионов файлов строк.

В настоящее время есть что - то вроде-но это слишком медленно с большими файлами:

Dim objFSO, strTextFile, strData, arrLines, LineCount
CONST ForReading = 1

'name of the text file
strTextFile = "sample.txt"

'Create a File System Object
Set objFSO = CreateObject("Scripting.FileSystemObject")

'Open the text file - strData now contains the whole file
strData = objFSO.OpenTextFile(strTextFile,ForReading).ReadAll

'Split by lines, put into an array
arrLines = Split(strData,vbCrLf)

'Use UBound to count the lines
LineCount = UBound(arrLines) + 1

wscript.echo LineCount

'Cleanup
Set objFSO = Nothing
11
scripting vbscript

6 ответов

единственная альтернатива, которую я вижу, - читать строки один за другим (EDIT: или даже просто пропустить их по одному) вместо того, чтобы читать весь файл сразу. К сожалению, я не могу проверить, что сейчас быстрее. Думаю, прыгать быстрее. 

Dim objFSO, txsInput, strTemp, arrLines
Const ForReading = 1
Set objFSO = CreateObject("Scripting.FileSystemObject")

strTextFile = "sample.txt"
txsInput = objFSO.OpenTextFile(strTextFile, ForReading)

'Skip lines one by one 
Do While txsInput.AtEndOfStream <> True
    txsInput.SkipLine ' or strTemp = txsInput.ReadLine
Loop

wscript.echo txsInput.Line-1 ' Returns the number of lines

'Cleanup
Set objFSO = Nothing

кстати, я взял на себя смелость удалить некоторые из ваших 'comments. С точки зрения хорошей практики они были излишними и не добавляли никакой объяснительной ценности, особенно когда они в основном повторяли сами имена методов, например,

'Create a File System Object
... CreateObject("Scripting.FileSystemObject")
6

Если кто-то все еще ищет более быстрый способ, Вот код:

Set fso = CreateObject("Scripting.FileSystemObject") 
Set theFile = fso.OpenTextFile("C:\textfile.txt", 8, True) 
WScript.Echo theFile.Line 
Set Fso = Nothing

конечно, время обработки зависит от размера файла, а не только от количества строк. По сравнению с методом RegEx TextStream.Свойство Line по крайней мере в 3 раза быстрее.

15

слишком большие файлы...
Следующее наиболее эффективно способ я знаю:

Dim oFso, oReg, sData, lCount
Const ForReading = 1, sPath = "C:\file.txt"
Set oReg = New RegExp
Set oFso = CreateObject("Scripting.FileSystemObject")
sData = oFso.OpenTextFile(sPath, ForReading).ReadAll
With oReg
    .Global = True
    .Pattern = "\r\n" 'vbCrLf
    '.Pattern = "\n" ' vbLf, Unix style line-endings
    lCount = .Execute(sData).Count + 1
End With
WScript.Echo lCount
Set oFso = Nothing
Set oReg = Nothing
7

вы можете попробовать некоторые варианты этого

cnt = 0
Set fso = CreateObject("Scripting.FileSystemObject")
Set theFile = fso.OpenTextFile(filespec, ForReading, False)
Do While theFile.AtEndOfStream <> True
   theFile.SkipLine
   c = c + 1
Loop
theFile.Close
WScript.Echo c,"lines"
4

Я искал более быстрый способ, чем мне уже приходилось определять количество строк в текстовом файле. Я искал в интернете и наткнулся на 2 перспективное решение. Одним из них было решение на основе SQL, а другим-решение, которое я нашел здесь на основе Fso Кул-Тигина. Я протестировал их, и это часть результата:

Number of lines  Time elapsed  Variant
--------------------------------------------------------
110              00:00:00.70   SQL
110              00:00:00.00   Vanilla VBA (my solution)
110              00:00:00.16   FSO    
--------------------------------------------------------
1445014          00:00:17.25   SQL
1445014          00:00:09.19   Vanilla VBA (my solution)
1445014          00:00:17.73   FSO

я запускал это несколько раз с большими и малыми числами. Снова и снова ванильный VBA выходил на первое место. Я знаю, что это устарело, но для всех все еще ищете самый быстрый способ определить количество строк в csv / текстовом файле, вот код, который я использую. 

Public Function GetNumRecs(ASCFile As String) As Long
  Dim InStream As Long
  Dim Record As String
  InStream = FreeFile
  GetNumRecs = 0
  Open ASCFile For Input As #InStream
  Do While Not EOF(InStream)
    Line Input #InStream, Record
    GetNumRecs = GetNumRecs + 1
  Loop
  Close #InStream
End Function
0
txt = "c:\YourTxtFile.txt"
j = 0
Dim read
Open txt For Input As #1
  Do While Not EOF(1)
    Input #1, read
    j = j + 1
  Loop
Close #1

если он добавляет пустую последнюю строку, результатом будет (j - 1).

Он отлично работает для одного столбца в текстовый файл.

-1