Как исправить / сдвинуть время субтитров в файлах SRT (SubRip)?

как исправить / сдвинуть время субтитров вперед и назад? Формат времени субтитров выглядит следующим образом: 00:00:52,656 --> 00:00:56,326

если субтитры и аудио не синхронизированы, например, субтитры отображаются перед голосом / аудио, а затем все время строк субтитров (формат времени:00:00:52,656 --> 00:00:56,326) следует исправить.

Итак, если время всех строк субтитров должно быть изменено / сдвинуто на 2 сек. тогда вперед, на этот раз для строки субтитров:00:00:52,656 --> 00:00:56,326 следует изменить на: 00:00:54,656 --> 00:00:58,326.

и это относится ко всем временам в файле субтитров, а не только к одной строке текста/один раз.

пример того, как SubRip (.srt) файл выглядит так:

1
00:00:52,656 --> 00:00:56,326
Kanalska Zona: Panama

2
00:00:56,335 --> 00:00:59,755
Francuzi su pokušali da izgrade
kanal pre Amerikanaca.
6
delphi shift subtitle

1 ответов

при условии, что формат каждой строки в ваш вклад всегда 00:00:00,000 --> 00:00:00,000, тогда эта процедура преобразует время строки в TDateTime добавить или вычесть сдвиг, и измените строку:

procedure ShiftSubtitleTimes(Lines: TStrings; Diff: TTime);
var
  FS: TFormatSettings;
  I: Integer;
  T1: TDateTime;
  T2: TDateTime;
begin
  // Ensure using the correct time separator
  FS.TimeSeparator := ':';
  // Parse each line separately
  for I := 0 to Lines.Count - 1 do
  begin
    // Convert the two time strings to time values
    if not TryStrToTime(Copy(Lines[I], 1, 8), T1, FS) then
      // But skip line in case of wrong format
      Continue;
    T1 := T1 + StrToInt(Copy(Lines[I], 10, 3)) / MSecsPerDay;
    T2 := StrToTime(Copy(Lines[I], 18, 8), FS);
    T2 := T2 + StrToInt(Copy(Lines[I], 27, 3)) / MSecsPerDay;
    // Add the shift
    T1 := T1 + Diff;
    T2 := T2 + Diff;
    // Rewrite the line
    Lines[I] := FormatDateTime('hh:nn:ss,zzz --> ', T1, FS) +
      FormatDateTime('hh:nn:ss,zzz', T2, FS);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  List: TStringList;
begin
  List := TStringList.Create;
  try
    List.LoadFromFile('Filename.dat');
    Memo1.Lines.Add('Input:');
    Memo1.Lines.AddStrings(List);
    Memo1.Lines.Add('');
    // Shift 3,5 seconds backwards:
    ShiftSubtitleTimes(List, -3.5 / SecsPerDay);  
    Memo1.Lines.Add('Output:');
    Memo1.Lines.AddStrings(List);
  finally
    List.Free;
  end;
end;

enter image description here

Edit:

из-за вашего редактирования теперь ввод может содержать "неправильные" строки, которые также не нуждаются в преобразовании.

7