Как я могу перечислить TDictionary в алфавитном порядке по ключу в Delphi 2009?

Как я могу использовать TEnumerator для просмотра моего TDictionary в отсортированном порядке по ключу?

У меня есть что-то вроде этого:

  var
    Dic: TDictionary<string, string>;
    Enum: TPair<string, string>;

  begin
    Dic := TDictionary<string, string>.create;
    Dic.Add('Tired', 'I have been working on this too long');
    Dic.Add('Early', 'It is too early in the morning to be working on this');
    Dic.Add('HelpMe', 'I need some help'); 
    Dic.Add('Dumb', 'Yes I know this example is dumb');

   { I want to do the following but do it in sorted order by Enum.Key }
    for Enum in Dic do
      some processing with Enum.Key and Enum.Value;

    Dic.Free;
  end;

поэтому я хотел бы обработать свой словарь в порядке: тупой, рано, HelpMe, устал.

к сожалению, помощь Delphi очень минимальна в описании того, как перечислители вообще и TEnumerator конкретно работают, и не дает примеров, которые я могу найти. В интернете также очень мало написано об использовании Перечислителей с дженериками в Дельфах.

и мой пример кода выше даже не использует TEnumerator, поэтому я смущен тем, как все это предназначено для использования.

спасибо, Барри, за ваш ответ.

мое предприятие в дженерики, так как я задал вопрос, было интересно. Я хотел начать внедрять их в свой код. Проблема "сортировки" была несколько озадачивающей, так как кажется, что дженерики, похоже, имеют встроенные методы сортировки, но нет ничего хорошего примеры или документацию о том, как это сделать.

в конце концов я сделал то, что предложил Барри, и встроил внешний индекс в словарь. И все же, это неправильно.

правда, тогда у меня был еще один сюрприз: я пытался заменить Габр ' s GPStringHash С родовым TDictionary. Код был немного чище с дженериками. Но суть в том, что TDictionary был более чем в 3 раза медленнее, чем Gabr. 1 704 667 звонков TryGetValue взял .45 секунд, но та же операция, что и у Габра .12 секунд. Я не уверен, почему, но, возможно, это так же просто, как Gabr, имеющий более быструю хэш-функцию и комбинацию букетирования. Или, может быть, дженерики должны были обобщать для каждого случая, и это по своей сути замедляет его.

никогда-менее, возможно, Барри или другие разработчики Delphi должны посмотреть на это, потому что ускорение в 3 раза может в конечном итоге принести пользу всем. Я лично предпочел бы использовать то, что встроено в язык, чем пакет 3rd party (даже такой же хороший, как Gabr), если предоставляется выбор. Но пока я буду придерживаться GPStringHash.

18
delphi delphi-2009 generics tdictionary

3 ответов

в моем случае я использую TDictionary .TKeyCollection класса.

function compareKey(const L, R: String): Integer;
begin
  Result := SysUtils.CompareText(L, R);
end;

function getReverseSortedKeyArray(dictionary: TDictionary<String, String): TArray<String>;
var
  keyArray: TArray<String>;
  keyCollection: TDictionary<String, String>.TKeyCollection;
begin
  keyCollection:= TDictionary<String, String>.TKeyCollection.Create(dictionary);
  try
    keyArray:= keyCollection.ToArray;
    TArray.Sort<String>(keyArray, TComparer<String>.Construct(compareKey));
  finally
    keyCollection.Free;
  end;

  Result := keyArray;
end;

пример использования :

var
  key: String;
  keyArray : TArray<String>;
begin
    keyArray  := getSortedKeyArray (dictionary);
    for key in keyArray  do
    begin
      // ...
    end;
end;
6

словарь является хэш-таблицей, поэтому он не хранит элементы в отсортированном порядке. TEnumerator прост - это просто средство перебора элементов.

чтобы получить элементы в порядке, вам нужно их отсортировать. Один из способов-поместить их в список и отсортировать список, например:

var
  list: TList<string>;
begin
  list := TList<string>.Create(Dic.Keys);
  try
    list.Sort;
    // process sorted list of items now
  finally
    list.Free;
  end;
end;
21

вот пример кода, который сортирует через Array<T> или TList<T>. Он сохраняет отношение пары ключевых значений, а также может быть изменен для сортировки по значению вместо ключа. Кроме того, он использует анонимный метод для сортировки.

обязательно указывайте Generics.Collections и Generics.Defaults в своем uses предложения. Первый метод сортировки с помощью TArray<T>:

procedure TestSortDictionaryViaArray;
var
  D: TDictionary<string, Integer>;
  A: TArray<TPair<string, Integer>>;
  P: TPair<string, Integer>;
begin
  D := TDictionary<string, Integer>.Create;

  D.Add('Test - 6', 6);
  D.Add('Test - 1', 1);
  D.Add('Test - 0', 0);
  D.Add('Test - 4', 4);
  D.Add('Test - 3', 3);
  D.Add('Test - 5', 0);
  D.Add('Test - 2', 2);

  A := D.ToArray;

  TArray.Sort<TPair<string, Integer>>(A,
    TComparer<TPair<string, Integer>>.Construct(
      function (const L, R: TPair<string, Integer>): Integer
      begin
        Result := CompareStr(L.Key, R.Key);
      end)
  );

  for P in A do
    ShowMessage(P.Key);
  D.Free;
end;

и это с помощью TList<T>:

procedure TestSortDictionaryViaList;
var
  D: TDictionary<string, Integer>;
  L: TList<TPair<string, Integer>>;
  P: TPair<string, Integer>;
begin
  D := TDictionary<string, Integer>.Create;

  D.Add('Test - 6', 6);
  D.Add('Test - 1', 1);
  D.Add('Test - 0', 0);
  D.Add('Test - 4', 4);
  D.Add('Test - 3', 3);
  D.Add('Test - 5', 0);
  D.Add('Test - 2', 2);

  L := TList<TPair<string, Integer>>.Create(D);

  L.Sort(
    TComparer<TPair<string, Integer>>.Construct(
      function (const L, R: TPair<string, Integer>): Integer
      begin
        Result := CompareStr(L.Key, R.Key);
      end)
  );

  for P in L do
    ShowMessage(P.Key);

  D.Free;
  L.Free;
end;

дополнительная (и ненужная) информация: Этот TList<T> метод должен быть освобожден список, тогда как TArray<T> не нуждается в освобождении. Внутренне,TList<T> использует TArray<T> (например, TArray есть BinarySearch() метод класса, и TList<T> имеет метод BinarySearch).

4