Как использовать Oracle SQL developer для запуска хранимых процедур?

мало того, что есть способ сделать это, есть несколько способов сделать это (что я признаю не очень Питоническим, но тогда SQL*Developer написан на Java ).

у меня есть процедура с этой подписью: get_maxsal_by_dept( dno number, maxsal out number).

я выделяю его в навигаторе объектов SQL * Developer, вызываю меню правой кнопкой мыши и выбираю выполнить. (Я мог бы использовать ctrl+F11.) Это порождает всплывающее окно с тестовым жгутом. (Примечание: если хранимая процедура живет в пакете, вам нужно щелкнуть правой кнопкой мыши пакет,не значок под пакетом, содержащий имя процедуры; затем вы выберете sproc из списка "цель" пакета, когда появится тестовая проводка.) В этом примере теста будет выглядеть следующим образом:

DECLARE
  DNO NUMBER;
  MAXSAL NUMBER;
BEGIN
  DNO := NULL;

  GET_MAXSAL_BY_DEPT(
    DNO => DNO,
    MAXSAL => MAXSAL
  );
  DBMS_OUTPUT.PUT_LINE('MAXSAL = ' || MAXSAL);
END;

я установил переменную DNO в 50 и нажмите OK. В Running - Log панель (нижний правый угол если вы не закрыли/не переместили / не скрыли его), я вижу следующий вывод:

Connecting to the database apc.
MAXSAL = 4500
Process exited.
Disconnecting from the database apc. 

справедливости ради бегун менее дружелюбен для функций, которые возвращают курсор Ref, как этот:get_emps_by_dept (dno number) return sys_refcursor.

DECLARE
  DNO NUMBER;
  v_Return sys_refcursor;
BEGIN
  DNO := 50;

  v_Return := GET_EMPS_BY_DEPT(
    DNO => DNO
  );
  -- Modify the code to output the variable
  -- DBMS_OUTPUT.PUT_LINE('v_Return = ' || v_Return);
END;

однако, по крайней мере, это дает возможность сохранить любые изменения в файле, поэтому мы можем сохранить наши инвестиции в настройку жгута...

DECLARE
  DNO NUMBER;
  v_Return sys_refcursor;
  v_rec emp%rowtype;
BEGIN
  DNO := 50;

  v_Return := GET_EMPS_BY_DEPT(
    DNO => DNO
  );

  loop
    fetch v_Return into v_rec;
    exit when v_Return%notfound;
    DBMS_OUTPUT.PUT_LINE('name = ' || v_rec.ename);
  end loop;
END;

выход из того же места:

Connecting to the database apc.
name = TRICHLER
name = VERREYNNE
name = FEUERSTEIN
name = PODER
Process exited.
Disconnecting from the database apc. 

кроме того, мы можем использовать старый В SQLплюс команды в SQLразработчик листе:

var rc refcursor 
exec :rc := get_emps_by_dept(30) 
print rc

в этом случае результат отображается в Результат Работы Скрипта панель (расположение по умолчанию-вкладка справа от результаты tab).

самые ранние версии IDE не очень поддерживали SQL * Plus. Однако все вышеперечисленные команды поддерживаются начиная с версии 1.2.1. См.матрица в онлайн-документации дополнительные информация.

" когда я печатаю просто var rc refcursor; и выберите его и запустите, я получу это ошибка (GUI):"

есть функция - или ошибка-в том, как рабочий лист интерпретирует SQLкоманды плюс. Он предполагает SQLPlus являются частью скрипта. Итак, если мы введем строку SQL * Plus, скажем var rc refcursor и нажмите кнопку Execute Statement (или F9 ) рабочий лист швыряет ORA-900 потому что это не исполняемый файл заявление т. е. это не SQL . Что нам нужно сделать, это нажать Run Script (или Ф5), даже для одной строки SQL*Plus.

"я так близко ... пожалуйста помочь."

вы программы процедура с подписью пяти обязательных параметров. Вы получаете ошибку, потому что вы вызываете ее как функцию и только с одним параметром:

exec :rc := get_account(1)

что вам нужно, это что-то примерно следующий. Я использовал названную нотацию для ясности.

var ret1 number
var tran_cnt number
var msg_cnt number
var rc refcursor

exec :tran_cnt := 0
exec :msg_cnt := 123

exec get_account (Vret_val => :ret1, 
                  Vtran_count => :tran_cnt, 
                  Vmessage_count => :msg_cnt, 
                  Vaccount_id   => 1,
                  rc1 => :rc )

print tran_count 
print rc

то есть вам нужна переменная для каждого параметра OUT или IN OUT. В параметрах можно передавать как литералы. Первые две инструкции EXEC присваивают значения паре параметров IN OUT. Третий исполнитель вызывает процедуру. Процедуры не возвращают значение (в отличие от функций), поэтому мы не используем синтаксис присваивания. Наконец, этот скрипт отображает значение нескольких переменных, сопоставленных с OUT параметры.