Каков наилучший способ программирования задержки в Delphi?

сценарий: Вы хотите выполнить несколько последовательных действий с определенной задержкой между ними.

это правильный способ запрограммировать задержку?

Я бы сказал, что есть лучшие способы, см. ниже.

если ответ да, то почему это лучше, чем вызовом Sleep()?

спать в главном потоке-плохая идея: помните, что парадигма windows управляется событиями, i.e выполняйте свою задачу на основе действия и тогда пусть система решает, что делать дальше. Спать в потоке также плохо, так как вы можете остановить важные сообщения из системы (в случае выключения и т. д.).

ваши возможности:

• обрабатывайте свои действия от таймера в основном потоке, как государственная машина. Следите за состоянием и просто выполните действие, которое представляет это конкретное состояние, когда срабатывает событие таймера. Это работает для кода, который заканчивается за короткое время для каждого таймера событие.

• поместите строку действий в поток. Используйте тайм-аут события в качестве таймера, чтобы избежать замораживания потока при вызовах сна. Часто эти типы действий связаны с вводом-выводом, где вы вызываете функции со встроенным таймаутом. В этих случаях номер тайм-аута служит естественной задержкой. Так строятся все мои коммуникационные библиотеки.

пример второй вариант:

procedure StartActions(const ShutdownEvent: TSimpleEvent);
begin
  TThread.CreateAnonymousThread(
    procedure
    var
      waitResult: TWaitResult;
      i: Integer;
    begin
      i := 0;
      repeat
        if not Assigned(ShutdownEvent) then
          break;
        waitResult := ShutdownEvent.WaitFor(2000);
        if (waitResult = wrTimeOut) then
        begin
          // Do your stuff
          // case i of
          //   0: ;
          //   1: ;
          // end;
          Inc(i);
          if (i = 10) then
            break;
        end
        else 
          break;  // Abort actions if process shutdown
      until Application.Terminated;
    end
  ).Start;
end;

звоните это:

var
  SE: TSimpleEvent;
...
SE := TSimpleEvent.Create(Nil,False,False,'');
StartActions(SE);

и прервать действия (в случае выключения программы или ручного прерывания):

SE.SetEvent;
...
FreeAndNil(SE);

это создаст анонимный поток, где время управляется TSimpleEvent. Когда линия действий будет готова, нить будет самоуничтожена. Объект события "global" может использоваться для прерывания действий вручную или во время завершения работы программы.

после энергичного испытания сна против никакого сна... Я решил, что опция без сна гораздо менее склонна давать пользователю ощущение, что в программном обеспечении есть ситуация блокировки.

uses System.Math, System.Types, System.Classes, System.Diagnostics, Vcl.Forms;

// written by Joseph A Poirier, 2016.06-17, converted 2016.12, added try-finally 2017.01-31 
// TThread.sleep(ms) replaced with good old-fashioned math.
// Pause a process, while allowing your forms to continue working,
// move, resize, and close (even mid-process).
procedure handleEvents(Milliseconds: Integer);
 var
   DoneTime, TimeLeft : LongWord;

   sw: TStopwatch;
begin

  DoneTime :=  TThread.GetTickCount + LongWord(Milliseconds);

  TimeLeft := 100;
  sw := TStopwatch.StartNew; // timing entire process
  try
    While ( TimeLeft > 0 ) do
     begin
       TimeLeft := DoneTime - TThread.GetTickCount;

       // continuously check application processes every 3 ms.
       if (TimeLeft mod 3 = 0) or ( TThread.GetTickCount > DoneTime ) then
        begin
         Application.ProcessMessages(); // clear all Vcl messages  // part of Vcl.Forms
         CheckSynchronize(); // check all threaded events
       end;

       if ( TThread.GetTickCount > DoneTime ) then break;
    end;
  finally // ensure stop is executed, whether or not close exceptions occur.
    sw.Stop;
    sw.ElapsedMilliseconds; // captures full run time for debug
  end;

end;

procedure Delay(TickTime : Integer);
 var
 Past: longint;
 begin
 Past := GetTickCount;
 repeat
 application.ProcessMessages;
 Until (GetTickCount - Past) >= longint(TickTime);
end;