Как улучшить использование кадров Delphi

Я использовал фреймы в Delphi в течение многих лет, и они являются одной из самых мощных функций VCL, но стандартное использование их, похоже, имеет некоторый риск, такой как:

  1. легко случайно переместить или отредактировать субкомпоненты фрейма на хост-форме фрейма, не понимая, что вы "настраиваете" фрейм - я знаю, что это не влияет на исходный код фрейма, но это, как правило, не то, что вы хотели бы.

  2. при работе с фрейм по-прежнему подвергается визуальному редактированию его субкомпонентами, даже если этому фрейму много лет и к нему нельзя прикасаться.

поэтому я задумался....

  1. есть ли способ "группировки" компонентов, чтобы их позиции были "заблокированы"? Это было бы полезно как для готовых форм, так и для фреймов. Часто другие разработчики возвращают мне код, где изменились только границы формы, и даже они не намеревались изменение.

  2. есть ли способ превратить кадр и его компоненты в один компонент Delphi? Если это так, внутренние элементы фрейма будут полностью скрыты, и его полезность будет увеличиваться.

меня интересуют любые мысли...

Брайан.

22
components delphi tframe

5 ответов

Регистрация ваших кадров в качестве компонента решает оба 1. и 2.:

  1. компоненты на фрейме блокируются, когда вы помещаете этот элемент управления фреймом в форму или другой фрейм
  2. вы получите компонент (на самом деле: control), который вы можете создать визуально

но: есть несколько уловов (которые можно решить, см. ссылку на статью), из которых наиболее важным является этот:

когда вы кладете компоненты на ваш кадр, и позже удалите этот фрейм как компонент в форме Delphi или фрейме, компоненты будут видны на панели структура.

проблема в том, что, поскольку они видны в области структуры, вы можете удалить их, вызвав нарушения доступа.

трюк, чтобы решить эту не забудьте 'веточка'.
Я извлек этот ценный урок из Рэй Конопка во время DelphiLive 2009.

поскольку урок таков ценный, я написал блоге на нем, который описывает его подробно.

существенной частью является этот маленький кусочек кода (подробнее в блоге):

procedure RegisterFramesAsComponents(const Page: string; const FrameClasses: array of TFrameClass);
var
  FrameClass: TFrameClass;
begin
  for FrameClass in FrameClasses do
  begin
    RegisterComponents(Page, [FrameClass]);
    RegisterSprigType(FrameClass, TComponentSprig);
  end;
end;

надеюсь, что это помогает.

--jeroen

22

да, просто зарегистрируйте их как компоненты. :-)

создайте свой кадр нормально и после этого зарегистрируйте его. Также убедитесь, что у вас нет нежелательных зависимостей от разных блоков, поскольку они связаны при использовании вашего "компонента". Также вы можете добавить published свойства, чтобы использовать их в Инспекторе объектов позже. См., например, следующий код, созданный IDE (см. Также мои комментарии):

unit myUnit;

uses
 ...

type
  TmyComp = class(TFrame) //set your frame name to be the name your component 
    ToolBar1: TToolBar; //different components added in the form designer
    aliMain: TActionList;
    ...
  published //this section is added by hand
    property DataSource: TDataSource read FDataSource write SetDataSource; //some published properties added just for exemplification
    property DefFields: string read FDefFields write SetDefFields;
    ...
  end;


procedure Register; //added by hand

implementation

{$R *.DFM}

procedure Register;
begin
  RegisterComponents('MyFrames', [TmyComp]); //register the frame in the desired component category
end;

скомпилируйте вышеуказанное в пакете вашего выбора, установите его и проверьте палитру компонентов. :-)

HTH

17

просто для увеличения вклада, обратите внимание, что если вы идете в Structure окно и щелкните правой кнопкой мыши на имени TFrame, которое вы выбрали, и нажмите на Add to Palete опции меню. Это сделает компонент из вашего фрейма, и вам не нужно создавать какие-либо Register процедуры. ;-)

8

Я почти всегда создаю экземпляры фреймов в коде. Это легко и хорошо сработало для меня до сих пор.

5

Я тоже столкнулся с этой проблемой при попытке использовать рамки в качестве компонентов. Существуют различные возможности для устранения очевидных проблем, но все они подрывают принцип сокрытия информации (все подкомпоненты фрейма отображаются как опубликованные свойства, а это означает, что каждый может получить к ним доступ).

Я решил это, реализовав общий компонент "frame control":

unit RttiBrow.Cbde.FrameControl;

interface

uses
  Classes, Controls, Forms, Messages, ExtCtrls;

type
  TFrameClass = class of TFrame;

  TComponentFrame = class (TFrame)
  private
    function GetClientHeight: Integer;
    function GetClientWidth: Integer;
    procedure SetClientHeight(const Value: Integer);
    procedure SetClientWidth(const Value: Integer);
    function GetOldCreateOrder: Boolean;
    procedure SetOldCreateOrder(const Value: Boolean);
    function GetPixelsPerInch: Integer;
    procedure SetPixelsPerInch(const Value: Integer);
    function GetTextHeight: Integer;
    procedure SetTextHeight(const Value: Integer);
  published
    { workarounds for IDE bug }
    property ClientWidth: Integer read GetClientWidth write SetClientWidth stored False;
    property ClientHeight: Integer read GetClientHeight write SetClientHeight stored False;
    property OldCreateOrder: Boolean read GetOldCreateOrder write SetOldCreateOrder stored False;
    property PixelsPerInch: Integer read GetPixelsPerInch write SetPixelsPerInch stored False;
    property TextHeight: Integer read GetTextHeight write SetTextHeight stored False;
  end;

  TComponentFrame<TFrameControl: class { TControl }> = class (TComponentFrame)
  private
    function GetController: TFrameControl; inline;
  protected
    property Controller: TFrameControl read GetController;
  public
    constructor Create (AOwner: TComponent); override;
  end;

  TFrameControl<T: TFrame> = class (TWinControl)
  private
    FFrame: T;
    function PlainFrame: TFrame;
  protected
    procedure CreateParams (var Params: TCreateParams); override;
    property Frame: T read FFrame;
  public
    constructor Create (AOwner: TComponent); override;
    property DockManager;
  published
    property Align;
    property Anchors;
    property BiDiMode;
    property Color;
    property Constraints;
    property Ctl3D;
    property UseDockManager default True;
    property DockSite;
    property DoubleBuffered;
    property DragCursor;
    property DragKind;
    property DragMode;
    property Enabled;
    property Font;
    property ParentBiDiMode;
    property ParentBackground;
    property ParentColor;
    property ParentCtl3D;
    property ParentDoubleBuffered;
    property ParentFont;
    property ParentShowHint;
    property ShowHint;
    property TabOrder;
    property TabStop;
    property Touch;
    property Visible;
    property OnAlignInsertBefore;
    property OnAlignPosition;
    property OnCanResize;
    property OnConstrainedResize;
    property OnDockDrop;
    property OnDockOver;
    property OnDragDrop;
    property OnDragOver;
    property OnEndDock;
    property OnEndDrag;
    property OnEnter;
    property OnExit;
    property OnGesture;
    property OnGetSiteInfo;
    property OnMouseActivate;
    property OnMouseDown;
    property OnMouseEnter;
    property OnMouseLeave;
    property OnMouseMove;
    property OnMouseUp;
    property OnResize;
    property OnStartDock;
    property OnStartDrag;
    property OnUnDock;
  end;


implementation

uses
  Windows;

{ TFrameControl<T> }

constructor TFrameControl<T>.Create(AOwner: TComponent);
begin
  inherited;
  FFrame := T (TFrameClass (T).Create (Self));
  PlainFrame.Parent := Self;
  PlainFrame.Align := alClient;
end;

procedure TFrameControl<T>.CreateParams(var Params: TCreateParams);
begin
  inherited;
  Params.Style := Params.Style or WS_CLIPCHILDREN;
  Params.ExStyle := Params.ExStyle or WS_EX_CONTROLPARENT;
end;

function TFrameControl<T>.PlainFrame: TFrame;
begin
  Result := FFrame; // buggy compiler workaround
end;


{ TComponentFrame }

function TComponentFrame.GetOldCreateOrder: Boolean;
begin
  Result := False;
end;

function TComponentFrame.GetPixelsPerInch: Integer;
begin
  Result := 0;
end;

function TComponentFrame.GetTextHeight: Integer;
begin
  Result := 0;
end;

procedure TComponentFrame.SetClientHeight(const Value: Integer);
begin
  Height := Value;
end;

procedure TComponentFrame.SetClientWidth(const Value: Integer);
begin
  Width := Value;
end;

procedure TComponentFrame.SetOldCreateOrder(const Value: Boolean);
begin
end;

procedure TComponentFrame.SetPixelsPerInch(const Value: Integer);
begin
end;

procedure TComponentFrame.SetTextHeight(const Value: Integer);
begin
end;

function TComponentFrame.GetClientHeight: Integer;
begin
  Result := Height;
end;

function TComponentFrame.GetClientWidth: Integer;
begin
  Result := Width;
end;


{ TComponentFrame<TFrameControl> }

constructor TComponentFrame<TFrameControl>.Create(AOwner: TComponent);
begin
  inherited;
  Assert (AOwner <> nil);
  Assert (AOwner.InheritsFrom (TFrameControl));
end;

function TComponentFrame<TFrameControl>.GetController: TFrameControl;
begin
  Result := TFrameControl (Owner);
end;


end.

С этим классом добавление фрейма в качестве компонента становится двухэтапным процесс:

  // frame unit
type
  TFilteredList = class;

  TFrmFilteredList = class (TComponentFrame<TFilteredList>)
    // lots of published sub-components and event methods like this one:
    procedure BtnFooClick(Sender: TObject);
  end;

  TFilteredList = class (TFrameControl<TFrmFilteredList>)
  private
    procedure Foo;
  public
    // the component's public interface
  published
    // the component's published properties
  end;

procedure Register;
...
procedure Register;
begin
  RegisterComponents ('CBDE Components', [TFilteredList]);
end;

procedure TFrmFilteredList.BtnFooClick(Sender: TObject);
begin
  Controller.Foo;
end;

procedure TFilteredList.Foo;
begin
end;
...

при использовании этого подхода пользователь вашего компонента не будет видеть ваши субкомпоненты.

4