Отключить все ограничения таблицы в Oracle

Как отключить все ограничения таблицы в Oracle с помощью одной команды? Это может быть как для одной таблицы, списка таблиц, так и для всех таблиц.

10 ответов


лучше избегать написания временных файлов катушек. Используйте блок PL / SQL. Вы можете запустить это из SQL * Plus или поместить эту вещь в пакет или процедуру. Соединение с USER_TABLES существует, чтобы избежать ограничений представления.

маловероятно, что вы действительно хотите отключить все ограничения (включая NOT NULL, первичные ключи и т. д.). Вы должны подумать о том, чтобы поместить constraint_type в предложение WHERE.

BEGIN
  FOR c IN
  (SELECT c.owner, c.table_name, c.constraint_name
   FROM user_constraints c, user_tables t
   WHERE c.table_name = t.table_name
   AND c.status = 'ENABLED'
   AND NOT (t.iot_type IS NOT NULL AND c.constraint_type = 'P')
   ORDER BY c.constraint_type DESC)
  LOOP
    dbms_utility.exec_ddl_statement('alter table "' || c.owner || '"."' || c.table_name || '" disable constraint ' || c.constraint_name);
  END LOOP;
END;
/

включение ограничений снова немного сложнее-вы необходимо включить ограничения первичного ключа, прежде чем ссылаться на них в ограничении внешнего ключа. Это можно сделать, используя заказ on constraint_type. 'P' = первичный ключ,' R ' = внешний ключ.

BEGIN
  FOR c IN
  (SELECT c.owner, c.table_name, c.constraint_name
   FROM user_constraints c, user_tables t
   WHERE c.table_name = t.table_name
   AND c.status = 'DISABLED'
   ORDER BY c.constraint_type)
  LOOP
    dbms_utility.exec_ddl_statement('alter table "' || c.owner || '"."' || c.table_name || '" enable constraint ' || c.constraint_name);
  END LOOP;
END;
/

чтобы подсчитать зависимости между ограничениями:

SET Serveroutput ON
BEGIN
    FOR c IN
    (SELECT c.owner,c.table_name,c.constraint_name
    FROM user_constraints c,user_tables t
    WHERE c.table_name=t.table_name
    AND c.status='ENABLED'
    ORDER BY c.constraint_type DESC,c.last_change DESC
    )
    LOOP
        FOR D IN
        (SELECT P.Table_Name Parent_Table,C1.Table_Name Child_Table,C1.Owner,P.Constraint_Name Parent_Constraint,
            c1.constraint_name Child_Constraint
        FROM user_constraints p
        JOIN user_constraints c1 ON(p.constraint_name=c1.r_constraint_name)
        WHERE(p.constraint_type='P'
        OR p.constraint_type='U')
        AND c1.constraint_type='R'
        AND p.table_name=UPPER(c.table_name)
        )
        LOOP
            dbms_output.put_line('. Disable the constraint ' || d.Child_Constraint ||' (on table '||d.owner || '.' ||
            d.Child_Table || ')') ;
            dbms_utility.exec_ddl_statement('alter table ' || d.owner || '.' ||d.Child_Table || ' disable constraint ' ||
            d.Child_Constraint) ;
        END LOOP;
    END LOOP;
END;
/

Это не одна команда, но вот как я это делаю. Следующий сценарий был разработан для работы в SQL * Plus. Обратите внимание, что я намеренно написал это, чтобы работать только в текущей схеме.

set heading off

spool drop_constraints.out

select
    'alter table ' || 
    owner || '.' || 
    table_name || 
    ' disable constraint ' || -- or 'drop' if you want to permanently remove
    constraint_name || ';'
from
    user_constraints;

spool off

set heading on

@drop_constraints.out

чтобы ограничить то, что вы отбрасываете, фильтр добавляет предложение where в инструкцию select: -

  • фильтр на constraint_type, чтобы удалить только определенные типы ограничений

использовать следующий курсор, чтобы отключить все ограничения.. И alter query для ограничений enable...

DECLARE

cursor r1 is select * from user_constraints;
cursor r2 is select * from user_tables;

BEGIN
  FOR c1 IN r1
  loop
    for c2 in r2
    loop
       if c1.table_name = c2.table_name and c1.status = 'ENABLED' THEN
        dbms_utility.exec_ddl_statement('alter table ' || c1.owner || '.' || c1.table_name || ' disable constraint ' || c1.constraint_name);
       end if;
    end loop;
  END LOOP;
END;
/

Это может быть написано в PL/SQL довольно просто на основе системного представления DBA/ALL / USER_CONSTRAINTS, но различные детали не так тривиальны, как кажется. Вы должны быть осторожны с порядком, в котором это делается, а также учитывать наличие уникальных индексов.

порядок важен, потому что вы не можете удалить уникальный или первичный ключ, на который ссылается внешний ключ, и могут быть внешние ключи в таблицах в других схемах, которые ссылаются на первичный ключи в своем собственном, поэтому, если у вас нет прав ALTER ANY TABLE, вы не можете удалить эти PKs и UKs. Также вы не можете переключить уникальный индекс на не уникальный индекс, поэтому вам нужно удалить его, чтобы удалить ограничение (по этой причине почти всегда лучше реализовать уникальные ограничения как "реальное" ограничение, поддерживаемое не уникальным индексом).


не похоже, что вы можете сделать это с помощью одной команды, но здесьэто самое близкое к нему, что я мог найти.


это еще один способ отключения ограничений (он пришел из https://asktom.oracle.com/pls/asktom/f?p=100:11:2402577774283132::::P11_QUESTION_ID:399218963817)

WITH qry0 AS
       (SELECT    'ALTER TABLE '
               || child_tname
               || ' DISABLE CONSTRAINT '
               || child_cons_name
                 disable_fk
              ,   'ALTER TABLE '
               || parent_tname
               || ' DISABLE CONSTRAINT '
               || parent.parent_cons_name
                 disable_pk
          FROM (SELECT a.table_name child_tname
                      ,a.constraint_name child_cons_name
                      ,b.r_constraint_name parent_cons_name
                      ,LISTAGG ( column_name, ',') WITHIN GROUP (ORDER BY position) child_columns
                  FROM user_cons_columns a
                      ,user_constraints b
                 WHERE a.constraint_name = b.constraint_name AND b.constraint_type = 'R'
                GROUP BY a.table_name, a.constraint_name
                        ,b.r_constraint_name) child
              ,(SELECT a.constraint_name parent_cons_name
                      ,a.table_name parent_tname
                      ,LISTAGG ( column_name, ',') WITHIN GROUP (ORDER BY position) parent_columns
                  FROM user_cons_columns a
                      ,user_constraints b
                 WHERE a.constraint_name = b.constraint_name AND b.constraint_type IN ('P', 'U')
                GROUP BY a.table_name, a.constraint_name) parent
         WHERE child.parent_cons_name = parent.parent_cons_name
           AND (parent.parent_tname LIKE 'V2_%' OR child.child_tname LIKE 'V2_%'))
SELECT DISTINCT disable_pk
  FROM qry0
UNION
SELECT DISTINCT disable_fk
  FROM qry0;

работает


в скрипте" disable " предложение order by должно быть таким:

ORDER BY c.constraint_type DESC, c.last_change DESC

цель этого предложения-отключить ограничения в правильном порядке.


SELECT 'ALTER TABLE '||substr(c.table_name,1,35)|| 
' DISABLE CONSTRAINT '||constraint_name||' ;' 
FROM user_constraints c, user_tables u 
WHERE c.table_name = u.table_name; 

этот оператор возвращает команды, которые отключают все ограничения, включая первичный ключ, внешние ключи и другие ограничения.


с курсором для цикла (user = 'TRANEE', table = 'D')

declare
    constr all_constraints.constraint_name%TYPE;
begin
    for constr in
        (select constraint_name from all_constraints
        where table_name = 'D'
        and owner = 'TRANEE')
    loop
        execute immediate 'alter table D disable constraint '||constr.constraint_name;
    end loop;
end;
/

(Если вы измените disable на enable, вы можете включить все ограничения)