Преобразование изображений Jpeg в Bmp - некоторые изображения выходят синими

причина, по которой ваш файл синий, потому что кодировка BGR isntead RGB.
Если вы измените jpeg.pas исходный файл и используйте замену пикселей (удалить {.$IFDEF JPEGSO} на TJPEGImage.GetBitmap) вы увидите ваш образец файла правильно коричневый.

Итак, я думаю, суть в том, что источник JPEG не обнаруживает правильную (обратную) кодировку; вероятно, в jc.d.out_color_space...

обновление:
Исходный файл C (и jpeg.pas) должен объявить (и использовать) цвет Пробелы с новыми расширениями JCS_EXT_...:

enum J_COLOR_SPACE {
  JCS_UNKNOWN, JCS_GRAYSCALE, JCS_RGB, JCS_YCbCr,
  JCS_CMYK, JCS_YCCK, JCS_EXT_RGB, JCS_EXT_RGBX,
  JCS_EXT_BGR, JCS_EXT_BGRX, JCS_EXT_XBGR, JCS_EXT_XRGB
}

обновление 2:
jpeg.pas можно найти (XE) в C:...\RAD Studio.0\source\vcl с файлами C в jpg папку.

если вы готовы поспорить, что все файлы Adobe с цветовым пространством RGB должны иметь свои биты, вы можете легко взломать jpeg.пас источника для выявления ваших специальных файлов и conditionnally обмена, упомянутых выше в TJPEGImage.GetBitmap

{.$IFDEF JPEGSO}
          if (jc.c.in_color_space=JCS_RGB)and
            (smallint(jc.c.jpeg_color_space)=Ord(JCS_UNKNOWN))and   //comes 1072693248 = FF00000 = 111111111100000000000000000000
            jc.d.saw_Adobe_marker  and
            (PixelFormat = jf24bit) then
          begin

WIC (доступно для XP и выше) может обрабатывать это изображение. Этот компонент хорошо упакован в Delphi 2010 и выше. Для более ранних версий Delphi достаточно легко вызвать WIC с помощью COM-интерфейсов.

вот мое доказательство кода концепции:

var
  Image: TWICImage;
  Bitmap: TBitmap;
begin
  Image := TWICImage.Create;
  Image.LoadFromFile('C:\desktop\ABrownImage.jpg');
  Bitmap := TBitmap.Create;
  Bitmap.Assign(Image);
  Bitmap.SaveToFile('C:\desktop\ABrownImage.bmp');
end;

Примечание 1: WIC поставляется с Vista, но должен быть перераспределен для XP. Один очевидный вариант - использовать WIC, если он доступен, но вернуться к декодеру Delphi JPEG иначе.

примечание 2.: Я не могу найти повторно распространяемый пакет для WIC. Я подозреваю, что для этого может потребоваться загрузка конечного пользователя для XP. Тем не менее, я бы не удивился, если бы подавляющее большинство машин XP уже установили его.

в ответ на ваш другой вопрос, вот код для загрузки файла JPG в растровое изображение и условно применить исправление к полученному растровому изображению. Обратите внимание, что это работает для вашего коричневого.JPG, но я понятия не имею, что в этих первых 18 байтах, поэтому я понятия не имею, будет ли это работать в долгосрочной перспективе или нет. Я лично предпочел бы использовать готовую, известную для работы, широко используемую библиотеку. Кроме того я хотел использовать идею Давида через WIC если доступен и возвращаясь к этому стилю хаков если нет.

здесь полное код блока, поэтому вы можете увидеть все используемые блоки. Форма ожидает только одно TImage имени Image1 на форме, чтобы вы могли создать свою форму, сначала поместите TImage там, затем переключитесь на представление исходного кода и скопируйте мой код поверх кода, созданного Delphi.

как работает код:

код открывает файл с изображением JPG и загружает его в TJpgImage. Затем он сравнивает первые 18 байт файл маркера. Если есть совпадение, оно применяет преобразование к каждому пикселю созданного растрового изображения. Поскольку запись фактических констант маркера затруднена, существует процедура (CopyConstToClipboard), которая берет байты из файла, преобразует их в константу в стиле Delphi и копирует ее в буфер обмена. Когда вы найдете новый файл, который не работает, вы должны использовать эту процедуру для подготовки новой константы.

код:

unit Unit9;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, Jpeg, Clipbrd;

type
  TForm9 = class(TForm)
    Image1: TImage;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form9: TForm9;

implementation

{$R *.dfm}

type
  TRGB_Pixel = packed record
    B1: Byte;
    B2: Byte;
    B3: Byte;
  end;
  TScanLine = array[0..(System.MaxInt div SizeOf(TRGB_Pixel))-1] of TRGB_Pixel;
  PScanLine = ^TScanLine;

procedure CopyConstToClipboard(const FB:array of byte);
var s: string;
    i: Integer;
begin
  s := 'Name: array[0..' + IntToStr(High(FB)) + '] of Byte = ($' + IntToHex(FB[0], 2);
  for i:=1 to High(FB) do
    s := s + ', $' + IntToHex(FB[i],2);
  s := s + ');';
  Clipboard.AsText := s;
end;

function LoadJpegIntoBitmap(const FileName:string): TBitmap;
var F: TFileStream;
    Jpg: TJPEGImage;
    FirstBytes:array[0..17] of Byte;
    y,x: Integer;
    ScanLine: PScanLine;
const Marker_1: array[0..17] of Byte = ($FF, $D8, $FF, $EE, , E, , , F, , , , , , , , , );

  procedure SwapBytes(var A, B: Byte);
  var T: Byte;
  begin
    T := A;
    A := B;
    B := T;
  end;

begin
  F := TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite);
  try
    Jpg := TJPEGImage.Create;
    try
      Jpg.LoadFromStream(F);
      F.Position := 0;
      F.Read(FirstBytes, SizeOf(FirstBytes));

      // CopyConstToClipboard(FirstBytes); // Uncomment this to copy those first bytes to cliboard

      Result := TBitmap.Create;
      Result.Assign(Jpg);

      if (Result.PixelFormat = pf24bit) and CompareMem(@Marker_1, @FirstBytes, SizeOf(FirstBytes)) then
      begin
        for y:=0 to Result.Height-1 do
        begin
          ScanLine := Result.ScanLine[y];
          for x:=0 to Result.Width-1 do
          begin
            SwapBytes(ScanLine[x].B1, ScanLine[x].B3);
          end;
        end;
      end;

    finally Jpg.Free;
    end;
  finally F.Free;
  end;
end;

procedure TForm9.FormCreate(Sender: TObject);
var B: TBitmap;
begin
  B := LoadJpegIntoBitmap('C:\Users\Cosmin Prund\Downloads\ABrownImage.jpg');
  try
    Image1.Picture.Assign(B);
  finally B.Free;
  end;
end;

end.