Поиск символов, отличных от ASCII, в Столбцах varchar с помощью SQL Server

вот решение для поиска одного столбца с помощью PATINDEX.
Он также отображает код StartPosition, InvalidCharacter и ASCII.

select line,
  patindex('%[^ !-~]%' COLLATE Latin1_General_BIN,Line) as [Position],
  substring(line,patindex('%[^ !-~]%' COLLATE Latin1_General_BIN,Line),1) as [InvalidCharacter],
  ascii(substring(line,patindex('%[^ !-~]%' COLLATE Latin1_General_BIN,Line),1)) as [ASCIICode]
from  staging.APARMRE1
where patindex('%[^ !-~]%' COLLATE Latin1_General_BIN,Line) >0

этот скрипт ищет символы, отличные от ascii, в одном столбце. Он генерирует строку всех допустимых символов, здесь кодовая точка 32 до 127. Затем он ищет строки, которые не соответствуют списку:

declare @str varchar(128)
declare @i int
set @str = ''
set @i = 32
while @i <= 127
    begin
    set @str = @str + '|' + char(@i)
    set @i = @i + 1
    end

select  col1
from    YourTable
where   col1 like '%[^' + @str + ']%' escape '|'

Я успешно запускал этот бит кода

declare @UnicodeData table (
     data nvarchar(500)
)
insert into 
    @UnicodeData
values 
    (N'Horse�')
    ,(N'Dog')
    ,(N'Cat')

select
    data
from
    @UnicodeData 
where
    data collate LATIN1_GENERAL_BIN != cast(data as varchar(max))

что хорошо работает для известных столбцов.

для дополнительного кредита я написал этот быстрый скрипт для поиска всех столбцов nvarchar в данной таблице для символов Юникода.

declare 
    @sql    varchar(max)    = ''
    ,@table sysname         = 'mytable' -- enter your table here

;with ColumnData as (
    select
        RowId               = row_number() over (order by c.COLUMN_NAME)
        ,c.COLUMN_NAME
        ,ColumnName         = '[' + c.COLUMN_NAME + ']'
        ,TableName          = '[' + c.TABLE_SCHEMA + '].[' + c.TABLE_NAME + ']' 
    from
        INFORMATION_SCHEMA.COLUMNS c
    where
        c.DATA_TYPE         = 'nvarchar'
        and c.TABLE_NAME    = @table
)
select
    @sql = @sql + 'select FieldName = ''' + c.ColumnName + ''',         InvalidCharacter = [' + c.COLUMN_NAME + ']  from ' + c.TableName + ' where ' + c.ColumnName + ' collate LATIN1_GENERAL_BIN != cast(' + c.ColumnName + ' as varchar(max)) '  +  case when c.RowId <> (select max(RowId) from ColumnData) then  ' union all ' else '' end + char(13)
from
    ColumnData c

-- check
-- print @sql
exec (@sql)

Я не поклонник динамического SQL, но он использует его для исследовательских запросов, подобных этому.

запуск различных решений на некоторых реальных данных-12M строк varchar длина ~30, около 9k изворотливых строк, нет полнотекстового индекса в игре, решение patIndex является самым быстрым, и он также выбирает большинство строк.

(предварительно пробежал км. чтобы установить кэш в известное состояние, запустите 3 процесса и, наконец, снова запустите km - последние 2 запуска km дали время в течение 2 секунд)

решение patindex от Gerhard Weiss -- Runtime 0: 38, возвращает 9144 строки

select dodgyColumn from myTable fcc
WHERE  patindex('%[^ !-~]%' COLLATE Latin1_General_BIN,dodgyColumn ) >0

решение подстрок-чисел по MT. -- Время выполнения 1: 16, возвращено 8996 строк

select dodgyColumn from myTable fcc
INNER JOIN dbo.Numbers32k dn ON dn.number<(len(fcc.dodgyColumn ))
WHERE ASCII(SUBSTRING(fcc.dodgyColumn , dn.Number, 1))<32 
    OR ASCII(SUBSTRING(fcc.dodgyColumn , dn.Number, 1))>127

решение udf от Deon Robertson -- Runtime 3: 47, возвращает 7316 строк

select dodgyColumn 
from myTable 
where dbo.udf_test_ContainsNonASCIIChars(dodgyColumn , 1) = 1

существует определенная пользователем функция, доступная в интернете "разбор буквенно-цифровой". Google UDF анализирует буквенно-цифровой код, и вы должны найти код для него. Эта пользовательская функция удаляет все символы, которые не помещаются между 0-9, a-z и A-Z.

Select * from Staging.APARMRE1 ar
where udf_parsealpha(ar.last_name) <> ar.last_name

Это должно вернуть любые записи, которые имеют last_name с недопустимыми символами для вас...хотя ваш вопрос бонусных очков-это немного более сложная задача, но я думаю, что заявление по делу может справиться с этим. Это немного псевдо код, я не совсем уверен, что это сработает.

Select id, case when udf_parsealpha(ar.last_name) <> ar.last_name then 'last name'
when udf_parsealpha(ar.first_name) <> ar.first_name then 'first name'
when udf_parsealpha(ar.Address1) <> ar.last_name then 'Address1'
end, 
case when udf_parsealpha(ar.last_name) <> ar.last_name then ar.last_name
when udf_parsealpha(ar.first_name) <> ar.first_name then ar.first_name
when udf_parsealpha(ar.Address1) <> ar.last_name then ar.Address1
end
from Staging.APARMRE1 ar
where udf_parsealpha(ar.last_name) <> ar.last_name or
udf_parsealpha(ar.first_name) <> ar.first_name or
udf_parsealpha(ar.Address1) <> ar.last_name 

Я написал это в почтовом ящике форума...поэтому я не совсем уверен, что это будет работать так, как есть, но это должно быть близко. Я не совсем уверен, как он будет вести себя, если одна запись имеет два поля с недопустимыми символами.

в качестве альтернативы вы должны иметь возможность изменить предложение from из одной таблицы и в подзапрос, который выглядит примерно так:

select id,fieldname,value from (
Select id,'last_name' as 'fieldname', last_name as 'value'
from Staging.APARMRE1 ar
Union
Select id,'first_name' as 'fieldname', first_name as 'value'
from Staging.APARMRE1 ar
---(and repeat unions for each field)
)
where udf_parsealpha(value) <> value

преимущество здесь для каждого столбца вы будете нужно только расширить оператор union здесь, в то время как вам нужно поставить этот comparisson три раза для каждого столбца в версии оператора case этого скрипта

вот функцию я построил для detectc колонн с расширенной обозначения на клавишах символов ASCII. Это быстро, и вы можете расширить набор символов, который вы хотите проверить. Второй параметр позволяет переключаться между проверкой чего-либо вне стандартного набора символов или разрешением расширенного набора:

create function [dbo].[udf_ContainsNonASCIIChars]
(
@string nvarchar(4000),
@checkExtendedCharset bit
)
returns bit
as
begin

    declare @pos int = 0;
    declare @char varchar(1);
    declare @return bit = 0;

    while @pos < len(@string)
    begin
        select @char = substring(@string, @pos, 1)
        if ascii(@char) < 32 or ascii(@char) > 126 
            begin
                if @checkExtendedCharset = 1
                    begin
                        if ascii(@char) not in (9,124,130,138,142,146,150,154,158,160,170,176,180,181,183,184,185,186,192,193,194,195,196,197,199,200,201,202,203,204,205,206,207,209,210,211,212,213,214,216,217,218,219,220,221,223,224,225,226,227,228,229,230,231,232,233,234,235,236,237,238,239,240,241,242,243,244,245,246,248,249,250,251,252,253,254,255)
                            begin
                                select @return = 1;
                                select @pos = (len(@string) + 1)
                            end
                        else
                            begin
                                select @pos = @pos + 1
                            end
                    end
                else
                    begin
                        select @return = 1;
                        select @pos = (len(@string) + 1)    
                    end
            end
        else
            begin
                select @pos = @pos + 1
            end
    end

    return @return;

end

использование:

select Address1 
from PropertyFile_English
where udf_ContainsNonASCIIChars(Address1, 1) = 1

найти, какое поле имеет недопустимые символы:

SELECT * FROM Staging.APARMRE1 FOR XML AUTO, TYPE

Вы можете проверить это с помощью этого запроса:

SELECT top 1 'char 31: '+char(31)+' (hex 0x1F)' field
from sysobjects
FOR XML AUTO, TYPE

результат будет такой:

Msg 6841, Уровень 16, состояние 1, строка 3 для XML не удалось сериализовать данные для узла "поле", поскольку он содержит символ (0x001F), который не допускается в XML. Чтобы получить эти данные с помощью for XML, преобразуйте их для двоичного, varbinary или image типа данных и использовать двоичный BASE64 директива.

это очень полезно, когда вы пишете xml-файлы и получаете ошибку недопустимых символов при ее проверке.