Лучший способ использовать метод "isa"?

вы можете обернуть проверки безопасности в скаляр, а затем использовать скаляр в качестве метода для поддержания чистоты:

use Scalar::Util 'blessed';

my $isa = sub {blessed $_[0] and $_[0]->isa($_[1])};

my $obj;

if ($obj->$isa('object')) { ... } # returns false instead of throwing an error 

$obj = {};

if ($obj->$isa('object')) { ... } # returns false as well

bless $obj => 'object';

if ($obj->$isa('object')) { say "we got an object" }

отметим, что $obj->$isa(...) - это просто другое написание $isa->($obj, ...) таким образом, вызов метода фактически не происходит (поэтому он избегает каких-либо ошибок).

и вот какой-то код, который позволит вам позвонить isa на что угодно, а затем проверьте результат (вдохновленный ответом Axeman):

{package ISA::Helper;
    use Scalar::Util;
    sub new {
        my ($class, $obj, $type) = @_;
        my $blessed = Scalar::Util::blessed $obj;
        bless {
            type    => $type,
            obj     => $obj,
            blessed => $blessed,
            isa     => $blessed && $obj->isa($type)
        } => $class
    }
    sub blessed         {$_[0]{blessed}}
    sub type            {$_[0]{isa}}
    sub ref     {ref     $_[0]{obj}}
    sub defined {defined $_[0]{obj}}

    use overload fallback => 1,
                 bool     => sub {$_[0]{isa}};
    sub explain {
        my $self = shift;
        $self->type    ? "object is a $$self{type}" :
        $self->blessed ? "object is a $$self{blessed} not a $$self{type}" :
        $self->ref     ? "object is a reference, but is not blessed" :
        $self->defined ? "object is defined, but not a reference"
                       : "object is not defined"
    }
}
my $isa = sub {ISA::Helper->new(@_)};

путем размещения ссылки на код в скаляр, его можно вызвать на что угодно без ошибок:

my @items = (
    undef,
    5,
    'five',
    \'ref',
    bless( {} => 'Other::Pkg'),
    bless( {} => 'My::Obj'),
);

for (@items) {
    if (my $ok = $_->$isa('My::Obj')) {
        print 'ok: ', $ok->explain, "\n";
    } else {
        print 'error: ', $ok->explain, "\n";
    }
}

print undef->$isa('anything?')->explain, "\n";

my $obj = bless {} => 'Obj';
print $obj->$isa('Obj'), "\n";

my $ref = {};
if (my $reason = $ref->$isa('Object')) {
    say "all is well"
} else {
    given ($reason) {
        when (not $_->defined) {say "not defined"}
        when (not $_->ref)     {say "not a reference"}
        when (not $_->blessed) {say "not a blessed reference"}
        when (not $_->type)    {say "not correct type"}
    }
}

печатается:

error: object is not defined
error: object is defined, but not a reference
error: object is defined, but not a reference
error: object is a reference, but is not blessed
error: object is a Other::Pkg not a My::Obj
ok: object is a My::Obj
object is not defined
1
not a blessed reference

если кто-то думает, что это действительно полезно, дайте мне знать, и я поставлю его на CPAN.

это может показаться немного суровым для Perl, но ни один из них не идеален. Оба скрывают тот факт, что объекты-это Галс на Perl. The blessed идиома многословна и содержит более пары простых частей.

blessed( $object ) && object->isa( 'Class' )

я бы предпочел что-то вроде этого:

object_isa( $object, 'Class' )

нет логической операции, чтобы ошибиться, и большинство непригодных применений будут отсеяны компилятором. (Кавычки не закрыты, запятая отсутствует, родители не закрыты, вызов object_ia вместо...)

потребовались бы неопределенные скаляры, простые скаляры (если они не являются именем класса, которое это Class), не благословленные ссылки и благословенные ссылки, которые не расширяют "класс" и говорят вам, что нет, они не Class объекты. Если только мы не хотим пойти по пути autobox - ing все, нам понадобится функции что говорит нам просто.

возможно, есть третий параметр для $how_close, но там также может быть что-то вроде этого:

if ( my $ranking = object_isa( $object, 'Class' )) { 
   ...
}
else { 
   given ( $ranking ) { 
       when ( NOT_TYPE )    { ... }
       when ( NOT_BLESSED ) { ... }
       when ( NOT_REF )     { ... }
       when ( NOT_DEFINED ) { ... }
   }
}

о единственном способе, которым я могу видеть, что мы могли бы вернуть это много уникальный falses-это если $ranking был благословлен в класс, который перегрузил логический оператор для возврата false, если функция не вернула одно значение, указывающее на связь ISA.

тем не менее, он может иметь несколько членов: EXACTLY, INHERITS, 'реализует,Сросткиor evenглумится`

я устал печатать это тоже:

$object->can( 'DOES' ) && $object->DOES( 'role' )

потому что я пытаюсь реализовать будущее в меньших perls (по идее, что люди могут нахмуриться на мое загрязнение UNIVERSAL) на них.