Как я могу генерировать графики box-and-whisker с переменной шириной коробки в gnuplot?

Я пытаюсь визуализировать набор данных, который у меня есть (на Java, но это не имеет большого значения), используя gnuplot. Я мог бы задать несколько разных вопросов об этом, но пока: предположим, что мои данные категоричны, и для каждой категории у меня есть квартили 1,2,3, min и max и общий вес образцов в этой категории (но не фактические данные выборки). Я хочу построить это с помощью GNUplot 'candlesticks'. Я почти могу получить это:

the 'candlesticks' plot

кроме визуализации вес образцов с использованием ширины коробки.

можно ли это сделать в сюжете gnuplot 'candlesticks'? Как-то иначе?

Примечание: Я в основном заинтересован в том, чтобы сделать это с gnuplot. Другие предложения приветствуются, только если они легко модифицируемые и не требуют установки слишком дополнительных программ.

6
boxplot data-visualization gnuplot statistics

1 ответов

Ок, понял.

сценарий:

set terminal pngcairo  transparent enhanced font "arial,10" fontscale 1.0 size 500,    350 
set output 'candlesticks.png'
set boxwidth 0.2 absolute
set title "Box-and-whisker plot with median bar, whiskerbars, and variable box width" 
set xrange[0:5]
set yrange[0:25]

# Data columns: X Min 1stQuartile Median 3rdQuartile Max BoxWidth Titles

# set bars 4.0
set style fill empty
plot 'data.txt' using 1:3:2:6:5:7:xticlabels(8) with candlesticks title 'Quartiles' whiskerbars, \
  ''         using 1:4:4:4:4:7 with candlesticks lt -1 notitle

содержание образец data.txt:

# Data columns: X Min 1stQuartile Median 3rdQuartile Max BoxWidth Titles
1 5 7 10 15 24 0.3 Quick
2 6 8 11 16 23 0.4 Fox
3 5 7 11 17 22 0.5 Lazy
4 6 9 10 18 21 0.3 Dog

(заметим, что # строки не просто комментарии, мы действительно не указываем имена столбцов.)

результат:

Plot

12