Как перебирать хэш (хэшей) в Perl?

У меня есть хэш, где значения ключей и другие хэши.

пример: {'key' => {'key2' => {'key3' => 'value'}}}

Как я могу перебирать эту структуру?

16
hash perl perl-data-structures

9 ответов

это то, что вы хотите? (непроверено)

sub for_hash {
    my ($hash, $fn) = @_;
    while (my ($key, $value) = each %$hash) {
        if ('HASH' eq ref $value) {
            for_hash $value, $fn;
        }
        else {
            $fn->($value);
        }
    }
}

my $example = {'key' => {'key2' => {'key3' => 'value'}}};
for_hash $example, sub {
    my ($value) = @_;
    # Do something with $value...
};
12

этот ответ основывается на идее Дейва Хинтона, а именно: написать подпрограмму общего назначения для хеш-структуры. Такой хэш-ходок берет ссылку на код и просто вызывает этот код для каждого листового узла в хэше.

при таком подходе один и тот же хэш-Уолкер может использоваться для многих вещей, в зависимости от того, какой обратный вызов мы ему даем. Для еще большей гибкости вам нужно будет передать два обратного вызова - один для вызова, когда значение является хэш-ссылкой и другое для вызова, когда это обычное скалярное значение. Подобные стратегии более подробно рассматриваются в превосходной книге Марка Джейсона Доминуса"Высший Порядок Perl.

use strict;
use warnings;

sub hash_walk {
    my ($hash, $key_list, $callback) = @_;
    while (my ($k, $v) = each %$hash) {
        # Keep track of the hierarchy of keys, in case
        # our callback needs it.
        push @$key_list, $k;

        if (ref($v) eq 'HASH') {
            # Recurse.
            hash_walk($v, $key_list, $callback);
        }
        else {
            # Otherwise, invoke our callback, passing it
            # the current key and value, along with the
            # full parentage of that key.
            $callback->($k, $v, $key_list);
        }

        pop @$key_list;
    }
}

my %data = (
    a => {
        ab => 1,
        ac => 2,
        ad => {
            ada => 3,
            adb => 4,
            adc => {
                adca => 5,
                adcb => 6,
            },
        },
    },
    b => 7,
    c => {
        ca => 8,
        cb => {
            cba => 9,
            cbb => 10,
        },
    },
);

sub print_keys_and_value {
    my ($k, $v, $key_list) = @_;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $v, "@$key_list";
}

hash_walk(\%data, [], \&print_keys_and_value);
23

этот пост могут быть полезны.

foreach my $key (keys %hash) {
    foreach my $key2 (keys %{ $hash{$key} }) {
        foreach my $key3 (keys %{ $hash{$key}{$key2} }) {
            $value = $hash{$key}{$key2}->{$key3};
            # .
            # .
            # Do something with $value
            # .
            # .
            # .
        }
    }
}
7

предыдущие ответы показывают, как свернуть собственное решение, что хорошо сделать хотя бы один раз, чтобы вы поняли, как работают ссылки perl и структуры данных. Вы должны обязательно прочитать perldoc perldsc и perldoc perlref Если вы еще не.

однако вам не нужно писать свое собственное решение - уже есть модуль на CPAN, который будет перебирать произвольно сложные структуры данных для вас: Сведения::Посетитель.

7

кроме того, пожалуйста, прочитайте perldoc perldsc. Вы можете узнать о хэшах в глубине

5

Это не совсем новый ответ, но я хотел поделиться тем, как сделать больше, чем просто распечатайте все хэш-значения рекурсивно, но и при необходимости измените их.

вот моя небольшая модификация ответа dave4420, в которой значение передается обратному вызову в качестве ссылки, поэтому мой обратный вызов затем процедура может изменить каждое значение в хэше.

мне также пришлось перестроить хэш, поскольку каждый цикл создает копии не ссылки.

sub hash_walk {
   my $self = shift;
    my ($hash, $key_list, $callback) = @_;
    while (my ($k, $v) = each %$hash) {
        # Keep track of the hierarchy of keys, in case
        # our callback needs it.
        push @$key_list, $k;

        if (ref($v) eq 'HASH') {
            # Recurse.
            $self->hash_walk($v, $key_list, $callback);
        }
        else {
            # Otherwise, invoke our callback, passing it
            # the current key and value, along with the
            # full parentage of that key.
            $callback->($k, $v, $key_list);
        }

        pop @$key_list;
        # Replace old hash values with the new ones
        $hash->{$k} = $v;
    }
}

hash_walk(\%prj, [], \&replace_all_val_strings);

sub replace_all_val_strings {
    my ($k, $v, $key_list) = @_;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $$v, "@$key_list";
    $$v =~ s/oldstr/newstr/;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $$v, "@$key_list";
}
1

вам придется пройти через него дважды. т. е.

while ( ($family, $roles) = each %HoH ) {
   print "$family: ";
   while ( ($role, $person) = each %$roles ) {
      print "$role=$person ";
   }
print "\n";
}
0
foreach my $keyname (keys(%foo) {
  my $subhash = $foo{$keyname};
  # stuff with $subhash as the value at $keyname
}
0

если вы используете perl в качестве "интерпретатора CPAN", то в дополнение к Data::Visitor и Data::Deep есть супер простой Data::Traverse:

use Data::Traverse qw(traverse);

my %test_hash = (
  q => [qw/1 2 3 4/],
  w => [qw/4 6 5 7/],
  e => ["8"],
  r => { 
         r => "9"  ,
         t => "10" ,
         y => "11" ,
      } ,
);

traverse { next if /ARRAY/; print "$a => $b\n" if /HASH/ && $b > 8 } \%test_hash;

выход:

t => 10
y => 11

$a и $b рассматриваются как специальные переменные здесь (как с sort()) внутри . Data::Traverse - очень простой, но чрезвычайно полезный модуль без неосновных зависимостей.

0