Как сделать целочисленное (подписанное или беззнаковое) деление на ARM?
Я работаю над Cortex-A8 и Cortex-A9 в частности. Я знаю, что некоторые архитектуры не имеют целочисленного деления, но каков наилучший способ сделать это, кроме преобразования в float, divide, convert to integer? Или это действительно лучшее решение?
Ура! = )
5 ответов
компилятор обычно включает разделение в свою библиотеку, gcclib, например, я извлек их из gcc и использую их напрямую:
https://github.com/dwelch67/stm32vld/ затем stm32f4d / приключения / gcclib
переход на float и обратно, вероятно, не лучшее решение. вы можете попробовать и посмотреть, насколько это быстро...Это умножение, но так же легко может сделать его делением:
https://github.com/dwelch67/stm32vld/ тогда stm32f4d/float01 / векторы.s
Я не время, хотя, чтобы увидеть, как быстро / медленно. Понятно, что я использую кортекс-м выше, и вы говорите о кортекс-а, разных концах спектра, похожих инструкциях float и материале GCC lib похож, для кортекса-м я должен построить для большого пальца, но вы можете так же легко построить для руки. На самом деле с gcc все должно работать автоматически, вам не нужно делать это так, как я это сделал. Другие компиляторы, а также вам не нужно сделайте это так, как я сделал это в приключенческой игре выше.
деление на постоянное значение выполняется быстро, выполняя 64-битное умножение и сдвиг вправо, например, так:
LDR R3, =0xA151C331
UMULL R3, R2, R1, R3
MOV R0, R2,LSR#10
здесь R1 делится на 1625. Расчет выполняется следующим образом: 64bitreg (R2:R3) = R1*0xA151C331, то в результате верхний 32-битный правый сдвинут на 10:
R1*0xA151C331/2^(32+10) = R1*0.00061538461545751488 = R1/1624.99999980
вы можете рассчитать собственные константы из этой формулы:
x / N == (x*A)/2^(32+n) --> A = 2^(32+n)/N
выберите самый большой n, для которого a
некоторая копия-паста из другого места для целочисленного деления: В основном, 3 инструкции на бит. От этой веб-сайт, хотя я видел его и во многих других местах. этой сайт также имеет хорошую версию, которая может быть быстрее в целом.
@ Entry r0: numerator (lo) must be signed positive
@ r2: deniminator (den) must be non-zero and signed negative
idiv:
lo .req r0; hi .req r1; den .req r2
mov hi, #0 @ hi = 0
adds lo, lo, lo
.rept 32 @ repeat 32 times
adcs hi, den, hi, lsl #1
subcc hi, hi, den
adcs lo, lo, lo
.endr
mov pc, lr @ return
@ Exit r0: quotient (lo)
@ r1: remainder (hi)
Я написал свою собственную процедуру для выполнения неподписанного деления, поскольку я не мог найти неподписанную версию в интернете. Мне нужно было разделить 64-битное значение с 32-битным значением, чтобы получить 32-битный результат.
внутренний цикл не так эффективен, как подписанное решение, приведенное выше, но это поддерживает арифметику без знака. Эта процедура выполняет 32-разрядное деление, если верхняя часть числителя (hi) меньше знаменателя (den), в противном случае выполняется полное 64-разрядное деление (привет: lo / den). Результат в lo.
cmp hi, den // if hi < den do 32 bits, else 64 bits
bpl do64bits
REPT 32
adds lo, lo, lo // shift numerator through carry
adcs hi, hi, hi
subscc work, hi, den // if carry not set, compare
subcs hi, hi, den // if carry set, subtract
addcs lo, lo, #1 // if carry set, and 1 to quotient
ENDR
mov r0, lo // move result into R0
mov pc, lr // return
do64bits:
mov top, #0
REPT 64
adds lo, lo, lo // shift numerator through carry
adcs hi, hi, hi
adcs top, top, top
subscc work, top, den // if carry not set, compare
subcs top, top, den // if carry set, subtract
addcs lo, lo, #1 // if carry set, and 1 to quotient
ENDR
mov r0, lo // move result into R0
mov pc, lr // return
можно добавить дополнительную проверку граничных условий и мощности 2. Полную информацию можно найти по адресуhttp://www.idwiz.co.za/Tips%20and%20Tricks/Divide.htm
я написал следующие функции ARM GNU ассемблер. Если у вас нет процессора с udiv/sdiv поддержка машины, просто вырежьте первые несколько строк до метки "0:" в любой функции.
.arm
.cpu cortex-a7
.syntax unified
.type udiv,%function
.globl udiv
udiv: tst r1,r1
bne 0f
udiv r3,r0,r2
mls r1,r2,r3,r0
mov r0,r3
bx lr
0: cmp r1,r2
movhs r1,r2
bxhs lr
mvn r3,0
1: adds r0,r0
adcs r1,r1
cmpcc r1,r2
subcs r1,r2
orrcs r0,1
lsls r3,1
bne 1b
bx lr
.size udiv,.-udiv
.type sdiv,%function
.globl sdiv
sdiv: teq r1,r0,ASR 31
bne 0f
sdiv r3,r0,r2
mls r1,r2,r3,r0
mov r0,r3
bx lr
0: mov r3,2
adds r0,r0
and r3,r3,r1,LSR 30
adcs r1,r1
orr r3,r3,r2,LSR 31
movvs r1,r2
ldrvc pc,[pc,r3,LSL 2]
bx lr
.int 1f
.int 3f
.int 5f
.int 11f
1: cmp r1,r2
movge r1,r2
bxge lr
mvn r3,1
2: adds r0,r0
adcs r1,r1
cmpvc r1,r2
subge r1,r2
orrge r0,1
lsls r3,1
bne 2b
bx lr
3: cmn r1,r2
movge r1,r2
bxge lr
mvn r3,1
4: adds r0,r0
adcs r1,r1
cmnvc r1,r2
addge r1,r2
orrge r0,1
lsls r3,1
bne 4b
rsb r0,0
bx lr
5: cmn r1,r2
blt 6f
tsteq r0,r0
bne 7f
6: mov r1,r2
bx lr
7: mvn r3,1
8: adds r0,r0
adcs r1,r1
cmnvc r1,r2
blt 9f
tsteq r0,r3
bne 10f
9: add r1,r2
orr r0,1
10: lsls r3,1
bne 8b
rsb r0,0
bx lr
11: cmp r1,r2
blt 12f
tsteq r0,r0
bne 13f
12: mov r1,r2
bx lr
13: mvn r3,1
14: adds r0,r0
adcs r1,r1
cmpvc r1,r2
blt 15f
tsteq r0,r3
bne 16f
15: sub r1,r2
orr r0,1
16: lsls r3,1
bne 14b
bx lr
есть две функции, udiv для целочисленного деления без знака и sdiv для знакового деления. Они оба ожидают 64-битный дивиденд (подписанный или неподписанный) в r1 (старшее Слово) и r0 (младшее Слово) и 32-разрядный делитель в r2. Они возвращают коэффициент в r0 а остальное в r1, таким образом, вы можете определить их в C header as extern возвращает 64-разрядное целое число и маскирует фактор и остаток после этого. Ошибка (деление на 0 или переполнение) указывается остатком, имеющим абсолютное значение, большее или равное абсолютному значению делителя. Подписанный алгоритм деления использует различие случаев по признакам как дивиденда, так и делителя; он не преобразуется сначала в положительные целые числа, так как это не определите все условия переполнения правильно.