Имеет ли Microsoft Access полнотекстовый поиск?

первым шагом в полнотекстовом поиске является создание списка слов, содержащего все слова в базе данных. Полнотекстовый поиск также имеет другие функции, такие как stemming, который связывает производные слова с базовым словом (fast, faster, fastest), и у него есть стоп-слова, которые игнорируются, потому что они настолько распространены (и,). Небольшой код VBA может генерировать список слов, который можно визуально сканировать. С немного больше работы, можно было бы использовать код, чтобы проверить список, прежде чем слово поиск в базе данных и это может сделать поиск гораздо быстрее. Ниже приведен код, который я создал для этой цели. Его реальная жизнь приложение, чтобы найти имена людей в базе данных, так что я могу удалить или изменить их для защиты конфиденциальности и как биолог, я хочу курсивом научных имен в докладах. Если я могу создать список научных имен, то я могу заменить их именем, заключенным в теги html.

код работает хорошо, но я не проверял это много или против большие поля memo / rich текстовые поля. Он был написан в Access 2010.

'This code requires a table called tblWordList with fields called Word (str 255), WordCount (long), FirstCopyID (long)

Option Compare Database
Option Explicit

'Click on this procedure and press F5 to run the code
Private Sub ScopeWordList()

    'A list of tables and fields that need to be processed
    Call CreateWordList("Issues", "IssueSummary", "IssueID")

End Sub

'The main routine that finds new words
Public Sub CreateWordList(TableName As String, FieldName As String, ForeignKey As String)

    Dim dbs As Database
    Dim rst As Recordset
    Dim SQL_Statement As String

    Dim r As Recordset

    Dim RowText As String
    Dim OriginalWord As String
    Dim SearchWord As String
    Dim SearchTerm As String
    Dim Quote As String: Quote = Chr$(34)
    Dim i As Long
    Dim RecNum As Long

    SQL_Statement = "SELECT " & FieldName & ", " & ForeignKey & " AS FirstCopyID FROM " & TableName & " WHERE " & FieldName & " IS NOT NULL;"
    Set dbs = CurrentDb()
    Set rst = dbs.OpenRecordset(SQL_Statement, dbOpenSnapshot)

    Set r = dbs.OpenRecordset("tblWordCounts", dbOpenTable)
    r.Index = "Word"

    With rst
    If .RecordCount = 0 Then GoTo ExitCreateWordList

    Do Until .EOF
        Dim RowWords As Variant 'holds an array which needs to be created
        RowText = .Fields(0)
        'strip out quotes, slashes and other characters
        RowText = CleanLine(RowText)
        'split data into words
        RowWords = Split(RowText, Space(1))

        For i = LBound(RowWords) To UBound(RowWords)
            OriginalWord = RowWords(i)
            SearchWord = Left(Trim(OriginalWord), 254)
            If Len(SearchWord) > 0 Then
                    r.Seek "=", SearchWord
                    If r.NoMatch Then
                        r.AddNew
                        r!Word = SearchWord
                        r!wordcount = 1
                        'records ID field of first occurrence, so you can debug unexpected results
                        r!FirstCopyID = !FirstCopyID
                        r.Update
                    Else
                        r.Edit
                        r!wordcount = r!wordcount + 1
                        r.Update
                    End If
                End If
'            End If
        Next i
        RecNum = RecNum + 1
        If RecNum Mod 20 = 0 Then Debug.Print "Record " & RecNum
        .MoveNext
    Loop

ExitCreateWordList:
    End With
    Debug.Print "Done"
    Set rst = Nothing
    Set dbs = Nothing


End Sub

'Need to clean out unwanted characters and replace then with normal spaces
Private Function CleanLine(RowText As String) As String

        Dim X As Long
        Dim Y As String
        Dim Z As Long
        Dim W As String

        For X = 1 To Len(RowText)
            Y = Mid(RowText, X, 1)
            Z = Asc(Y)
            Select Case Z
                Case 65 To 90      'capital letters
                    W = W & Y
                Case 97 To 122     'lowercase letters
                    W = W & Y
                Case Else
                    W = W & Space(1)
            End Select
        Next
        CleanLine = W

End Function

'Delete all records in Word List table
Public Sub ClearWordList()

    Dim SQL_Statement As String

    'Delete all records from tblWordCounts
    SQL_Statement = "DELETE FROM tblWordCounts"
    DoCmd.SetWarnings False
    DoCmd.RunSQL SQL_Statement
    DoCmd.SetWarnings True

End Sub

MSDE (теперь называется SQL Server Express) имеет полнотекстовую индексацию, если вы ищете клиентскую развертываемую базу данных

пример кода @duffymo обеспечивает очень хорошо работает. Я использую его с Microsoft Access 2003. Но несколько исправлений необходимы.

1. таблица должна быть определена как: "Для этого кода требуется таблица tblwordlist с полями слово (текст, 255), приложения WordCount (количество), FirstCopyID (число)

2. другое исправление tblWordCounts необходимо заменить с tblWordList и конечно Вызов CreateWordList необходимо изменить на таблицу и поле, которые необходимо отправить в tblWordList.

на таблице записей 5000 он работал так быстро, что я думал, что он не работает, когда я нажал на Sub ScopeWordList () и нажал F5, но модуль создал список слов с более чем 700 различными записями (для моей таблицы данных). Спасибо @duffymo для некоторых аккуратные пример кода.

Access не является базой данных. Но он поставляется с ядром базы данных по умолчанию, Jet / ACE. Я бы предположил, что вы это имеете в виду, но вы должны быть более ясны, что вы имеете в виду, когда задаете такой вопрос.

Jet / ACE не имеет возможности полнотекстового поиска.

лучший способ сделать полнотекстовый поиск файлов данных Jet / ACE через любые возможности полнотекстового поиска у вас есть для файлов на вашем компьютере. Это не будет быстро, и не будет можно использовать через SQL.

вы не говорите, что это за контекст, но я вообще никогда не видел необходимости в полнотекстовом поиске, кроме как на веб-сайтах (где это что-то вроде ожидаемой возможности). Если вы используете Jet / ACE в качестве хранилища данных для HTTP-приложения, то вы выбрали неправильное хранилище данных. Хотя Jet/ACE может отлично работать для малообъемных сайтов только для чтения, это не рекомендуется использовать (из-за ограничений в ядре базы данных Jet / ACE).

Если вам нужен полный текст поиск тогда вам нужен другой компонент database engine.

http://www.dummies.com/how-to/content/finding-records-in-your-access-2003-tables.html

речь идет об использовании инструмента найти. Я еще не пробовал, и я не уверен, работает ли он на полях memo.