Пролог GNU - оператор Univ? Объяснение

Итак, оператор univ. Я не совсем понимаю.

например это:

foo(PredList,[H|_]) :- bar(PredList,H).
foo(PredList,[_|T]) :- foo(PredList,T),!.

bar([H|_],Item) :- G =.. [H,Item],G.
bar([_|T],Item) :- bar(T,Item).

что это делаешь? Это похоже на то, чтобы увидеть, является ли другой предикат истинным. Я не понимаю, что за ".." делает.

Как бы вы переписали это без оператора univ?

13
backtracking meta-predicate operator-keyword prolog

2 ответов

Univ (=..) разбивает термин на список составляющих или создает термин из такого списка. Попробуйте:

?- f(x,y) =.. L.
L = [f, x, y].

?- f(x,y,z) =.. [f|Args].
Args = [x, y, z].

?- Term =.. [g,x,y].
Term = g(x, y).

bar кажется, вызывает каждый предикат в PredList on Item С foo откат за Items. (Использование переменной в качестве предиката не является переносимым;call предикат должен быть предпочтительным.)

редактировать: Каарел прав, univ можно заменить на functor/3 и arg/3 следующим образом:

bar([H|_],Item) :-
    functor(Goal,H,1),   % unifies Goal with H(_)
    arg(1,Goal,Item),    % unifies first argument of Goal with Item
    call(Goal).          % use this for portability
15

наиболее подходящей переписью на мой взгляд было бы:

 bar( [H|_], Item ) :- call(H, Item).

call/n еще не частью ядра стандарта ISO, но они могут стать в ближайшем будущем (*). Многие системы Prolog уже поддерживают их.

есть одна причина, почему call/n следует предпочесть простой (=..)/2 и functor/3 + arg/3 решений. The call/n решение способно для того чтобы отрегулировать закрытие (**).

простые (=..)/2 и functor/3 + arg/3 решение можно вызвать bar/2 только с атомами в первом списке аргументов. Например:

 p1(1).
 p2(2).
 ?- bar( [p1, p2], 1 ).
 Yes
 ?- bar( [p1, p2], 2 ).
 Yes
 ?- bar( [p1, p2], 3 ).
 No

с замыканиями мы не ограничены атомами, и мы могли бы сэкономить некоторые усилия кодирования. Например, мы можем сделать следующее непосредственно:

 ?- bar( [=(1), =(2)], 1 ).
 Yes
 ?- bar( [=(1), =(2)], 2 ).
 Yes
 ?- bar( [=(1), =(2)], 3 ).
 No

С Наилучшими Пожеланиями

(*)
Проект Технического Исправления 2
http://www.complang.tuwien.ac.at/ulrich/iso-prolog/dtc2#call

(**)
Кто Его Изобрел?: call/n Predicates
http://www.complang.tuwien.ac.at/ulrich/Prolog-inedit/naish.html

2