Как сделать Windows Forms.NET отображение приложения в виде значка в трее?

Что нужно сделать, чтобы ваше приложение .NET появилось в системном трее окна в виде значка?

и как вы обрабатываете mousebutton нажимает на указанный значок?

19
.net system-tray systray winforms

6 ответов

Сначала добавьте элемент управления NotifyIcon в форму. Затем подключите значок уведомления, чтобы сделать то, что вы хотите.

Если вы хотите, чтобы скрыть в трей при минимизации, попробуйте это.

Private Sub frmMain_Resize(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Resize
    If Me.WindowState = FormWindowState.Minimized Then
        Me.ShowInTaskbar = False
    Else
        Me.ShowInTaskbar = True
    End If
End Sub

Private Sub NotifyIcon1_MouseClick(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles NotifyIcon1.MouseClick
    Me.WindowState = FormWindowState.Normal
End Sub

Я буду иногда использовать текст воздушного шара, чтобы уведомить пользователя-это делается как таковой

 Me.NotifyIcon1.ShowBalloonTip(3000, "This is a notification title!!", "This is notification text.", ToolTipIcon.Info)
20

вы можете добавить компонент NotifyIcon из панели инструментов в основную форму.

Это такие события, как MouseDoubleClick, которые можно использовать для обработки различных событий.

Edit: вы должны убедиться, что для свойства Icon задано значение valid .ICO-файл, если вы хотите, чтобы он правильно отображался в systray.

6

хороший маленький учебник по использованию класса NotifyIcon здесь:http://www.developer.com/net/csharp/article.php/3336751

2

добавить NotifyIcon компонент на форму. И используйте его события для обработки щелчков мыши.

0

чтобы расширить ответ Тома, мне нравится только сделать значок видимым, если приложение свернуто. Для этого установите visible=false для NotifyIcon и используйте приведенный ниже код.

у меня также есть код ниже, чтобы скрыть значок во время закрытия предотвратить раздражающие значки лотка "призрак", которые сохраняются после закрытия приложения

Private Sub Form_Resize(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Resize
    If Me.WindowState = FormWindowState.Minimized Then
        Hide()
        NotifyIcon1.Visible = True
        NotifyIcon1.ShowBalloonTip(3000, NotifyIcon1.Text, "Minimized to tray", ToolTipIcon.Info)
    End If
End Sub

Private Sub NotifyIcon1_MouseClick(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles NotifyIcon1.MouseClick
    Show()
    Me.WindowState = FormWindowState.Normal
    Me.Activate()
    NotifyIcon1.Visible = False
End Sub

Private Sub Form_FormClosing(sender As Object, e As FormClosingEventArgs) Handles Me.FormClosing
    NotifyIcon1.Visible = False
    Dim index As Integer
    While index < My.Application.OpenForms.Count
        If My.Application.OpenForms(index) IsNot Me Then
            My.Application.OpenForms(index).Close()
        End If
        index += 1
    End While
End Sub

Если вы хотите добавить Правой Кнопкой Мыши меню:

https://social.technet.microsoft.com/wiki/contents/articles/13319.vb-net-how-to-make-a-right-click-menu-for-a-tray-icon.aspx

В статье (с модами для контекста):

настройка формы для размещения контекстного меню значка в трее

  • в свойствах задать FormBorderStyle значение None.
  • установите ShowInTaskbar как False (потому что мы не хотим, чтобы значок появлялся на панели задач при щелчке правой кнопкой мыши значок в трее!).
  • установите StartPosition в ручное.
  • установите верхнее значение True.
  • добавьте ContextMenuStrip в новую форму и назовите ее как хотите.
  • добавить элементы в ContextMenuStrip (для этого примера просто добавьте один элемент под названием "Выход").

код формы позади будет выглядеть так:

Private Sub Form_Deactivate(sender As Object, e As EventArgs) Handles Me.Deactivate
    Me.Close()
End Sub

Private Sub Form_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    ContextMenuStrip1.Show(Cursor.Position)
    Me.Left = ContextMenuStrip1.Left + 1
    Me.Top = ContextMenuStrip1.Top + 1
End Sub

Private Sub ExitToolStripMenuItem_Click(sender As Object, e As EventArgs) Handles ExitToolStripMenuItem.Click
    MainForm.NotifyIcon1.Visible = False
    End
End Sub

затем я изменяю событие мыши notifyicon на это (TrayIconMenuForm-это имя моей формы для предоставления контекстное меню):

Private Sub NotifyIcon1_MouseClick(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles NotifyIcon1.MouseClick
    Select Case e.Button
        Case Windows.Forms.MouseButtons.Left
            Show()
            Me.WindowState = FormWindowState.Normal
            Me.Activate()
            NotifyIcon1.Visible = False
        Case Windows.Forms.MouseButtons.Right
            TrayIconMenuForm.Show() 'Shows the Form that is the parent of "traymenu"
            TrayIconMenuForm.Activate() 'Set the Form to "Active", that means that that will be the "selected" window
            TrayIconMenuForm.Width = 1 'Set the Form width to 1 pixel, that is needed because later we will set it behind the "traymenu"
            TrayIconMenuForm.Height = 1 'Set the Form Height to 1 pixel, for the same reason as above
        Case Else
            'Do nothing
    End Select
End Sub
0

Это показывает и обрабатывает все комбинации щелчка мыши для NotifyIcon

подробнее здесь: https://archive.codeplex.com/?p=notifyicon

0