Изоморфизм Карри-Говарда

возможно, лучший способ понять, что это означает начать (или попробовать) используя типы как предложения и программы в качестве доказательств. Лучше изучать язык с зависимыми типами, такими как Agda (это написано в Haskell и похоже на Haskell). Существуют различные статьи и курсы на этом языке. узнать вас Agda является неполным, но стараюсь все упрощать, как LYAHFGG книга.

вот пример простого доказательства:

{-# OPTIONS --without-K #-} -- we are consistent

module Equality where

-- Peano arithmetic.
-- 
--   ℕ-formation:     ℕ is set.
-- 
--   ℕ-introduction:  o ∈ ℕ,
--                    a ∈ ℕ | (1 + a) ∈ ℕ.
-- 
data ℕ : Set where
  o : ℕ
  1+ : ℕ → ℕ

-- Axiom for _+_.
-- 
--   Form of ℕ-elimination.
-- 
infixl 6 _+_
_+_ : ℕ → ℕ → ℕ
o + m = m
1+ n + m = 1+ (n + m)

-- The identity type for ℕ.
-- 
infix 4 _≡_
data _≡_ (m : ℕ) : ℕ → Set where
  refl : m ≡ m

-- Usefull property.
-- 
cong : {m n : ℕ} → m ≡ n → 1+ m ≡ 1+ n
cong refl = refl

-- Proof _of_ mathematical induction:
-- 
--   P 0, ∀ x. P x → P (1 + x) | ∀ x. P x.
-- 
ind : (P : ℕ → Set) → P o → (∀ n → P n → P (1+ n)) → ∀ n → P n
ind P P₀ _ o = P₀
ind P P₀ next (1+ n) = next n (ind P P₀ next n)

-- Associativity of addition using mathematical induction.
-- 
+-associative : (m n p : ℕ) → (m + n) + p ≡ m + (n + p)
+-associative m n p = ind P P₀ is m
  where
    P : ℕ → Set
    P i = (i + n) + p ≡ i + (n + p)
    P₀ : P o
    P₀ = refl
    is : ∀ i → P i → P (1+ i)
    is i Pi = cong Pi

-- Associativity of addition using (dependent) pattern matching.
-- 
+-associative′ : (m n p : ℕ) → (m + n) + p ≡ m + (n + p)
+-associative′ o _ _ = refl
+-associative′ (1+ m) n p = cong (+-associative′ m n p)

там вы можете увидеть (m + n) + p ≡ m + (n + p) предложение как тип и его доказательство как функция. Существуют более продвинутые методы для таких доказательств (например, предзаказ рассуждения, комбинаторы в Agda похожи на тактику в Coq).

что еще можно доказать:

• head ∘ init ≡ head для векторов, здесь.

• ваш компилятор создает программу какое выполнение дает то же значение, что и значение, полученное в интерпретации той же (хост -) программы, здесь, для Coq. книги также является хорошим чтением по теме моделирования языка и проверки программ.

• все остальное, что может быть доказано в конструктивной математике, так как теория типов Мартина-Лефа в своей выразительной силе эквивалентна ZFC. Фактически, изоморфизм Карри-Говарда может быть расширен до физика и топология и алгебраической топологии.

единственный разумный ответ, который я могу придумать, таков: Если у вас есть функция X -> Y -> Z, то подпись типа говорит: "предполагая, что можно построить значение типа X, а другое типа Y, то можно построить значение типа Z". И тело функции точно описывает, как вы это сделаете. В этом есть смысл, но это не очень интересно. Ясно, что за этим кроется нечто большее...

Ну, да, есть гораздо больше, потому что это имеет много последствий и открывает много вопросов.

прежде всего, ваше обсуждение Ци оформлено исключительно в терминах типов импликации / функции (->). Вы не говорите об этом, но вы, вероятно, видели, как конъюнкция и дизъюнкция соответствуют типам продукта и суммы соответственно. Но как насчет других логических операторов, таких как отрицание, универсальная квантификация и экзистенциальная квантификация? Как мы перевести логические доказательства, связанные с ними, в программы? Получается, что примерно так:

• отрицание соответствует первоклассные продолжения. Не проси меня объяснить это.
• универсальная квантификация над пропозициональными (не индивидуальными) переменными соответствует параметрический полиморфизм. Так, например, полиморфная функция id действительно имеет тип forall a. a -> a
• экзистенциальное квантификация над пропозициональными переменными соответствует нескольким вещам, которые имеют отношение к скрытию данных или реализации:абстрактные типы данных, системы и динамическая диспетчеризация. Экзистенциальные типы GHC связаны с этим.
• универсальная и экзистенциальная квантификация по отдельным переменным приводит к зависимые системы типов.

кроме этого, это также означает, что все виды доказательств о логике мгновенно переводятся в доказательства о языках программирования. Например, разрешимость интуитивистской пропозициональной логики подразумевает прекращение всех программ в простом типизированном лямбда-исчислении.

теперь, что, черт возьми, означает Int - > Int?? О_о

это тип, или же предложение. В f :: Int -> Int, (+1) называет " программу "(в определенном смысле, который допускает как функции, так и константы как "программы", или альтернативно доказательство. Семантика языка должна либо обеспечивать f как примитивное правило вывода, или продемонстрировать, как f является доказательством, которое может быть построено из таких правил и предпосылок.

эти правила часто указываются с точки зрения эквациональной аксиом, которые определяют члены базового типа и правила, которые позволяют доказать, что других программ населяют этот тип. Например, переключение с Int to Nat (натуральные числа от 0 forward), мы могли бы иметь следующие правила:

• аксиомы: 0 :: Nat (0 примитивное доказательство Nat)
• правила: x :: Nat ==> Succ x :: Nat
• правила: x :: Nat, y :: Nat ==> x + y :: Nat
• правила: x + Zero :: Nat ==> x :: Nat
• правила: Succ x + y ==> Succ (x + y)

эти правила достаточно, чтобы доказать многие теоремы о сложении натуральных чисел. Эти доказательства также будут программами.