Как читать данные из xml-файла и отображать их в текстовом поле на языке delphi

Я новичок в языке delphi, и здесь у меня есть сомнения, у меня есть xml-файл под названием vehicle.XML.

это выглядит так

<data>
<vehicle>
    <type>Car</type>
    <model>2005</model>
    <number>1568</number>
</vehicle>
<vehicle>
    <type>Car</type>
    <model>2009</model>
    <number>1598</number>
</vehicle>
</data>

моя форма Delphi содержит три текстовых поля:

  • txtType
  • txtModel
  • txtnumber

при загрузке страницы я хочу, чтобы отобразить содержимое транспортного средства.xml над текстовым полем например:

  • txtType=автомобиль
  • txtModel=2005
  • txtNumber="1568"
9
delphi delphi-2009

2 ответов

посмотрите на собственные Дельфи TXMLDocument компонент, например:

procedure TForm1.FormCreate(Sender: TObject);
var
  Vehicle: IXMLNode;
begin
  XMLDocument1.FileName :='vehicle.xml';
  XMLDocument1.Active := True;
  try
    Vehicle := XMLDocument.DocumentElement;
    txtType.Text := Vehicle.ChildNodes['type'].Text;
    txtModel.Text := Vehicle.ChildNodes['model'].Text;
    txtnumber.Text  := Vehicle.ChildNodes['number'].Text;
  finally
    XMLDocument1.Active := False;
  end;
end;

или IXMLDocument интерфейс напрямую (который TXMLDocument обертывания):

procedure TForm1.FormCreate(Sender: TObject);
var
  Doc: IXMLDocument;
  Vehicle: IXMLNode;
begin
  Doc := LoadXMLDocument('vehicle.xml');
  Vehicle := Doc.DocumentElement;
  txtType.Text := Vehicle.ChildNodes['type'].Text;
  txtModel.Text := Vehicle.ChildNodes['model'].Text;
  txtnumber.Text := Vehicle.ChildNodes['number'].Text;
end;

обновление: XML в вопросе был изменен, чтобы теперь обернуть vehicle элемент внутри data элемент, и иметь несколько vehicle элементы. Таким образом, код выше должен быть скорректирован соответствующим образом, например:

procedure TForm1.FormCreate(Sender: TObject);
var
  Doc: IXMLDocument;
  Data: IXMLNode;
  Node: IXMLNode;
  I: Integer;
begin
  Doc := LoadXMLDocument('vehicle.xml');
  Data := Doc.DocumentElement;
  for I := 0 to Data.ChildNodes.Count-1 do
  begin
    Node := Data.ChildNodes[I];
    // if all of the child nodes will always be 'vehicle' only
    // then this check can be removed...
    if Node.LocalName = 'vehicle' then
    begin
      // use Node.ChildNodes['type'], Node.ChildNodes['model'],
      // and Node.ChildNodes['number'] as needed...
    end;
  end;
end;
11

вы можете прочитать XML-файл с помощью блока MSXML (или любого другого синтаксического анализатора XML).

Он дает вам древовидную структуру, представляющую XML-файл. Где транспортное средство-верхний узел, а остальные три-дочерние узлы.

каждый узел имеет свойство text, которое можно использовать для получения значения. Это можно назначить текстовым полям в форме.

код:

uses
  ActiveX,
  MSXML;

procedure TForm1.ReadFromXML(const AFilename: string);
var
  doc : IXMLDOMDocument;
  node : IXMLDomNode;

begin
  CoInitialize; // Needs to be called once before using CoDOMDocument.Create;
  if not FileExists(AFileName) then 
    Exit; // Add proper Error handling.

  doc := CoDOMDocument.Create;
  doc.load(AFileName);

  if (doc.documentElement = nil) or (doc.documentElement.nodeName <> 'vehicle') then
    Exit; // Add proper Error handling.

  node := doc.documentElement.firstChild;
  while node<>nil do begin
    if node.nodeName = 'model' then
      txtModel.Text := node.text;
    if node.nodeName = 'number' then
      txtNumber.Text := node.text;
    if node.nodeName = 'type' then
      txtType.Text := node.text;
    node := node.nextSibling;
  end;
end;
4