Пакетная / поиск и редактирование строк в TXT-файле

Я хочу создать пакет, который находит определенные строки в пакетном файле и может редактировать эти строки.

пример:

/ / TXT ФАЙЛ//

ex1
ex2
ex3
ex4

Я хочу, чтобы пакетный файл нашел " ex3 "и отредактировал его в "ex5", чтобы он выглядел так:

ex1
ex2
ex5
ex4

8 ответов


в собственной установке Windows вы можете использовать пакет (cmd.exe) или vbscript без необходимости получения внешних инструментов. вот пример в vbscript

Set objFS = CreateObject("Scripting.FileSystemObject")
strFile = "c:\test\file.txt"
Set objFile = objFS.OpenTextFile(strFile)
Do Until objFile.AtEndOfStream
    strLine = objFile.ReadLine
    If InStr(strLine,"ex3")> 0 Then
        strLine = Replace(strLine,"ex3","ex5")
    End If 
    WScript.Echo strLine
Loop    

сохранить как myreplace.VBS и в командной строке

c:\test> cscript /nologo myreplace.vbs  > newfile
c:\test> ren newfile file.txt

нет функции поиска и замены или редактирования потока в командной строке в XP или 2k3 (не знаю о vista или за ее пределами). Таким образом, вам нужно будет использовать скрипт, подобный опубликованному Ghostdog, или инструмент поиска и замены, такой как sed.

Существует несколько способов сделать это, как показывает этот скрипт:

@echo off
    SETLOCAL=ENABLEDELAYEDEXPANSION

    rename text.file text.tmp
    for /f %%a in (text.tmp) do (
        set foo=%%a
        if !foo!==ex3 set foo=ex5
        echo !foo! >> text.file) 
del text.tmp

пример ghostdog74 предоставил ядро того, что мне нужно, так как я никогда не писал никаких vbs раньше и должен был это сделать. Это не идеально, но я конкретизировал пример в полный сценарий на случай, если кто-то найдет его полезным.

'ReplaceText.vbs

Option Explicit

Const ForAppending = 8
Const TristateFalse = 0 ' the value for ASCII
Const Overwrite = True

Const WindowsFolder = 0
Const SystemFolder = 1
Const TemporaryFolder = 2

Dim FileSystem
Dim Filename, OldText, NewText
Dim OriginalFile, TempFile, Line
Dim TempFilename

If WScript.Arguments.Count = 3 Then
    Filename = WScript.Arguments.Item(0)
    OldText = WScript.Arguments.Item(1)
    NewText = WScript.Arguments.Item(2)
Else
    Wscript.Echo "Usage: ReplaceText.vbs <Filename> <OldText> <NewText>"
    Wscript.Quit
End If

Set FileSystem = CreateObject("Scripting.FileSystemObject")
Dim tempFolder: tempFolder = FileSystem.GetSpecialFolder(TemporaryFolder)
TempFilename = FileSystem.GetTempName

If FileSystem.FileExists(TempFilename) Then
    FileSystem.DeleteFile TempFilename
End If

Set TempFile = FileSystem.CreateTextFile(TempFilename, Overwrite, TristateFalse)
Set OriginalFile = FileSystem.OpenTextFile(Filename)

Do Until OriginalFile.AtEndOfStream
    Line = OriginalFile.ReadLine

    If InStr(Line, OldText) > 0 Then
        Line = Replace(Line, OldText, NewText)
    End If 

    TempFile.WriteLine(Line)
Loop

OriginalFile.Close
TempFile.Close

FileSystem.DeleteFile Filename
FileSystem.MoveFile TempFilename, Filename

Wscript.Quit

Если вы находитесь в Windows, вы можете использовать пердеть (Find And Replace Text). Это только 1 один *.exe-файл (не требуется библиотека).

все, что вам нужно-это запустить:

fart.exe your_batch_file.bat ex3 ex5

вот такие вещи sed был сделан для (Конечно, для этого вам нужен sed в вашей системе).

sed' s/ex3/ex5 / g ' вход.тхт > выход.txt

вам понадобится либо система Unix, либо Windows Cygwin вид платформы для этого.
Существует также GnuWin32 для sed. (установка и использование GnuWin32).


вы всегда можете использовать " FAR " = "Find and Replace". Он написан под java, поэтому он работает там, где работает Java (почти везде). Работает с каталогами и подкаталогами, ищет и заменяет внутри файлов, также может переименовывать их. Также можно переименовывать массовые файлы.Лицензия = бесплатно, как для физических лиц, так и для comapnies. Очень быстро и поддерживается разработчиком. Найти его здесь: http://findandreplace.sourceforge.net/

также вы можете использовать GrepWin. Работает довольно много тот же. Вы можете найти его здесь: http://tools.tortoisesvn.net/grepWin.html


@echo off
set "replace=something"
set "replaced=different"

set "source=Source.txt"
set "target=Target.txt"

setlocal enableDelayedExpansion
(
   for /F "tokens=1* delims=:" %%a in ('findstr /N "^" %source%') do (
      set "line=%%b"
      if defined line set "line=!line:%replace%=%replaced%!"
      echo(!line!
   )
) > %target%
endlocal

источник. Надеюсь, это кому-то поможет.


вы можете сделать так:

rename %CURR_DIR%\ftp\mywish1.txt text.txt
for /f %%a in (%CURR_DIR%\ftp\text.txt) do (
if "%%a" EQU "ex3" ( 
echo ex5 >> %CURR_DIR%\ftp\mywish1.txt
) else (
echo %%a >> %CURR_DIR%\ftp\mywish1.txt
)
)
del %CURR_DIR%\ftp\text.txt