Как получить список запущенных сборок jenkins через groovy script?

Это не особенно эффективно (но гораздо эффективнее, чем использование API). Он распечатает все текущие сборки с помощью HTML-ссылки. Можно запустить в консоли скрипта или через scriptler.

def now = new Date()  // Get the current time
// Get a list of all running jobs
def buildingJobs = Jenkins.instance.getAllItems(Job.class).findAll { 
  it.isBuilding() }

buildingJobs.each { job->
    // Enumerate all runs
    allRuns = job._getRuns()
    allRuns.each { item ->
        // If NOT currently building... check the next build for this job
        if (!item.isBuilding()) return

        // Access and calculate time information for this build.
        def startedAt = new Date(item.getStartTimeInMillis())
        def duration_mins = ((now.getTime() - item.getStartTimeInMillis()) / 60000).intValue()

        estDurationMins = (item.getEstimatedDuration() / 60000).intValue()
        String jobname = item.getUrl()
        jobname = jobname.replaceAll('job/', '')  // Strip redundant folder info.

        println "${duration_mins.toString().padLeft(5)}/" +
            "${estDurationMins.toString().padLeft(4)}  - " +
            "<a href=${baseURL}${item.getUrl()}>${jobname}</a>"
    }
}

вы можете использовать REST API для получения списка запущенных сборок. Используя следующий url:

http://myjenkins/jenkins/computer/api/xml?depth=1

вы получите следующий ответ, который содержит <executor> элементы. Только выполняя построения есть <url> элемент внутри <executor>. Обратите внимание также, что выполняя построения и <idle>false</idle> значение:

<computerSet>
    <busyExecutors>1</busyExecutors>
    <computer>
        ...
        <executor>
            <idle>true</idle>
            <likelyStuck>false</likelyStuck>
            <number>0</number>
            <progress>-1</progress>
        </executor>
        <executor>
            <currentExecutable>
                <number>328</number>
                <!-- This is the url from the current running build -->
                <url>http://myJenkins/jenkins/job/someJob/328/</url>             
            </currentExecutable>
            <currentWorkUnit/>
            <idle>false</idle>
            <likelyStuck>false</likelyStuck>
            <number>1</number>
            <progress>24</progress>
        </executor>
        ...
    </computer> 
<computerSet>

следовательно, используйте REST API с XPath-выражения на url чтобы получить только запущенные сборки (обратите внимание, что &wrapper параметр-это имя корневого элемента xml, чтобы избежать ошибок при XPath-выражения не соответствует или возвращает более одного узла):

http://myJenkins/jenkins/computer/api/xml?depth=1&xpath=//url&wrapper=builds

вы получите что-то вроде:

<builds>
    <url>
http://myJenkins/jenkins/job/someJob/300/
    </url>
    <url>
http://myJenkins/jenkins/job/another/332/
    </url>
</builds>

так в Groovy вы можете получить REST API, проанализировать возвращенный Xml, а затем применить регулярное выражение к каждому <url> чтобы получить данные из запущенных сборок:

// get the xml from the rest api
def builds = 'http://myJenkins/jenkins/computer/api/xml?depth=1&xpath=//url&wrapper=builds'.toURL().text
// parse the xml result
def xml = new XmlSlurper().parseText(builds)
// for each url get the job name
def jobNames = xml.url.collect{ url ->
    // regex to get the jobName and a build number
    def group = (url =~ /.*\/job\/([^\/]+)\/(\d+)/)
    println group[0] // [http://myJenkins/jenkins/job/someJob/300, someJob, 300]
    def jobName = group[0][1]
    return jobName
    // to get the build number
    // def buildNr = group[0][2]
}
println jobNames