Просмотр вывода операторов "print" с помощью ADOConnection в Delphi

некоторые из моих хранимых процедур MS SQL создают сообщения с помощью команды "печать". В моем приложении Delphi 2007, которое подключается к MS SQL с помощью TADOConnection, как я могу просмотреть выходные данные этих команд "печать"?

ключевые требования: 1) я не могу запустить запрос более одного раза; это может быть обновление вещей. 2) мне нужно увидеть результаты печати даже если наборы данных не возвращаются.

10
ado delphi sql-server stored-procedures

4 ответов

Это было интересно...
событие OnInfoMessage из ADOConnection работает, но дьявол в деталях!

основные моменты:
используйте CursorLocation = clUseServer вместо clUseClient по умолчанию.
используйте Open, а не ExecProc с вашим ADOStoredProc.
используйте NextRecordset из текущего, чтобы получить следующее, но не забудьте проверить, что у вас есть один открытый.
используйте SET NOCOUNT = ON в хранимой процедуре.

сторона SQL: хранимая процедура

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
IF  EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[FG_TEST]') AND type in (N'P', N'PC'))
  DROP PROCEDURE [dbo].[FG_TEST]
GO
-- =============================================
-- Author:      François
-- Description: test multi ADO with info
-- =============================================
CREATE PROCEDURE FG_TEST
AS
BEGIN
    -- SET NOCOUNT ON absolutely NEEDED
    SET NOCOUNT ON;

    PRINT '*** start ***'

    SELECT 'one' as Set1Field1

    PRINT '*** done once ***'

    SELECT 'two' as Set2Field2

    PRINT '*** done again ***'

    SELECT 'three' as Set3Field3

    PRINT '***finish ***'
END
GO

Delphi сторона:
Создайте новое приложение VCL Forms.
Поместите памятку и кнопку в форму.

скопируйте следующий текст, измените каталог и источник данных и вставьте его в форму 

object ADOConnection1: TADOConnection
  ConnectionString = 
    'Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security In' +
    'fo=False;Initial Catalog=xxxYOURxxxDBxxx;Data Source=xxxYOURxxxSERVERxxx'
  CursorLocation = clUseServer
  LoginPrompt = False
  Provider = 'SQLOLEDB.1'
  OnInfoMessage = ADOConnection1InfoMessage
  Left = 24
  Top = 216
end
object ADOStoredProc1: TADOStoredProc
  Connection = ADOConnection1
  CursorLocation = clUseServer
  ProcedureName = 'FG_TEST;1'
  Parameters = <>
  Left = 24
  Top = 264
end

в OnInfoMessage ADOConnection поставить

Memo1.Lines.Add(Error.Description);

для ButtonClick, вставьте этот код

procedure TForm1.Button1Click(Sender: TObject);
const
  adStateOpen = 000001; // or defined in ADOInt
var
  I: Integer;
  ARecordSet: _Recordset;
begin
  Memo1.Lines.Add('==========================');

  ADOStoredProc1.Open; // not ExecProc !!!!!

  ARecordSet := ADOStoredProc1.Recordset;
  while Assigned(ARecordSet) do
  begin
    // do whatever with current RecordSet
    while not ADOStoredProc1.Eof do
    begin
      Memo1.Lines.Add(ADOStoredProc1.Fields[0].FieldName + ': ' + ADOStoredProc1.Fields[0].Value);
      ADOStoredProc1.Next;
    end;
    // switch to subsequent RecordSet if any
    ARecordSet := ADOStoredProc1.NextRecordset(I);
    if Assigned(ARecordSet) and ((ARecordSet.State and adStateOpen) <> 0) then
      ADOStoredProc1.Recordset := ARecordSet
    else
      Break;
  end;

  ADOStoredProc1.Close;
end;
9

в .классы сети связь существует событие InfoMessage. В обработчике для этого события вы можете получить InfoMessage (операторы печати) из args события.

Я считаю, что у Delphi есть аналогичное событие под названием "OnInfoMessage", которое поможет вам.

3

Я не думаю, что это возможно. Вы можете использовать временную таблицу для сброса инструкций печати и возврата ее вместе с результатами.

1

некоторые улучшения в коде Франсуа (как проверено с DXE2) для обслуживания нескольких операторов печати и результатов из переменного числа выбранных. Изменения неуловимы.

procedure TForm1.ADOConnection1InfoMessage(Connection: TADOConnection;
  const Error: Error; var EventStatus: TEventStatus);
var
  i: integer;
begin
  // show ALL print statements
  for i := 0 to AdoConnection1.Errors.Count - 1 do
  begin
    // was: cxMemo1.Lines.Add(Error.Description);
    cxMemo1.Lines.Add(
      ADOConnection1.Errors.Item[i].Description);
  end;
end;

procedure TForm1.cxButton1Click(Sender: TObject);
const
  adStateOpen = 000001; // or uses ADOInt
var
  records: Integer;
  ARecordSet: _RecordSet;
begin
  cxMemo1.Lines.Add('==========================');

  ADOStoredProc1.Open;

  try
    ARecordSet := ADOStoredProc1.RecordSet; // initial fetch
    while Assigned(ARecordSet) do
    begin
      // assign the recordset to a DataSets recordset to traverse
      AdoDataSet1.Recordset := ARecordSet;
      // do whatever with current ARecordSet
      while not ADODataSet1.eof do
      begin
        cxMemo1.Lines.Add(ADODataSet1.Fields[0].FieldName + 
          ': ' + ADODataSet1.Fields[0].Value);
        AdoDataSet1.Next;
      end;
      // fetch next recordset if there is one
      ARecordSet := ADOStoredProc1.NextRecordSet(records);
      if Assigned(ARecordSet) and ((ARecordSet.State and adStateOpen) <> 0) then
        ADOStoredProc1.Recordset := ARecordSet
      else
        Break;
    end;
  finally
    ADOStoredProc1.Close;
  end;

end;
0