Как получить доступ к подсчетам тестов Junit в проекте конвейера Jenkins

чтобы расширить ответ @vikramsjn, вот что я использую, чтобы получить резюме теста в моем Jenkinsfile:

import hudson.tasks.test.AbstractTestResultAction
import hudson.model.Actionable

@NonCPS
def getTestSummary = { ->
    def testResultAction = currentBuild.rawBuild.getAction(AbstractTestResultAction.class)
    def summary = ""

    if (testResultAction != null) {
        def total = testResultAction.getTotalCount()
        def failed = testResultAction.getFailCount()
        def skipped = testResultAction.getSkipCount()

        summary = "Test results:\n\t"
        summary = summary + ("Passed: " + (total - failed - skipped))
        summary = summary + (", Failed: " + failed)
        summary = summary + (", Skipped: " + skipped)
    } else {
        summary = "No tests found"
    }
    return summary
}

затем я использую этот метод для создания экземпляра my testSummary переменной:

def testSummary = getTestSummary()

это вернет что-то похожее на:

"Test results:
     Passed: 123, Failed: 0, Skipped: 0"

прежде всего, спасибо за ответы выше. Они сэкономили мне много времени, я использовал предложенное решение в своем конвейере. Однако я не использовал "белый список", и он работает нормально. Я использую общие библиотеки для конвейера Дженкинса, и вот часть этой общей библиотеки с конвейером и использованием методов для получения подсчетов:

import hudson.model.*
import jenkins.model.*
import hudson.tasks.test.AbstractTestResultAction

def call(Closure body) {
    ...

    def emailTestReport = ""

    pipeline {
        ...

        stages{
            stage('Test'){
                ...
                post {
                    always {
                        junit 'tests.xml'

                        script {
                            AbstractTestResultAction testResultAction =  currentBuild.rawBuild.getAction(AbstractTestResultAction.class)
                            if (testResultAction != null) {
                                def totalNumberOfTests = testResultAction.totalCount
                                def failedNumberOfTests = testResultAction.failCount
                                def failedDiff = testResultAction.failureDiffString
                                def skippedNumberOfTests = testResultAction.skipCount
                                def passedNumberOfTests = totalNumberOfTests - failedNumberOfTests - skippedNumberOfTests
                                emailTestReport = "Tests Report:\n Passed: ${passedNumberOfTests}; Failed: ${failedNumberOfTests} ${failedDiff}; Skipped: ${skippedNumberOfTests}  out of ${totalNumberOfTests} "
                            }
                        }

                        mail to: 'example@email.com',
                        subject: "Tests are finished: ${currentBuild.fullDisplayName}",
                        body: "Tests are finished  ${env.BUILD_URL}\n  Test Report: ${emailTestReport} "
                    }

                }
            }
        }
    }
}

p.s. Если я создаю emailTestRepot как локальную переменную внутри скрипта "раздел", я получаю следующее исключение:

an exception which occurred:
    in field locals
    in field parent
    in field caller
    in field e
    in field program
    in field threads
    in object org.jenkinsci.plugins.workflow.cps.CpsThreadGroup@11cd92de
Caused: java.io.NotSerializableException: hudson.tasks.junit.TestResultAction
...

Я много боролся с попытками исправить это Java.Ио.NotSerializableException. Как я понял мне нужно использовать "белые списки", чтобы предотвратить NotSerializableException. Но я действительно не хотел этого делать, и когда я переместил "def emailTestReport" из конвейера, он работал просто отлично.