Объединить два списка

Я ищу, чтобы объединить 2 списка в F# чисто функциональным способом. Мне трудно понять синтаксис.

скажем, у меня есть кортеж ([5;3;8],[2;9;4])

когда я вызываю функцию, она должна вернуть [5;2;3;9;8;4]

вот почему я до сих пор, что это неправильно, я уверен. Если бы кто-то мог объяснить это простым способом, я был бы благодарен.

let rec interleave (xs,ys) = function
|([], ys) -> ys
|(x::xs, y::ys) -> x :: y::  interleave (xs,ys)
10
f# f#-scripting list recursion

4 ответов

функция почти право. let f = function сокращенно от let f x = match x with таким образом, вам не нужны явные args. Кроме того, ваш алгоритм нуждается в некоторой доработке.

let rec interleave = function //same as: let rec interleave (xs, ys) = match xs, ys with
  |([], ys) -> ys
  |(xs, []) -> xs
  |(x::xs, y::ys) -> x :: y :: interleave (xs,ys)

interleave ([5;3;8],[2;9;4]) //output: [5; 2; 3; 9; 8; 4]
11

один важный момент заключается в том, что функция не является правильным. Это не удается с вводом ([1;2;3], []) так как вы пропустили случай (xs, []) в соответствии с шаблоном. Более того, аргументы лучше в форме карри, чтобы их было проще использовать с частичным применением. Вот исправленная версия:

let rec interleave xs ys =
    match xs, ys with
    | [], ys -> ys
    | xs, [] -> xs
    | x::xs', y::ys' -> x::y::interleave xs' ys'

вы можете видеть, что функция не хвост-рекурсивный так как он применяет минусы (::) конструктор дважды после рекурсивного вызова вернулся. Один интересный способ сделать его хвост-рекурсивным-использовать выражение последовательности:

let interleave xs ys =
    let rec loop xs ys = 
       seq {
             match xs, ys with
             | [], ys -> yield! ys
             | xs, [] -> yield! xs
             | x::xs', y::ys' -> 
                   yield x
                   yield y
                   yield! loop xs' ys'
            }
    loop xs ys |> List.ofSeq
8

вы можете использовать эту возможность для определения более общей функции более высокого порядка -zipWith, а затем реализовать interleave использовать его.

let rec zipWith f xlist ylist = 
  match f, xlist, ylist with
  | f, (x :: xs), (y :: ys) -> f x y :: zipWith f xs ys
  | _, _, _ -> []

let interleave xs ys = zipWith (fun a b -> [a; b]) xs ys |> List.concat

Edit:

как @pad сказал ниже, F# уже имеет zipWith под названиемList.map2. Таким образом, вы можете переписать interleave следующим образом:

let interleave xs ys = List.map2 (fun a b -> [a; b]) xs ys |> List.concat
2

из OP неясно, что должно произойти, если списки имеют разные длины, но вот общая, хвостовая рекурсивная реализация, которая полностью потребляет оба списка:

// 'a list -> 'a list -> 'a list
let interleave xs ys =
    let rec imp xs ys acc =
        match xs, ys with
        |    [],    [] -> acc
        | x::xs,    [] -> imp xs [] (x::acc)
        |    [], y::ys -> imp [] ys (y::acc)
        | x::xs, y::ys -> imp xs ys (y::x::acc)
    imp xs ys [] |> List.rev

примеры:

> interleave [5;3;8] [2;9;4];;
val it : int list = [5; 2; 3; 9; 8; 4]
> interleave [] [1..3];;
val it : int list = [1; 2; 3]
> interleave [1..3] [42];;
val it : int list = [1; 42; 2; 3]
> interleave [1..3] [42;1337];;
val it : int list = [1; 42; 2; 1337; 3]
> interleave [42; 1337] [1..3];;
val it : int list = [42; 1; 1337; 2; 3]
1