Интерфейсы, анонимные методы и утечки памяти

это сконструированный пример. Я не хочу размещать исходный код здесь. Я попытался извлечь соответствующие части.

у меня есть интерфейс, который управляет списком слушателей.

TListenerProc = reference to procedure (SomeInt : ISomeInterface);

ISomeInterface = interface
   procedure AddListener (Proc : TListenerProc);   
end;

Теперь я регистрирую слушателя:

SomeObj.AddListener (MyListener);

procedure MyListener (SomeInt : ISomeInterface);
begin
  ExecuteSynchronized (procedure
                       begin
                       DoSomething (SomeInt);
                       end);
end;

Я получаю утечки памяти. И анонимный метод, и интерфейсы никогда не освобождаются. Я подозреваю, что это связано с какой-то циклическая ссылка здесь. Анонимный метод сохраняет интерфейс alife и интерфейс сохраняет анонимный метод alife.

два вопроса:

  1. вы поддерживаете это объяснение? Или я упускаю что-то еще?
  2. могу ли я что-нибудь с этим поделать?

спасибо заранее!

редактировать: не так просто воспроизвести это в приложении, достаточно маленьком, чтобы опубликовать его здесь. Лучшее, что я могу сейчас сделать, это следующее. Анонимный метод не освобождается здесь:

program TestMemLeak;

{$APPTYPE CONSOLE}

uses
  Generics.Collections, SysUtils;

type
  ISomeInterface = interface;
  TListenerProc  = reference to procedure (SomeInt : ISomeInterface);

  ISomeInterface = interface
  ['{DB5A336B-3F79-4059-8933-27699203D1B6}']
    procedure AddListener (Proc : TListenerProc);
    procedure NotifyListeners;
    procedure Test;
  end;

  TSomeInterface = class (TInterfacedObject, ISomeInterface)
  strict private
    FListeners          : TList <TListenerProc>;
  protected
    procedure AddListener (Proc : TListenerProc);
    procedure NotifyListeners;
    procedure Test;
  public
    constructor Create;
    destructor  Destroy; override;
  end;


procedure TSomeInterface.AddListener(Proc: TListenerProc);
begin
FListeners.Add (Proc);
end;

constructor TSomeInterface.Create;
begin
FListeners := TList <TListenerProc>.Create;
end;

destructor TSomeInterface.Destroy;
begin
FreeAndNil (FListeners);
  inherited;
end;

procedure TSomeInterface.NotifyListeners;

var
  Listener : TListenerProc;

begin
for Listener in FListeners do
  Listener (Self);
end;

procedure TSomeInterface.Test;
begin
// do nothing
end;

procedure Execute (Proc : TProc);

begin
Proc;
end;

procedure MyListener (SomeInt : ISomeInterface);
begin
Execute (procedure
         begin
         SomeInt.Test;
         end);
end;

var
  Obj     : ISomeInterface;

begin
  try
    ReportMemoryLeaksOnShutdown := True;
    Obj := TSomeInterface.Create;
    Obj.AddListener (MyListener);
    Obj.NotifyListeners;
    Obj := nil;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.
17
anonymous-methods delphi delphi-2010 interface memory-management

3 ответов

ваш код далек от минимума. Следующее:

program AnonymousMemLeak;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TListenerProc  = reference to procedure (SomeInt : IInterface);

procedure MyListener (SomeInt : IInterface);
begin
end;

var
  Listener: TListenerProc;

begin
  try
    ReportMemoryLeaksOnShutdown := True;

    Listener := MyListener;
    Listener := nil;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

имеет ту же проблему (Delphi 2009 здесь). Это не может быть обработано или разработано. Похоже на ошибку в компиляторе.

Edit:

или, может быть, это проблема обнаружения утечек памяти. Это не имеет ничего общего с параметром интерфейса, процедура без параметров приводит к той же "утечки". Очень странный.

8

похоже на определенную круговую справочную проблему. Анонимные методы управляются через скрытые интерфейсы, и если TList<TListenerProc> принадлежит объекту, на котором реализован ISomeInterface, тогда у вас есть проблема с круговой ссылкой.

одним из возможных решений было бы поставить ClearListeners метод на ISomeInterface, который вызывает .Clear на TList<TListenerProc>. Пока ничто другое не содержит ссылки на анонимные методы, это заставит их все исчезнуть и отбросить их ссылки на ISomeInterface.

Я сделал несколько статей о структуре и внедрение анонимных методов, которые могут помочь вам понять, что вы действительно работаете, и как они работают немного лучше. Вы можете найти их в http://tech.turbu-rpg.com/category/delphi/anonymous-methods.

3

проблема заключается в анонимных методах в DPR main.

просто поместите свой код в рутину и вызовите это в DPR main, и отчет об утечке памяти исчезнет.

procedure Main;
var
  Obj: ISomeInterface;
begin
  try
    ReportMemoryLeaksOnShutdown := True;
    Obj := TSomeInterface.Create;
    Obj.AddListener (MyListener);
    Obj.NotifyListeners;
    Obj := nil;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end;

begin
  Main;
end.
1