Как отправить запрос HTTP POST в Delphi с помощью wininet api

Я пытаюсь сделать HTTP-запросы из Delphi, используя функции WinInet.

пока у меня есть:

function request:string;
var
  hNet,hURL,hRequest: HINTERNET;
begin
  hNet := InternetOpen(PChar('User Agent'),INTERNET_OPEN_TYPE_PRECONFIG or INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  if Assigned(hNet) then 
  begin
  try
    hURL := InternetConnect(hNet,PChar('http://example.com'),INTERNET_DEFAULT_HTTP_PORT,nil,nil,INTERNET_SERVICE_HTTP,0,DWORD(0));
    if(hURL<>nil) then
      hRequest := HttpOpenRequest(hURL, 'POST', PChar('param=value'),'HTTP/1.0',PChar(''), nil, INTERNET_FLAG_RELOAD or INTERNET_FLAG_PRAGMA_NOCACHE,0);
    if(hRequest<>nil) then
      HttpSendRequest(hRequest, nil, 0, nil, 0);
    InternetCloseHandle(hNet);
  except
    on E : Exception do
      ShowMessage(E.ClassName+' error raised, with message : '+E.Message);
  end;
  end
end;

но это ничего не делает (я нюхаю сетевой http-трафик, чтобы увидеть, работает ли он). Я успешно использовал InternetOpenURL, но мне также нужно отправить запрос POST, и эта функция этого не делает.

может кто-то показать мне простой пример? В результате я хочу получить страницу ответа http в var как строку.

15
delphi http post request wininet

3 ответов

Я получил всю часть url/filename перепутал с предыдущим кодом. Я использую это от Джеффа деворе Теперь и он нормально работает:

function request(const AUrl, AData: AnsiString; blnSSL: Boolean = True): AnsiString;
var
  aBuffer     : Array[0..4096] of Char;
  Header      : TStringStream;
  BufStream   : TMemoryStream;
  sMethod     : AnsiString;
  BytesRead   : Cardinal;
  pSession    : HINTERNET;
  pConnection : HINTERNET;
  pRequest    : HINTERNET;
  parsedURL   : TStringArray;
  port        : Integer;
  flags       : DWord;
begin
  ParsedUrl := ParseUrl(AUrl);

  Result := '';

  pSession := InternetOpen(nil, INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);

  if Assigned(pSession) then
  try
    if blnSSL then
      Port := INTERNET_DEFAULT_HTTPS_PORT
    else
      Port := INTERNET_DEFAULT_HTTP_PORT;
    pConnection := InternetConnect(pSession, PChar(ParsedUrl[0]), port, nil, nil, INTERNET_SERVICE_HTTP, 0, 0);

    if Assigned(pConnection) then
    try
      if (AData = '') then
        sMethod := 'GET'
      else
        sMethod := 'POST';

      if blnSSL then
        flags := INTERNET_FLAG_SECURE or INTERNET_FLAG_KEEP_CONNECTION
      else
        flags := INTERNET_SERVICE_HTTP;

      pRequest := HTTPOpenRequest(pConnection, PChar(sMethod), PChar(ParsedUrl[1]), nil, nil, nil, flags, 0);

      if Assigned(pRequest) then
      try
        Header := TStringStream.Create('');
        try
          with Header do
          begin
            WriteString('Host: ' + ParsedUrl[0] + sLineBreak);
            WriteString('User-Agent: Custom program 1.0'+SLineBreak);
            WriteString('Accept: text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8'+SLineBreak);
            WriteString('Accept-Language: en-us,en;q=0.5' + SLineBreak);
            WriteString('Accept-Charset: ISO-8859-1,utf-8;q=0.7,*;q=0.7'+SLineBreak);
            WriteString('Keep-Alive: 300'+ SLineBreak);
            WriteString('Connection: keep-alive'+ SlineBreak+SLineBreak);
          end;

          HttpAddRequestHeaders(pRequest, PChar(Header.DataString), Length(Header.DataString), HTTP_ADDREQ_FLAG_ADD);

          if HTTPSendRequest(pRequest, nil, 0, Pointer(AData), Length(AData)) then
          begin
            BufStream := TMemoryStream.Create;
            try
              while InternetReadFile(pRequest, @aBuffer, SizeOf(aBuffer), BytesRead) do
              begin
                if (BytesRead = 0) then Break;
                BufStream.Write(aBuffer, BytesRead);
              end;

              aBuffer[0] := #0;
              BufStream.Write(aBuffer, 1);
              Result := PChar(BufStream.Memory);
            finally
              BufStream.Free;
            end;
          end;
        finally
          Header.Free;
        end;
      finally
        InternetCloseHandle(pRequest);
      end;
    finally
      InternetCloseHandle(pConnection);
    end;
  finally
    InternetCloseHandle(pSession);
  end;
end;

ParseUrl-это функция, которая разбивает URL-адрес на "имя хоста / имя файла", а TStringArray-массив строк. Мне все еще нужно просмотреть код завтра, но он выглядит нормально, и в моем сниффере я видел отправленные данные и заголовки post.

10

лично я предпочитаю использовать синапс библиотека для всей моей работы TCP / IP. Например, простой HTTP-пост может быть закодирован как:

uses
  httpsend;

function testpost;
begin
  stm := tStringstream.create('param=value');
  try
    HttpPostBinary('http://example.com',Stm);
  finally
    stm.free;
  end;
end;

библиотека хорошо написана и очень проста в изменении в соответствии с вашими конкретными требованиями. Последняя версия subversion работает без каких-либо проблем как для Delphi 2009, так и для Delphi 2010. Эта структура не основана на компонентах, а представляет собой ряд классов и процедур, которые хорошо работают в многопоточной среде.

2

третий параметр (lpszObjectName) для HttpOpenRequest должен быть URL-адресом вы хотите заказать. Вот почему в документации пятый параметр (lpszReferer) описывается как "указатель на строку с нулевым завершением, которая указывает URL-адрес документа, из которого был получен URL-адрес в запросе (lpszObjectName)."

опубликованные данные отправляются с HttpSendRequest; параметр lpOptional описывается следующим образом:

указатель на буфер, содержащий любые дополнительные данные для отправки сразу после заголовков запроса. Этот параметр обычно используется для операций POST и PUT. Необязательными данными могут быть ресурс или информация, отправляемая на сервер. Этот параметр может иметь значение NULL, если нет дополнительных данных для отправки.

второй параметр InternetOpen должно быть только имя сервера; он не должен включать протокол. Протокол укажите с шестым параметром.

после того, как вы отправили запрос, вы можете прочитать ответ с InternetReadFile и InternetQueryDataAvailable.

не просто проверьте, возвращают ли функции API ноль, а затем перейдите к следующей строке. Если они потерпят неудачу, позвоните GetLastError чтобы выяснить, почему. Код, который вы опубликовали, не будет вызывать исключений, поэтому бесполезно его ловить. (И глупо "обращаться" с ними так, как вы это делаете. Не ловите исключение что ты еще не знаешь, как это исправить. Пусть все остальное достанется звонящему или звонящему и т. д.)

1