Как определить отступы в vim на основе фигурных скобок?

я использую https://github.com/cakebaker/scss-syntax.vim для подсветки синтаксиса SCSS (или Сасс) файлы на vim, который очень хорошо работает для подсветки синтаксиса. Однако плагин не поставляется с файлом отступа, и у меня возникли проблемы с его написанием.

Я хотел бы установить отступ, чтобы выглядеть так:

enter image description here

однако, если я это сделаю gg=G, I получить:

enter image description here

Я подозреваю, что он не понимает вложенный отступ на основе фигурных скобок. Я пробовал все различные комбинации

set cindent

set nocindent

set autoindent

set smartindent

и попытался использовать код клавиша Tab == 4 пробела и автоматический отступ после фигурных скобок в Vim , в том числе

set tabstop=2

set shiftwidth=2

set expandtab

...но вложенные скобки отступа никогда не работает.

Я считаю, что я мог бы написать пользовательский файл отступа, и все, что мне нужно, это отступ на основе фигурных скобок с вложенными уровнями. Как мне это сделать? Если у кого-то есть файл отступов для типов файлов с аналогичным синтаксисом, это тоже будет здорово.

1 ответов


это быстрый взлом, основанный на встроенном коде отступа perl (в indent/perl.vim). Надеюсь, вы можете использовать его, чтобы получить то, что вы хотите сделать. Дополнительные сведения см. в более подробных комментариях в коде отступа perl или в другом файле каталога отступов.

setlocal indentexpr=GetMyIndent()
function! GetMyIndent()
    let cline = getline(v:lnum)

    " Find a non-blank line above the current line.
    let lnum = prevnonblank(v:lnum - 1)
    " Hit the start of the file, use zero indent.
    if lnum == 0
        return 0
    endif
    let line = getline(lnum)
    let ind = indent(lnum)

    " Indent blocks enclosed by {}, (), or []
    " Find a real opening brace
    let bracepos = match(line, '[(){}\[\]]', matchend(line, '^\s*[)}\]]'))
    while bracepos != -1
        let brace = strpart(line, bracepos, 1)
        if brace == '(' || brace == '{' || brace == '['
            let ind = ind + &sw
        else
            let ind = ind - &sw
        endif
        let bracepos = match(line, '[(){}\[\]]', bracepos + 1)
    endwhile
    let bracepos = matchend(cline, '^\s*[)}\]]')
    if bracepos != -1
        let ind = ind - &sw
    endif

    return ind
endfunction

сохраните файл под именем ~/.vim/indent/something.vim здесь something ваш тип файла (replace ~/.vim путь vimfiles если вы на Windows.

вы также можете вставить это в начало файла (но только если нет другого объявления отступа, которое может быть загружено первым):

" Only load this indent file when no other was loaded.
if exists("b:did_indent")
    finish
endif
let b:did_indent = 1