Как вернуть запись из существующей таблицы из функции Oracle PL/SQL?

Я знаю, что это звучит как простая вещь, но я никогда не делал этого раньше.

Я хотел бы вернуть одну запись из существующей таблицы в результате функции Oracle PL / SQL. Я уже нашел несколько разных способов сделать это, но меня интересует лучшие способ сделать это (читайте: Я не очень доволен тем, что я нашел).

суть того, что я делаю это... У меня есть таблица под названием "пользователи" , и я хочу функцию "update_and_get_user", который дал имя пользователя (а также другую достоверную информацию о указанном пользователе), потенциально выполнит различные действия в таблице "пользователи", а затем вернет либо ноль, либо одну строку/запись из указанной таблицы.

Это основной набросок кода в моей голове на данный момент (читайте: не знаю, насколько синтаксис близок к правильному):

CREATE FUNCTION update_and_get_user(UserName in VARCHAR2, OtherStuff in VARCHAR2)
    RETURN users PIPELINED IS
  TYPE ref0 IS REF CURSOR;
  cur0       ref0;
  output_rec users%ROWTYPE;
BEGIN
  -- Do stuff

  -- Return the row (or nothing)
  OPEN cur0 FOR 'SELECT * FROM users WHERE username = :1'
    USING UserName;

  LOOP
    FETCH cur0 INTO output_rec;
    EXIT WHEN cur0%NOTFOUND;
    PIPE ROW(output_rec);
  END LOOP;
END update_and_get_user;

Я видел примеры, когда возвращается запись или таблица, тип записи или таблицы был создан / объявлено заранее, но похоже, что если таблица уже определена, я должен иметь возможность использовать это и, следовательно, не беспокоиться о синхронизации кода объявления типа, если изменения таблицы когда-либо будут сделаны.

Я открыт для всех потенциальных решений и комментариев, но я делаю действительно хотите сохранить это в одной функции PL / SQL (в отличие от кода на каком-либо другом языке / фреймворке, который взаимодействует с базой данных несколько раз, заканчивая некоторой формой 'SELECT * FROM users WHERE username=blah'), поскольку система, вызывающая функцию, и сама база данных могут быть разными городами. За пределами этого предела я готов изменить свое мышление.

7
oracle plsql

1 ответов

вот как я бы это сделал. Переменные / имена таблиц / имена столбцов не учитывают регистр в Oracle, поэтому я бы использовал user_name вместо UserName.

CREATE TABLE users( UserName varchar2(20), OtherStuff VARCHAR2(20) );

функции update_and_get_user. Обратите внимание, что я возвращаю ROWTYPE вместо конвейерных таблиц.

CREATE OR REPLACE FUNCTION update_and_get_user(
  in_UserName   IN users.UserName%TYPE,
  in_OtherStuff IN users.OtherStuff%TYPE )
RETURN users%ROWTYPE
IS
  output_rec users%ROWTYPE;
BEGIN
  UPDATE users
  SET OtherStuff = in_OtherStuff
  WHERE UserName = in_UserName
    RETURNING UserName, OtherStuff
    INTO output_rec;
  RETURN output_rec;
END update_and_get_user;

и вот как вы бы это назвали. Вы не можете проверить ROWTYPE на NULL, но вы можете проверить username например.

DECLARE
  users_rec users%ROWTYPE;
BEGIN
  users_rec := update_and_get_user('user', 'stuff');
  IF( users_rec.username IS NOT NULL ) THEN
    dbms_output.put_line('FOUND: ' || users_rec.otherstuff);
  END IF;
END;

решение с использованием PIPED ROWS ниже, но это так не бывает. Вы не можете обновлять таблицы внутри запроса.

SELECT * FROM TABLE(update_and_get_user('user', 'stuff'))

ORA-14551: cannot perform a DML operation inside a query

решение будет выглядеть так:

CREATE OR REPLACE TYPE users_type
AS OBJECT
(
  username   VARCHAR2(20),
  otherstuff VARCHAR2(20)
)

CREATE OR REPLACE TYPE users_tab
   AS TABLE OF users_type;

CREATE OR REPLACE FUNCTION update_and_get_user(
  in_UserName   IN users.username%TYPE,
  in_OtherStuff IN users.otherstuff%TYPE )
RETURN users_tab PIPELINED
IS
  output_rec users%ROWTYPE;
BEGIN
  UPDATE users
  SET OtherStuff = in_OtherStuff
  WHERE UserName = in_UserName
    RETURNING username, otherstuff
    INTO output_rec;
  PIPE ROW(users_type(output_rec.username, output_rec.otherstuff));
END;
13