Проверить тип узла в шаблоне XSL

можно ли проверить тип узла, который я сопоставил с шаблоном внутри того же шаблона? Если да, то как я могу это сделать? Например, я хотел бы сделать что-то вроде этого:

<xsl:template match="@*|node()">
    <xsl:choose>
        <xsl:when test="current() is an attribute">
        <!-- ... -->
        </xsl:when>
        <xsl:when test="current() is an element">
        <!-- ... -->
        </xsl:when>
        <xsl:otherwise>
        <!-- ... -->
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
6
xpath-1.0 xslt

3 ответов

взгляните на этот ответ здесь, так как это должно дать вам необходимую информацию:

разница между: child:: node() и child::*

Это дает следующее язык xsl:выбрать для проверки всех узлов, включая узел документа.

<xsl:choose>
  <xsl:when test="count(.|/)=1">
    <xsl:text>Root</xsl:text>
  </xsl:when>
  <xsl:when test="self::*">
    <xsl:text>Element </xsl:text>
    <xsl:value-of select="name()"/>
  </xsl:when>
  <xsl:when test="self::text()">
    <xsl:text>Text</xsl:text>
  </xsl:when>
  <xsl:when test="self::comment()">
    <xsl:text>Comment</xsl:text>
  </xsl:when>
  <xsl:when test="self::processing-instruction()">
    <xsl:text>PI</xsl:text>
  </xsl:when>
  <xsl:when test="count(.|../@*)=count(../@*)">
    <xsl:text>Attribute</xsl:text>
  </xsl:when>
</xsl:choose>
17

более точный способ определить, если узел $node is a корневой узел:

not(count($node/ancestor::node()))

выражение в ответе TimC проверяет тип текущего узла:

count(.|/)=1

но не применяется в случае, когда мы хотим определить тип узла в переменной, которая может принадлежать другому документу, а не текущему документу.

кроме того, тест для узла пространства имен:

count($node | $node/../namespace::*) = count($node/../namespace::*)
6

Я настоятельно рекомендую вам использовать выражения для типов последовательностей, введенные в XPath 2.0. Например:

. instance of document-node()
. instance of element()
4