Определить раскладку клавиатуры OS X ("Источник ввода") в терминале / скрипте?

Примечание: @MarkSetchell заслуживает уважения за то, что придумал фундаментальный подход-где [начать] смотреть и какие инструменты использовать. После дальнейшего исследования и взад и вперед в комментариях я думал, что суммирую решение (начиная с OS X 10.9.1):

do shell script "defaults read ~/Library/Preferences/com.apple.HIToolbox.plist \
 AppleSelectedInputSources | \
 egrep -w 'KeyboardLayout Name' | sed -E 's/^.+ = \"?([^\"]+)\"?;$/\1/'"

^{обратите внимание, как \ убежал, а \ в интересах AppleScript, что гарантирует, что просто \ достигнет оболочки. Если вы хотите выполнить ту же команду непосредственно из оболочки, это будет выглядеть так:
defaults read ~/Library/Preferences/com.apple.HIToolbox.plist AppleSelectedInputSources | egrep -w 'KeyboardLayout Name' | sed -E 's/^.+ = \"?([^\"]+)\"?;$//'}

• текущая выбранная раскладка клавиатуры хранится в на уровне пользователя~/Library/Preferences/com.apple.HIToolbox.plist верхнего уровня ключ AppleSelectedInputSources, подраздел KeyboardLayout Name.
• defaults read обеспечивает настоящее настройки считываются (к сожалению, начиная с OSX 10.9, в противном случае superior /usr/libexec/PlistBuddy видит только кэшированные версия, которая может быть не синхронизирована).
• С defaults read невозможно вернуть значение отдельного ключа, значение процента должно быть извлечено через egrep и sed - одно предостережение есть что defaults read условно использует двойные кавычки вокруг ключевых имен и строковых значений, в зависимости от того, являются ли они одним словом (без пунктуации) или нет.

обновление:

получается, что AppleScript может анализировать списки свойств, но это немного похоже на вытягивание зубов. Кроме того, невероятно, что проблема потенциально не полностью текущих значений также влияет на синтаксический анализ AppleScript.

Ниже приведен обработчик AppleScript, который получает текущую раскладку клавиатуры; он использует do shell script-на основе обходного пути, чтобы убедиться, что файл plist является текущим, но в противном случае использует функции списка свойств AppleScript, через Property List Suite приложения System Events.

Примечание: очевидно, выше shell-based подход очень короче в этом случае, а код ниже демонстрирует общие методы работы со списками свойств.

# Example call.
set activeKbdLayout to my getActiveKeyboardLayout() # ->, e.g., "U.S."

on getActiveKeyboardLayout()

  # Surprisingly, using POSIX-style paths (even with '~') works with 
  # the `property list file` type.
  set plistPath to "~/Library/Preferences/com.apple.HIToolbox.plist"

  # !! First, ensure that the plist cache is flushed and that the
  # !! *.plist file contains the current value; simply executing
  # !! `default read` against the file - even with a dummy
  # !! key - does that.
  try
    do shell script "defaults read " & plistPath & " dummy"
  end try

  tell application "System Events"

    repeat with pli in property list items of ¬
      property list item "AppleSelectedInputSources" of ¬
      property list file plistPath
      # Look for (first) entry with key "KeyboardLayout Name" and return
      # its value.
      # Note: Not all entries may have a 'KeyboardLayout Name' key, 
      # so we must ignore errors.
      try
        return value of property list item "KeyboardLayout Name" of pli
      end try
    end repeat

  end tell
end getActiveKeyboardLayout