как установить заголовок ниже графика в gnuplot

пример:

set title "title"
plot x

это нарисует график с заголовком вверху. Я хочу переместить заголовок под график. Что мне делать? Более того, как насчет той же проблемы в multiplot. Я хочу переместить заголовки для каждого небольшого графика s под каждым графиком. Обратите внимание, что заголовок не является заголовком В сюжете, который будет помещен в ключи. Большое спасибо!

7
gnuplot title

1 ответов

преимущества использования set title заключается в том, что для него автоматически зарезервировано некоторое вертикальное пространство. Это работает только при размещении заголовка над графиком.

вы можете поместить его ниже графика, только указав offset. Но в этом случае вы должны адаптировать как смещение вручную, так и нижнее поле:

рассмотрим следующий пример:

set multiplot layout 1,3

set title "title"
plot x

set title "positive offset" offset 0,1
plot x

set title "negative offset" offset 0,-2
plot x

unset multiplot

enter image description here

как только у вас слишком большое отрицательное смещение, верхнее поле сброс как если бы не заголовок, а нижнее остается неизменным.

поэтому вы должны установить метку вручную под участками и соответствующим образом адаптировать нижнее поле:

set multiplot layout 1,3

set xlabel "xlabel"
set label 11 center at graph 0.5,char 1 "first title" font ",14"
set bmargin 5
plot x

set label 11 "second title"
plot x

set label 11 "third title"
plot x

unset multiplot

enter image description here

в любом случае вам нужно ручное вмешательство и настройка полей.

12