Как извлечь строку между соответствующими фигурными скобками в Perl?

мой входной файл выглядит следующим образом:

HEADER 
{ABC|*|DEF {GHI 0 1 0} {{Points {}}}}

{ABC|*|DEF {GHI 0 2 0} {{Points {}}}}

{ABC|*|XYZ:abc:def {GHI 0 22 0} {{Points {{F1 1.1} {F2 1.2} {F3 1.3} {F4 1.4}}}}}

{ABC|*|XYZ:ghi:jkl {JKL 0 372 0} {{Points {}}}}

{ABC|*|XYZ:mno:pqr {GHI 0 34 0} {{Points {}}}}

{
    ABC|*|XYZ:abc:pqr {GHI 0 68 0}
        {{Points {{F1 11.11} {F2 12.10} {F3 14.11} {F4 16.23}}}}
        }
TRAILER

Я хочу, чтобы извлечь файл в массив, как показано ниже :

$array[0] = "{ABC|*|DEF {GHI 0 1 0} {{Points {}}}}"

$array[1] = "{ABC|*|DEF {GHI 0 2 0} {{Points {}}}}"

$array[2] = "{ABC|*|XYZ:abc:def {GHI 0 22 0} {{Points {{F1 1.1} {F2 1.2} {F3 1.3} {F4 1.4}}}}}"

..
..

$array[5] = "{
    ABC|*|XYZ:abc:pqr {GHI 0 68 0}
        {{Points {{F1 11.11} {F2 12.10} {F3 14.11} {F4 16.23}}}}
        }"

что означает, что мне нужно сопоставить первую открывающую фигурную скобку с ее закрывающей фигурной скобкой и извлечь строку между ними.

Я проверил ссылку ниже, но это не относится к моему вопросу. регулярное выражение, чтобы получить строку между фигурными скобками "{я хочу, что между фигурными скобками}"

Я стараюсь, но очень поможет, если кто-то может помочь мне с их опытом ...

спасибо Шри. ..

7 ответов


это, безусловно, можно сделать с регулярным выражением, по крайней мере, в современных версиях Perl:

my @array = $str =~ /( \{ (?: [^{}]* | (?0) )* \} )/xg;

print join "\n" => @array;

регулярное выражение соответствует блоку фигурной скобки, который содержит либо не фигурные символы скобки, либо рекурсию в себя (соответствует вложенным фигурным скобкам)

Edit: приведенный выше код работает в Perl 5.10+, для более ранних версий рекурсия немного более подробна:

my $re; $re = qr/ \{ (?: [^{}]* | (??{$re}) )* \} /x;

my @array = $str =~ /$re/xg;

использовать Text:: Balanced


Я поддерживаю предложение ysth использовать Text::Balanced модуль. Несколько строк-и вы на своем пути.

use strict;
use warnings;
use Text::Balanced qw/extract_multiple extract_bracketed/;

my $file;
open my $fileHandle, '<', 'file.txt';

{ 
  local $/ = undef; # or use File::Slurp
  $file = <$fileHandle>;
}

close $fileHandle;

my @array = extract_multiple(
                               $file,
                               [ sub{extract_bracketed($_[0], '{}')},],
                               undef,
                               1
                            );

print $_,"\n" foreach @array;

выход

{ABC|*|DEF {GHI 0 1 0} {{Points {}}}}
{ABC|*|DEF {GHI 0 2 0} {{Points {}}}}
{ABC|*|XYZ:abc:def {GHI 0 22 0} {{Points {{F1 1.1} {F2 1.2} {F3 1.3} {F4 1.4}}}}}
{ABC|*|XYZ:ghi:jkl {JKL 0 372 0} {{Points {}}}}
{ABC|*|XYZ:mno:pqr {GHI 0 34 0} {{Points {}}}}
{
    ABC|*|XYZ:abc:pqr {GHI 0 68 0}
        {{Points {{F1 11.11} {F2 12.10} {F3 14.11} {F4 16.23}}}}
        }

вы всегда можете рассчитывать скобки:

my $depth = 0;
my $out = "";
my @list=();
foreach my $fr (split(/([{}])/,$data)) {
    $out .= $fr;
    if($fr eq '{') {
        $depth ++;
    }
    elsif($fr eq '}') {
        $depth --;
        if($depth ==0) {
            $out =~ s/^.*?({.*}).*$//s; # trim
            push @list, $out;
            $out = "";
        }
    }
}
print join("\n==================\n",@list);

Это старый, простой стиль Perl (и, вероятно, уродливый).


Я не думаю, что чистые регулярные выражения - это то, что вы хотите использовать здесь (IMHO это может даже не быть разбираемым с помощью regex).

вместо этого создайте небольшой парсер, подобный тому, что показано здесь:http://www.perlmonks.org/?node_id=308039 (см. ответ shotgunefx (Parson) от 18 ноября 2003 года в 18:29 UTC)

обновление кажется, это может быть выполнимо с регулярным выражением - я видел ссылку на соответствующие вложенные скобки в Использование Регулярных Выражения (которая доступна в Google книгах и, таким образом, может быть погуглила для Если у вас нет книги - см. Главу 5, раздел "сопоставление сбалансированных наборов скобок")


вы гораздо лучше использовать государственную машину, чем regex для этого типа анализа.


регулярные выражения на самом деле очень плохо для парных скобок. В зависимости от того, насколько глубоко вы хотите пойти, вы можете написать полную грамматику (что намного проще, чем кажется!) for Parse:: RecDescent. Или, если вы просто хотите получить блоки, найдите открытие " {"метки и закрытие"} " и просто подсчитайте, сколько из них открыто в любой момент времени.