Как ссылаться на таблицы в Excel vba?

ОП спросил, Можно ли ссылка на таблицу, а не как добавить таблицу. Поэтому работая эквивалент

Sheets("Sheet1").Table("A_Table").Select

было бы это утверждение:

Sheets("Sheet1").ListObjects("A_Table").Range.Select

или для выбора деталей (например, только данные в таблице):

Dim LO As ListObject
Set LO = Sheets("Sheet1").ListObjects("A_Table")
LO.HeaderRowRange.Select        ' Select just header row
LO.DataBodyRange.Select         ' Select just data cells
LO.TotalsRowRange.Select        ' Select just totals row

для деталей вы можете проверить наличие строк заголовка и итогов перед их выбором.

и серьезно, это единственный вопрос о ссылках на таблицы в VBA в SO? Таблицы в Excel так много смысла, но с ними так сложно работать в VBA!

"таблица" в Excel действительно известна как ListObject.

"правильный" способ ссылки на таблицу-это получить ее ListObject из своего рабочего листа, т. е. SheetObject.ListObjects(ListObjectName).

Если вы хотите ссылаться на таблицу без использования листа, вы можете использовать Хак Application.Range(ListObjectName).ListObject.

Примечание: этот хак полагается на то, что Excel всегда создает именованный диапазон для таблицы DataBodyRange С тем же именем, что и таблица. Однако это имя диапазона can быть изменен...хотя это не то, что вы хотели бы сделать, так как имя будет сброшено, если вы измените имя таблицы! Также вы можете получить именованный диапазон без связанного ListObject.

учитывая не очень полезное сообщение об ошибке Excel 1004, когда вы получаете неправильное имя, вы можете создать обертку...

Public Function GetListObject(ByVal ListObjectName As String, Optional ParentWorksheet As Worksheet = Nothing) As Excel.ListObject
On Error Resume Next

    If (Not ParentWorksheet Is Nothing) Then
        Set GetListObject = ParentWorksheet.ListObjects(ListObjectName)
    Else
        Set GetListObject = Application.Range(ListObjectName).ListObject
    End If

On Error GoTo 0 'Or your error handler

    If (Not GetListObject Is Nothing) Then
        'Success
    ElseIf (Not ParentWorksheet Is Nothing) Then
        Call Err.Raise(1004, ThisWorkBook.Name, "ListObject '" & ListObjectName & "' not found on sheet '" & ParentWorksheet.Name & "'!")
    Else
        Call Err.Raise(1004, ThisWorkBook.Name, "ListObject '" & ListObjectName & "' not found!")
    End If

End Function

также некоторые хорошие listobject info здесь.

кроме того, удобно определять переменные, ссылающиеся на объекты. Например,

Sub CreateTable()
    Dim lo as ListObject
    Set lo = ActiveSheet.ListObjects.Add(xlSrcRange, Range("$B:$D"), , xlYes)
    lo.Name = "Table1"
    lo.TableStyle = "TableStyleLight2"
    ...
End Sub

вы, вероятно, найдете его выгодным сразу.

в дополнение к вышесказанному, вы можете сделать это (где "YourListObjectName" - это имя вашей таблицы):

Dim LO As ListObject
Set LO = ActiveSheet.ListObjects("YourListObjectName")

но я думаю, что это работает, только если вы хотите ссылаться на объект списка, который находится на активном листе.

Я нашел ваш вопрос, потому что хотел сослаться на объект списка (таблицу) на одном листе, на который ссылается сводная таблица на другом листе. Поскольку объекты list являются частью коллекции Worksheets, необходимо знать имя рабочего листа этот объект list включен, чтобы ссылаться на него. Поэтому, чтобы получить имя рабочего листа, на котором находится объект списка, я получил имя исходного объекта списка сводной таблицы (опять же, таблицы) и прошелся по листам и их объектам списка, пока не нашел рабочий лист, содержащий объект списка, который я искал.

Public Sub GetListObjectWorksheet()
' Get the name of the worksheet that contains the data
' that is the pivot table's source data.

    Dim WB As Workbook
    Set WB = ActiveWorkbook

    ' Create a PivotTable object and set it to be
    ' the pivot table in the active cell:
    Dim PT As PivotTable
    Set PT = ActiveCell.PivotTable

    Dim LO As ListObject
    Dim LOWS As Worksheet

    ' Loop through the worksheets and each worksheet's list objects
    ' to find the name of the worksheet that contains the list object
    ' that the pivot table uses as its source data:
    Dim WS As Worksheet
    For Each WS In WB.Worksheets
        ' Loop through the ListObjects in each workshet:
        For Each LO In WS.ListObjects
            ' If the ListObject's name is the name of the pivot table's soure data,
            ' set the LOWS to be the worksheet that contains the list object:
            If LO.Name = PT.SourceData Then
                Set LOWS = WB.Worksheets(LO.Parent.Name)
            End If
        Next LO
    Next WS

    Debug.Print LOWS.Name

End Sub

может кто знает более прямой путь.