Perl WWW:: Mechanize (или LWP) получить URL перенаправления

поэтому я использую WWW::Mechanize для обхода сайтов. Он отлично работает, за исключением случаев, когда я запрашиваю url-адрес, такой как:

http://www.levi.com/

Я перенаправлен на:

http://us.levi.com/home/index.jsp

и для моего скрипта мне нужно знать, что это перенаправление имело место и на какой url я был перенаправлен. Есть в любом случае, чтобы обнаружить это с WWW::Mechanize или LWP а затем получить перенаправленный url? Спасибо!

8
lwp perl redirect url www-mechanize

2 ответов

use strict;
use warnings;
use URI;
use WWW::Mechanize;

my $url = 'http://...';
my $mech = WWW::Mechanize->new(autocheck => 0);
$mech->max_redirect(0);
$mech->get($url);

my $status = $mech->status();
if (($status >= 300) && ($status < 400)) {
  my $location = $mech->response()->header('Location');
  if (defined $location) {
    print "Redirected to $location\n";
    $mech->get(URI->new_abs($location, $mech->base()));
  }
}

если код состояния равен 3 * х, затем вы должны проверить заголовки ответов для URL перенаправления.

10

вы также можете добраться до того же места, проверив redirects() метод объекта response.

use strict;
use warnings;
use feature qw( say );

use WWW::Mechanize;

my $ua = WWW::Mechanize->new;
my $res = $ua->get('http://metacpan.org');

my @redirects = $res->redirects;
say 'request uri: ' . $redirects[-1]->request->uri;
say 'location header: ' . $redirects[-1]->header('Location');

принты:

request uri: http://metacpan.org
location header: https://metacpan.org/

см.https://metacpan.org/pod/HTTP::Response# $r - %3Eredirects имейте в виду, что более одного перенаправления может привести вас к вашему текущему местоположению. Так что вы можете проверить каждый ответ, который возвращается через redirects().

0