Как работают поля gnuplot в режиме multiplot?

Я немного смущен полями gnuplot. Прежде всего, я понятия не имею, на какие единицы указывают эти вещи. Указывают ли они на координаты холста или они являются частью координат холста. Ведут ли они себя одинаково в режиме gnuplot и режиме multiplot?

моя проблема возникает при построении некоторых данных в режиме multiplot. Я строю график на экране (терминал wtx). Скажем так, я плохо все путаю - я получаю сюжеты с холста или очень маленькие нечитаемые график.

без полей первый сюжет находится вровень с верхней частью холста, поэтому, естественно, я хочу немного подтолкнуть его.

может кто-нибудь объяснить, как его полях работают и если они ведут себя так же в режиме совместного графика.

6
gnuplot plot scripting

1 ответов

да, поля ведут себя очень похоже на "нормальный" режим заговоре и в режиме совместного графика. В принципе, поля могут иметь три разных "режима":

  1. Automatic, который является значением по умолчанию.
  2. установка каждого поля на определенный размер, например set lmargin 2. Блок ширины характера (или высоты характера для tmargin и bmargin).
  3. настройки конкретного позиция границы относительно всего холста, как set lmargin at screen 0.1, которым задает левую границу участка на 10% от общей ширины холста.

единственная разница multiplot режим заключается в том, что ссылка для полей в 1. и 2. дается сайтами, определенными :

set multiplot layout 2,2

это подразделяет весь холст на четыре прямоугольника одинакового размера. Теперь, используя

set lmargin 1
set rmargin 1
set tmargin 1
set bmargin 1

оставляет поле шириной или высотой одного символа с каждой стороны каждого подзаголовка по отношению к меньшему прямоугольники:

set multiplot layout 2,2
set lmargin 0
set rmargin 0
set tmargin 0
set bmargin 0
set format ''
plot x
plot x**2
plot x**3
plot x**4
unset multiplot

enter image description here

set multiplot layout 2,2
set lmargin 1
set rmargin 1
set tmargin 1
set bmargin 1
set format ''
plot x
plot x**2
plot x**3
plot x**4
unset multiplot

enter image description here

если вы хотите установить абсолютные позиции каждой границы, это становится более громоздким, потому что вы должны установить четыре поля для каждого участка (layout параметры не имеют никакого эффекта в данном случае):

set multiplot
set lmargin at screen 0.1
set rmargin at screen 0.47
set tmargin at screen 0.97
set bmargin at screen 0.6
plot x
...

Gnuplot версия 5 предлагает довольно гибкий способ получения равных прямоугольников, см. Мой ответ на удаление пустых пробелов в gnuplot совместного графика

7