Как сохранить динамический массив в FileStream в Delphi?

У меня есть следующие структуры в Delphi 2009:

type
  IndiReportIndi = record
    IndiName: string;
    NameNum: integer;
    ReportIndiName: string;
  end;

var
  XRefList: array of IndiReportIndi;

где XRefList-динамический массив.

Я хочу сохранить XRefList в FileStream. Как это сделать и включить все строки IndiName и ReportIndiName, чтобы все они были снова извлекаемы при последующей загрузке из этого FileStream?

7
delphi dynamic-arrays filestream

6 ответов

использование:http://code.google.com/p/kblib/

type
  IndiReportIndi = record
    IndiName: string;
    NameNum: integer;
    ReportIndiName: string;
  end;

  TXRefList = array of IndiReportIndi;

var
  XRefList: TXRefList;

сохранить весь XRefList использовать поток:

TKBDynamic.WriteTo(lStream, XRefList, TypeInfo(TXRefList));

загрузить его обратно:

TKBDynamic.ReadFrom(lStream, XRefList, TypeInfo(TXRefList));
6
type
  IndiReportIndi = record
    IndiName: string;
    NameNum: integer;
    ReportIndiName: string;
    procedure SaveToStream(Stream: TStream);
    procedure LoadFromStream(Stream: TStream);
  end;

type
  TXRefList = array of IndiReportIndi;

function LoadString(Stream: TStream): string;
var
  N: Integer;

begin
  Result:= '';
  Stream.ReadBuffer(N, SizeOf(Integer));
  if N > 0 then begin
    SetLength(Result, N);
//    Stream.ReadBuffer(Result[1], N * SizeOf(Char));
// fast version - see comment by A.Bouchez
    Stream.ReadBuffer(Pointer(Result)^, N * SizeOf(Char));
  end;
end;

procedure SaveString(Stream: TStream; const S: string);
var
  N: Integer;

begin
  N:= Length(S);
  Stream.WriteBuffer(N, SizeOf(Integer));
  if N > 0 then
//    Stream.WriteBuffer(S[1], N * SizeOf(Char));
// fast version - see comment by A.Bouchez
    Stream.WriteBuffer(Pointer(S)^, N * SizeOf(Char));
end;

procedure IndiReportIndi.LoadFromStream(Stream: TStream);
var
  S: string;

begin
  IndiName:= LoadString(Stream);
  Stream.ReadBuffer(NameNum, SizeOf(Integer));
  ReportIndiName:= LoadString(Stream);
end;

procedure IndiReportIndi.SaveToStream(Stream: TStream);
begin
  SaveString(Stream, IndiName);
  Stream.WriteBuffer(NameNum, SizeOf(Integer));
  SaveString(Stream, ReportIndiName);
end;

function LoadXRefList(Stream: TStream): TXRefList;
var
  N: Integer;
  I: Integer;

begin
  Stream.ReadBuffer(N, SizeOf(Integer));
  if N <= 0 then Result:= nil
  else begin
    SetLength(Result, N);
    for I:= 0 to N - 1 do
      Result[I].LoadFromStream(Stream);
  end;
end;

procedure SaveXRefList(Stream: TStream; const List: TXRefList);
var
  N: Integer;
  I: Integer;

begin
  N:= Length(List);
  Stream.WriteBuffer(N, SizeOf(Integer));
  for I:= 0 to N - 1 do
    List[I].SaveToStream(Stream);
end;
10
var
  S: TStream;
  W: TWriter;
  A: array of IndiReportIndi;
  E: IndiReportIndi;
  ...
begin
  S := nil;
  W := nil;
  try 
    S := TFileStream.Create(...);
    W := TWriter.Create(S);
    W.WriteInteger(Length(A));
    for E in A do
    begin
      W.WriteString(E.IndiName);
      W.WriteInteger(E.NameNum);
      W.WriteString(E.ReportIndiName);
    end;
  finally
    W.Free;
    S.Free
  end;
end;

для чтения этих данных вы используете TReader и ReadInteger / ReadString.

5

простой TFileStreamEx для сохранения переменных

http://forum.chertenok.ru/viewtopic.php?t=4642

работаем с ними с 2005-го года, без каких-либо проблем...

1

просто для точного ответа:

рассмотрите возможность взглянуть на TDynArray wrapper, который способен сериализовать любую запись в двоичный файл, а также В / из динамических массивов.

много TList - подобные методы, включая новые методы (например, хэширование или двоичный поиск).

очень оптимизирован для скорости и использования диска, работает для Delphi 5 до XE2-и с открытым исходным кодом.

см. также как хранить динамические массивы в Список задач?

0

протестированное решение:

procedure TForm1.FormCreate(Sender: TObject);
VAR Stream: TFileStream;
    R: IndyRecordIndy;
begin
 Stream:= TFileStream.Create;
 TRY
   //put rec in stream
   Stream.WriteBuffer(R, SizeOf(R));

   //restore record from stram
   Stream.Position := 0;
   Stream.ReadBuffer(R, Stream.Size);
 FINALLY
  FreeAndNil(Stream);
 END;
end



;
0