Хэш-строка кода VBA

разделите строку на три более короткие строки (если не делится на три, последний будет длиннее, чем два других). Запустите свой" короткий " алгоритм на каждом и объедините результаты.

я мог бы написать код, но судя по качеству вопроса, я думаю, вы можете взять его отсюда!

EDIT: оказывается, этого совета недостаточно. В вашем оригинальном коде CRC16 есть серьезный недостаток-а именно строка, которая говорит:

j = Val("&H" + Mid(txt, nC, 2))

это обрабатывает только текст, который можно интерпретировать как шестнадцатеричные значения: строчные и прописные буквы одинаковы, и все, что после Ф в алфавите игнорируется (насколько я могу судить). То, что все хорошее выходит наружу-это чудо. Если вы замените строку с

j = asc(mid(txt, nC, 1))

вещи работать лучше - каждый код ASCII, по крайней мере, начинает жизнь как свою собственную ценность.

комбинируя это изменение с предложением, которое я сделал ранее, вы получаете следующий код:

Function hash12(s As String)
' create a 12 character hash from string s

Dim l As Integer, l3 As Integer
Dim s1 As String, s2 As String, s3 As String

l = Len(s)
l3 = Int(l / 3)
s1 = Mid(s, 1, l3)      ' first part
s2 = Mid(s, l3 + 1, l3) ' middle part
s3 = Mid(s, 2 * l3 + 1) ' the rest of the string...

hash12 = hash4(s1) + hash4(s2) + hash4(s3)

End Function

Function hash4(txt)
' copied from the example
Dim x As Long
Dim mask, i, j, nC, crc As Integer
Dim c As String

crc = &HFFFF

For nC = 1 To Len(txt)
    j = Asc(Mid(txt, nC)) ' <<<<<<< new line of code - makes all the difference
    ' instead of j = Val("&H" + Mid(txt, nC, 2))
    crc = crc Xor j
    For j = 1 To 8
        mask = 0
        If crc / 2 <> Int(crc / 2) Then mask = &HA001
        crc = Int(crc / 2) And &H7FFF: crc = crc Xor mask
    Next j
Next nC

c = Hex$(crc)

' <<<<< new section: make sure returned string is always 4 characters long >>>>>
' pad to always have length 4:
While Len(c) < 4
  c = "0" & c
Wend

hash4 = c

End Function

вы можете поместить этот код в электронную таблицу как =hash12("A2") etc. Для удовольствия вы также можете использовать" новый, улучшенный " алгоритм hash4 и посмотреть, как они сравниваются. Я создал сводную таблицу для подсчета столкновений-для hash12 алгоритм, и только 3 для hash4. Я уверен, что вы можете понять, как создать hash8, ... из этого. "Не нужно быть уникальным" из вашего вопроса предполагает, что возможно "улучшить" hash4 все, что вам необходимость.

в принципе, четырехсимвольный hex должен иметь 64K уникальных значений-так что вероятность двух случайных строк с одинаковым хэшем будет 1 в 64k. Когда у вас есть 400 строк, есть 400 x 399 / 2 "возможные пары столкновений" ~ 80k возможностей (предполагая, что у вас были очень случайные строки). Таким образом, наблюдение трех столкновений в образце набора данных не является необоснованным. По мере увеличения количества строк N вероятность столкновений увеличивается как квадрат N. с дополнительные 32 бита информации в hash12, вы ожидаете увидеть столкновения, когда N > 20 м или около того (размахивание руками, в моей голове математика).

вы можете сделать код hash12 немного более компактным, очевидно, - и должно быть легко увидеть, как расширить его на любую длину.

О - И последнее. Если у вас включена RC-адресация, используйте =CRC16("string") как электронная таблица формула дает трудно отслеживать #REF ошибка... вот почему я переименовал его hash4