как получить значения POST в perl

Я пытаюсь настроить скрипт и должен получить значение POST из формы с помощью perl. У меня нет фона perl, но это довольно простая вещь, поэтому я думаю, что это не должно быть сложно.

это php-версия кода, который я хотел бы иметь в PERL:

<?php
$download = ($_POST['dl']) ? '1' : '0';
?>

Я знаю, что это может быть совсем не связано с версией PERL, но это может помочь мне догадаться, что именно я хочу сделать.

6
cgi perl

4 ответов

Ну, в этом случае, пожалуйста, посмотрите на этот простой код: это поможет вам:

#!/usr/bin/perl
use strict;
use warnings;
use CGI;
use CGI::Carp qw(fatalsToBrowser);

sub output_top($);
sub output_end($);
sub display_results($);
sub output_form($);

my $q = new CGI;

print $q->header();

# Output stylesheet, heading etc
output_top($q);

if ($q->param()) {
    # Parameters are defined, therefore the form has been submitted
    display_results($q);
} else {
    # We're here for the first time, display the form
    output_form($q);
}

# Output footer and end html
output_end($q);

exit 0;

# Outputs the start html tag, stylesheet and heading
sub output_top($) {
    my ($q) = @_;
    print $q->start_html(
        -title => 'A Questionaire',
        -bgcolor => 'white');
}

# Outputs a footer line and end html tags
sub output_end($) {
    my ($q) = @_;
    print $q->div("My Web Form");
    print $q->end_html;
}

# Displays the results of the form
sub display_results($) {
    my ($q) = @_;

    my $username = $q->param('user_name');
}

# Outputs a web form
sub output_form($) {
    my ($q) = @_;
    print $q->start_form(
        -name => 'main',
        -method => 'POST',
    );

    print $q->start_table;
    print $q->Tr(
      $q->td('Name:'),
      $q->td(
        $q->textfield(-name => "user_name", -size => 50)
      )
    );

    print $q->Tr(
      $q->td($q->submit(-value => 'Submit')),
      $q->td('&nbsp;')
    );
    print $q->end_table;
    print $q->end_form;
}
6

советы по стилю: вам почти никогда не нужно назначать 0 или 1 переменной. Просто оцените само значение в контексте bool.

в CGI.pm (CGI), the param метод объединяет POST и GET параметры, поэтому нам нужно проверить метод запроса отдельно:

#!/usr/bin/env perl
use strict;
use warnings FATAL => 'all';
use CGI qw();
my $c = CGI->new;
print $c->header('text/plain');
if ('POST' eq $c->request_method && $c->param('dl')) {
    # yes, parameter exists
} else {
    # no
}
print 'Do not taunt happy fun CGI.';

С Plack:: Request (PSGI), у вас есть разные методы для POST (body_parameters) и Get (query_parameters) в дополнение к смешанному интерфейсу (parameters):

#!/usr/bin/env plackup
use strict;
use warnings FATAL => 'all';
use Plack::Request qw();
my $app = sub {
    my ($env) = @_;
    my $req = Plack::Request->new($env);
    if ($req->body_parameters->get_all('dl')) {
        # yes
    } else {
        # no
    }
    return [200, [Content_Type => 'text/plain'], ['Do not taunt happy fun Plack.']];
};
4

вот хорошее место для начала:руководство дурака к CGI.pm, модуль Perl для сценариев CGI.

Это покажет вам "...как получить значение POST (из отправленной формы) и назначить его переменной."

надеюсь, что это помогает!

0

приведенные выше примеры довольно сложно. Приведенный ниже код считывает значения в переменную. Вы можете извлечь значение ключа из этого. Если его получить, то его лучше использовать CGI модуль.

#!/usr/bin/perl

my $FormData = '';
read(STDIN, $FormData, $ENV{'CONTENT_LENGTH'});

## Variable $FormData holds all POST values passed

use CGI;
my $cgi = new CGI;
print $cgi->header();
print "$FormData";
0