Как вызвать именованные шаблоны на основе переменной?

это не возможно точно, как вы описываете, но если вы хотите иметь возможность выбрать шаблон во время выполнения на основе некоторого значения, которое вы установили в другом месте, есть трюк, чтобы сделать это. Идея состоит в том, чтобы ваш именованный шаблон также соответствовал узлу с соответствующим именем в отдельном режиме (чтобы он не испортил ваше обычное преобразование), а затем соответствовал этому. Например:

<xsl:stylesheet ... xmlns:t="urn:templates">

  <!-- Any compliant XSLT processor must allow and ignore any elements 
       not from XSLT namespace that are immediate children of root element -->
  <t:templates>
    <t:foo/>
    <t:bar/>
  </t:templates>

  <!-- document('') is the executing XSLT stylesheet -->     
  <xsl:variable name="templates" select="document('')//t:templates" />

  <xsl:template name="foo" match="t:foo" mode="call-template">
    Bla bla bla
  </xsl:template>

  <xsl:template name="bar" match="t:foo" mode="call-template">
    Bla bla bla
  </xsl:template>

  <xsl:template match="/">
    <xsl:variable name="template-name" select="..." />
    <xsl:apply-templates select="$templates/t:*[local-name() = $template-name]"
                         mode="call-template"/>
  </xsl:template>

обратите внимание, что вы можете использовать <xsl:with-param> на <xsl:apply-templates>, поэтому вы можете сделать все с этим, что вы могли бы сделайте с равниной <xsl:call-template>.

кроме того, код выше несколько длиннее, чем вам может понадобиться, потому что он пытается избежать использования любых расширений XSLT. Если ваш процессор поддерживает exslt:node-set(), то вы можете просто создать узлы непосредственно с помощью <xsl:element>, и использовать node-set() чтобы преобразовать полученный фрагмент дерева в простой узел, чтобы соответствовать, без необходимости document('') рубить.

для получения дополнительной информации см. раздел FXSL - это функциональная библиотека программирования для XSLT это основано на этой концепции.

для любой будущей ссылки:

вот рабочий пример, основанный на ответе Павла Минаева. Никакой оригинальной мысли с моей стороны. ;- ) Я переключил его на использование msxml: node-set, как он описал (более или менее), чтобы он работал .Сеть.

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" version="1.0">
    <xsl:variable name="templates">
        <templates>
            <foo />
            <bar />
        </templates>
    </xsl:variable>
    <xsl:template name="foo" match="foo" mode="call-template">
        <FooElement />
    </xsl:template>
    <xsl:template name="bar" match="bar" mode="call-template">
        <BarElement />
    </xsl:template>
    <xsl:template match="/">
        <Root>
            <xsl:variable name="template-name">bar</xsl:variable> <!-- Change this to foo to get the other template. -->
            <xsl:apply-templates select="msxsl:node-set($templates)/*/*[local-name() = $template-name]" mode="call-template" />
        </Root>
    </xsl:template>
</xsl:stylesheet>

обновление: ссылки ниже были обновлены, чтобы указать на web.archive.org -- к сожалению, IDEALLIANCE сделал все Exteme Языки Разметки материалы конференции недоступны... В свое время, я найду более постоянное место для этих двух статей.

это реализовано в FXSL.

есть хорошие объяснения основных принципов FXSL.

см. следующие два статьи:

"функциональное программирование в XSLT с помощью библиотеки FXSL" (для XSLT 1.0), (PDF) по адресу:

http://web.archive.org/web/20070710091236/http://www.idealliance.org/papers/extreme/proceedings/xslfo-pdf/2003/Novatchev01/EML2003Novatchev01.pdf

(HTML-код) at:

http://conferences.idealliance.org/extreme/html/2003/Novatchev01/EML2003Novatchev01.html

"функциональное программирование более высокого порядка с XSLT 2.0 и FXSL " (PDF) at:

http://web.archive.org/web/20070222111927/http://www.idealliance.org/papers/extreme/proceedings/xslfo-pdf/2006/Novatchev01/EML2006Novatchev01.pdf

(HTML-код) на: http://conferences.idealliance.org/extreme/html/2006/Novatchev01/EML2006Novatchev01.html

Используя FXSL, я смог легко и элегантно решить многие проблемы, которые кажутся "невозможными для XSLT". Можно найти много примеров здесь.

я думаю, что у меня была более или менее такая же проблема, как и у вас. У меня был" внешний "шаблон и я хотел вызвать другой" внутренний " шаблон в зависимости от некоторого набора переменных во время выполнения. Я нашел ваш вопрос в Googling для того, чтобы иметь динамический <xsl:call-template>. Я решил это, используя <xsl:apply-templates> вместо этого, следующим образом.

входной XML (генерируемый во время выполнения) содержит что-то вроде:

<template name="template_name_1"/>

XSL в" внешнем " шаблоне имеет:

<xsl:apply-templates select="template"/>

(том select="template" в этом приложении-шаблоны относятся к <template> тег во входном XML)

и, наконец, "внутренний" шаблон, который я хотел включить в результате значение name атрибут в моем XML выглядит так:

<xsl:template match="template[@name='template_name_1']">
    <!-- XSL / XHTML goes here -->
</xsl:template>

(опять же,match="template[@name='xyz']" относится к и, в свою очередь, к <template> тег и его name атрибут во входном XML)

таким образом я может иметь динамически "вызываемый" шаблон, просто управляемый из моего входного XML.

это может быть не та же проблема, что вы пытаетесь решить, но я думаю, что это довольно близко и намного проще, чем решения FSXL, упомянутые в другом месте на этой странице.

как насчет этого?:

  <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:template match="xsl:template[@name='foo']" name="foo">
    Bla bla bla foo
      </xsl:template>

      <xsl:template match="xsl:template[@name='bar']" name="bar">
    Bla bla bla bar
      </xsl:template>

      <xsl:template match="/">
        <xsl:variable name="templateName" select="'bar'"/>
        <xsl:apply-templates select="document('')/*/xsl:template[@name=$templateName]"/>
        <xsl:apply-templates select="document('')/*/xsl:template[@name='foo']"/>
      </xsl:template>

    </xsl:stylesheet>

вы можете упростить "вызов" шаблона, используя переменную, аналогично описанной в более раннем вкладе:

<xsl:variable name="templates" select="document('')/*/xsl:template"/> 

<xsl:apply-templates select="$templates[@name=$templateName]"/>
<xsl:apply-templates select="$templates[@name='foo']"/>

обратите внимание, что дополнительно <xsl:with-param> можно использовать как обычно.