Оценка члена записи F#

почему t.b оценивается по каждому звонку? И есть ли способ, как заставить его оценить только один раз?

type test =
  { a: float }
  member x.b =
    printfn "oh no"
    x.a * 2.

let t = { a = 1. }
t.b
t.b
12
f# member record

4 ответов

Это свойство; вы в основном называя get_b() член.

Если вы хотите, чтобы эффект произошел один раз с конструктором, вы можете использовать класс:

type Test(a:float) =
    // constructor
    let b =   // compute it once, store it in a field in the class
        printfn "oh no"
        a * 2.
    // properties
    member this.A = a
    member this.B = b
13

альтернативная версия ответа Брайана, которая будет оценивать b не более одного раза, но не будет оценивать его вообще, если B никогда не используется

type Test(a:float) =
    // constructor
    let b = lazy
                 printfn "oh no"
                 a * 2.
    // properties
    member this.A = a
    member this.B = b.Value
15

в ответ на ваши комментарии в сообщении Брайана вы можете подделать выражения записи копирования и обновления, используя необязательные/именованные args. Например:

type Person(?person:Person, ?name, ?age) =

    let getExplicitOrCopiedArg arg argName copy =
        match arg, person with
        | Some(value), _ -> value
        | None, Some(p) -> copy(p)
        | None, None -> nullArg argName

    let name = getExplicitOrCopiedArg name "name" (fun p -> p.Name)
    let age = getExplicitOrCopiedArg age "age" (fun p -> p.Age)

    member x.Name = name
    member x.Age = age

let bill = new Person(name = "Bill", age = 20)
let olderBill = new Person(bill, age = 25)

printfn "Name: %s, Age: %d" bill.Name bill.Age
printfn "Name: %s, Age: %d" olderBill.Name olderBill.Age
4

предыдущие ответы предлагают переключиться на класс, а не использовать запись. Если вы хотите остаться с записями (для их простого синтаксиса и неизменяемости), вы можете воспользоваться следующим подходом:

type test =
    { a : float
      b : float }
    static member initialize (t: test) =
        { t with b = t.a * 2. }

Это полезно, если экземпляр test создается другой библиотекой (например, поставщиком данных из веб-службы или базы данных). При таком подходе вы должны помнить, чтобы передать любой экземпляр test что вы получаете от этого API через функцию initialize перед использованием это в вашем коде.

1