Как изменить схему всех таблиц, представлений и хранимых процедур в MSSQL

недавно у нас были проблемы на нашем сервере баз данных, и после долгих усилий было решено изменить сервер баз данных. Таким образом, нам удалось восстановить базу данных на другом сервере, изменить строку подключения и т. д. Все шло по плану, пока мы не попытались получить доступ к веб-сайту из веб-браузера.

мы начали получать сообщения о том, что объекты базы данных не найден. Позже мы узнали, что это произошло в результате изменения имени схемы. Так как есть сотни объектов базы данных (таблицы, представления и хранимые процедуры) в базе данных Kentico, невозможно изменить их все вручную, один за другим. Есть ли практический способ сделать это?

23
database-migration database-schema kentico sql sql-server-2008

4 ответов

Да, это возможно.

изменить схему объекта базы данных необходимо выполнить следующий SQL-скрипт:

ALTER SCHEMA NewSchemaName TRANSFER OldSchemaName.ObjectName

где ObjectName может быть имя таблицы, представления или хранимой процедуры. Проблема заключается в получении списка всех объектов базы данных с заданным именем shcema. К счастью, есть системная таблица с именем sys.Объекты, хранящие все объекты базы данных. Следующий запрос создаст все необходимые сценарии SQL для завершения задачи:

SELECT 'ALTER SCHEMA NewSchemaName TRANSFER [' + SysSchemas.Name + '].[' + DbObjects.Name + '];'
FROM sys.Objects DbObjects
INNER JOIN sys.Schemas SysSchemas ON DbObjects.schema_id = SysSchemas.schema_id
WHERE SysSchemas.Name = 'OldSchemaName'
AND (DbObjects.Type IN ('U', 'P', 'V'))

где тип " U "обозначает пользовательские таблицы," V "обозначает представления, а" P " обозначает хранимые процедуры.

запуск вышеуказанного скрипта создаст команды SQL, необходимые для передачи объектов из одной схемы в другую. Что-то вроде этого:--6--> 

ALTER SCHEMA NewSchemaName TRANSFER OldSchemaName.CONTENT_KBArticle;
ALTER SCHEMA NewSchemaName TRANSFER OldSchemaName.Proc_Analytics_Statistics_Delete;
ALTER SCHEMA NewSchemaName TRANSFER OldSchemaName.Proc_CMS_QueryProvider_Select;
ALTER SCHEMA NewSchemaName TRANSFER OldSchemaName.COM_ShoppingCartSKU;
ALTER SCHEMA NewSchemaName TRANSFER OldSchemaName.CMS_WebPart;
ALTER SCHEMA NewSchemaName TRANSFER OldSchemaName.Polls_PollAnswer;

Теперь вы можете запустить все эти сгенерированные запросы для завершения операции перевода.

81

вот SQL, который я запустил, чтобы переместить все таблицы в моей базе данных( разбросанные по нескольким схемам) в схему" dbo":

DECLARE 
    @currentSchemaName nvarchar(200),
    @tableName nvarchar(200)

DECLARE tableCursor CURSOR FAST_FORWARD FOR 
SELECT TABLE_SCHEMA, TABLE_NAME
FROM information_schema.tables
ORDER BY 1, 2

DECLARE @SQL nvarchar(400)

OPEN tableCursor 
FETCH NEXT FROM tableCursor INTO @currentSchemaName, @tableName

WHILE @@FETCH_STATUS = 0
BEGIN
    SET @SQL = 'ALTER SCHEMA dbo TRANSFER ' + @currentSchemaName + '.' + @tableName
    PRINT @SQL

    EXEC (@SQL)

    FETCH NEXT FROM tableCursor INTO @currentSchemaName, @tableName
END

CLOSE tableCursor 
DEALLOCATE tableCursor

Фух!

3

Спасибо за совет.. Вот мое обновление к тому же, где я добавил crlf для вывода, а также поставил скобки вокруг SchemaName и ObjectName, потому что некоторые из объектов имели " - " в имени, и скобки решили эту ошибку именования.

SELECT 'ALTER SCHEMA NewSchemaName TRANSFER [' + SysSchemas.Name + '].[' +      DbObjects.Name + '];'
+ CHAR(13)+ CHAR(10)+ 'GO '+ CHAR(13)+ CHAR(10)
FROM sys.Objects DbObjects
INNER JOIN sys.Schemas SysSchemas ON DbObjects.schema_id =     SysSchemas.schema_id
WHERE SysSchemas.Name = 'OldSchemaName'
AND (DbObjects.Type IN ('U', 'P', 'V'))
2

вы можете использовать следующий скрипт, просто копировать/вставить для всех объектов

Примечание: вам нужно изменить имена схем в скрипт !

DECLARE @OldSchema VARCHAR(200)
DECLARE @NewSchema VARCHAR(200)
DECLARE @SQL nvarchar(4000)
SET @OldSchema = 'dbo'
SET @NewSchema = 'Inf'

DECLARE tableCursor CURSOR FAST_FORWARD FOR 
    SELECT 'ALTER SCHEMA  ['+ @NewSchema +'] TRANSFER [' + SysSchemas.Name + '].[' + DbObjects.Name + '];' AS Cmd
    FROM sys.Objects DbObjects
    INNER JOIN sys.Schemas SysSchemas ON DbObjects.schema_id = SysSchemas.schema_id
    WHERE SysSchemas.Name = @OldSchema
    AND (DbObjects.Type IN ('U', 'P', 'V'))
OPEN tableCursor 
FETCH NEXT FROM tableCursor INTO  @SQL
WHILE @@FETCH_STATUS = 0
BEGIN
    PRINT @SQL
    EXEC (@SQL)
    FETCH NEXT FROM tableCursor INTO  @SQL
END
CLOSE tableCursor 
DEALLOCATE tableCursor 
PRINT '*** Finished ***'
1