Как передать параметры командной строки в пакетный файл?

Мне нужно передать id и пароль в файл cmd (или bat) во время запуска, а не жестко закодировать их в файл.

вот как выглядит командная строка:

test.cmd admin [email protected] > test-log.txt

15 ответов


еще один полезный совет-использовать %* означает "все". Например:

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

при запуске:

test-command admin password foo bar

вышеуказанный пакетный файл будет запущен:

fake-command /u admin /p password foo bar

возможно, синтаксис немного неправильный, но это общая идея.


вот как я это делаю.

@fake-command /u %1 /p %2

вот как выглядит командная строка:

test.cmd admin [email protected] > test-log.txt

%1 применяется к первому параметру %2 (и вот сложная часть) применяется ко второму. Таким образом, можно передать до 9 параметров.


Если вы хотите грамотно обрабатывать отсутствующие параметры, вы можете сделать что-то вроде:

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

доступ к параметрам пакета может быть простым с %1, %2, ... %Или 9 %*,
но только если содержание простое.

нет простого способа для сложного содержимого, такого как "&"^&, так как невозможно получить доступ к %1 без возникновения ошибки.

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

линии расширяются до

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

и каждая строка терпит неудачу, как одна из & вне кавычек.

это можно решить с помощью чтения из временного файла a отметил вариант параметр.

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

фокус в том, чтобы включить echo on и разверните %1 после rem заявление (работает также с %2 .. %*).
Так даже "&"& можно было бы повторить, не производя ошибки, как это отмечается.

но иметь возможность перенаправлять вывод echo on, вам нужны два for-loops.

лишние символы * # используются, чтобы быть в безопасности от содержимого, как /? (показал бы помогите REM).
Или каретка ^ в конце строки может работать как многострочный символ, даже после rem.

затем чтение параметр rem вывод из файла, но осторожно.
FOR / F должен работать с отложенным расширением, иначе содержимое с "!- будут уничтожены.
После удаления дополнительных символов в param1 вы получили это.

и использовать param1 безопасным способом включите отложенное расширение.


да, и не забудьте использовать переменные типа %%1 при использовании if и for и банды.

если вы забыли дважды %, то вы будете подставлять в (возможно, null) аргументы командной строки, и вы получите некоторые довольно запутанные сообщения об ошибках.


нет необходимости усложнять ее. Это просто Команда %1 %2 параметры, например,

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

"пауза" отображает то, что сделал пакетный файл, и ждет, когда вы нажмете любую клавишу. Сохраните это как xx.bat в папке Windows.

чтобы использовать его, введите, например:

xx c:\f\*.* f:\sites

этот пакетный файл заботится обо всех необходимых параметрах, таких как копирование только файлов, которые являются более новыми и т. д. Я использовал его еще до Windows. Если вам нравится видеть имена файлов, поскольку они копируются, не включают


@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

Примечание: если "%1"=="" вызовет проблем, если %1 заключен в кавычки сам.

в этом случае используйте IF [%1]==[] или, в NT 4 (SP6) и выше, .


друг недавно спрашивал меня об этом предмете, поэтому я подумал, что опубликую, как я обрабатываю аргументы командной строки в пакетных файлах.

этот метод имеет немного накладных расходов, как вы увидите, но это делает мои пакетные файлы очень легко понять и быстро реализовать. А также поддержка следующих структур:

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

jist его оказывает :init, :parse и :main функции.

пример использование

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

шаблон.летучая мышь!--7-->

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

давайте оставим это простым.

здесь .файл cmd.

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

вот 3 вызова из командной строки.

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

это повторяет параметры пакета ( % * ) либо они цитируются, либо нет, а затем повторяет каждый параметр.


Я написал простой скрипт read_params, который можно вызвать как функцию (или external .bat) и поместит все переменные в текущую среду. Он не будет изменять исходные параметры, потому что функция является called с копией исходных параметров.

например, дана следующая команда:

myscript.bat some -random=43 extra -greeting="hello world" fluff

myscript.bat сможет использовать переменные после вызова функции:

call :read_params %*

echo %random%
echo %greeting%

здесь функция:

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

ограничения

  • невозможно загрузить аргументы без значения, например -force. Вы могли бы использовать -force=true но я не могу придумать способ разрешить пустые значения, не зная заранее список параметров, которые не будут иметь значения.

изменений

  • 2/18/2016
    • больше не требует задержки расширение
    • теперь работает с другими аргументами командной строки, ищем - перед параметрами.

для ссылки на переменную set в командной строке вам нужно будет использовать " %a%", например:

      set a=100 
      echo %a%  
      output = 100 

Примечание: это работает для Windows 7 pro.


создать новый пакетный файл (пример: openclass.bat) и напишите эту строку в файле:

java %~n1

затем поместите пакетный файл, скажем, в папку system32, перейдите в файл класса Java, щелкните правой кнопкой мыши, Свойства, откройте..., затем найдите свой пакетный файл, выберите его, и все...

это работает для меня.

PS: Я не могу найти способ закрыть окно cmd, когда я закрываю класс Java. Пока...


простое решение(хотя вопрос старый)

Test1.летучая мышь!--4-->

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.летучая мышь!--4-->

call "C:\Temp\Test1.bat" pass123

выход

YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

где YourLocalPath-текущий путь к каталогу.

чтобы все было просто, сохраните команду param в переменной и используйте переменную для сравнения.

его не просто просто написать, но его просто поддерживать, так что если позже какой-то другой человек или Вы читаете свой сценарий после длительного периода время, это будет легко понять и поддерживать.

чтобы написать встроенный код: см. другие ответы.


вдохновленный ответ в другом месте @Jon, я создал более общий алгоритм для извлечения именованных параметров, необязательных значений и переключателей.

предположим, что мы хотим реализовать программу foobar. Для этого требуется начальная команда. Он имеет необязательный параметр --foo С дополнительно value (который, конечно, не может быть другим параметром); если значение отсутствует, оно по умолчанию равно default. Он также имеет опционный параметр --bar что происходит требуются значение. Наконец он может взять флаг --baz не допускается значения. О, и эти параметры могут быть в любом порядке.

другими словами, это выглядит так:

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

вот решение:

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1
  • использовать SETLOCAL чтобы переменные не выходили в вызывающую среду.
  • не забудьте инициализировать переменные SET FOO=, etc. в случае если кто-то определил их в вызываю окружение.
  • использовать %~1 удалить кавычки.
  • использовать IF "%ARG%" == "", а не IF [%ARG%] == [], потому что [ и ] не играть будет вообще со значениями, заканчивающимися в пространстве.
  • даже если вы SHIFT внутри IF блок, текущие args, такие как %~1 не обновляйтесь, потому что они определяются, когда IF разбирается. Вы могли бы использовать %~1 и %~2 внутри IF блок, но это было бы запутанно, потому что у вас был SHIFT. Вы могли бы поставить SHIFT в конце блока для ясности, но это может потеряться и / или запутать людей. Так что "захват" %~1 и %~1 за пределами блока, кажется, лучше всего.
  • вы не хотите использовать параметр вместо необязательного значения другого параметра, поэтому вам нужно проверить IF NOT "%ARG:~0,2%" == "--".
  • будьте осторожны только в SHIFT когда вы использовать одним из параметров.
  • дублировать код SET FOO=%DEFAULT_FOO% - это прискорбно, но альтернативой было бы добавить IF "%FOO%" == "" SET FOO=%DEFAULT_FOO% за пределами IF NOT "%ARG%" == "" блок. Однако, потому что это все еще внутри IF "%PARAM%" == "--foo" блока %FOO% значение было бы оценено и установлено до того, как вы вошли в блок, поэтому вы никогда не обнаружите это и the