QML TableView с динамическим числом столбцов

я пытался использовать QML TableView показать QAbstractTableModel. Недостающая часть уравнения, по-видимому, заключается в том, что невозможно иметь переменное количество столбцов в TableView, несмотря на переопределение QAbstractItemModel::roleNames который должен сообщить Qt количество и имя моих столбцов. Я попытался протестировать это, используя только QML:

import QtQuick 2.0
import QtQuick.Controls 1.1

Rectangle {
    anchors.fill: parent
    property real showImage: 1.0
    width: 500
    TableView {
        id: myTable
        model: myModel
        //        TableViewColumn {
        //            role: "title"; title: "Name"; width: 200
        //        }
    }

    ListModel {
        id: myModel
        ListElement {
            title: "item one"
        }
        ListElement {
            title: "item two"
        }
    }
}

при запуске это ничего не показывает, несмотря на , содержащее ListElementС ролями, определенными в их.

однако, если приведенный выше код не раскомментирован и TableViewColumn определяется, то столбец будет отображать данные для этой роли, как ожидалось, но таблица по-прежнему не будет отображать любые другие роли. Очевидно, что это будет работать только для статически определенного количества столбцов, а не для моего случая, когда количество столбцов неизвестно до времени выполнения.

приведенный пример в основном совпадает с моим примером реальной жизни, за исключением того, что моя модель определена в C++.

это кажется, что это, возможно, уже было задано здесь но он не получил никакого ответа.

EDIT: я попытался вызвать функцию javascript:

function addColumnToTable(roleName) {
    var columnString = 'import QtQuick 2.3; import QtQuick.Controls 1.2; TableViewColumn {role: "'
            + roleName + '"; title: "' + roleName + '"; width: 40}';
    var column = Qt.createQmlObject(
                columnString
                , myTable
                , "dynamicSnippet1")
    myTable.addColumn(column);
}

Из C++:

QVariant roleName = "name";
QObject *root = view->rootObject();
QMetaObject::invokeMethod(root, "addColumnToTable", Q_ARG(QVariant, roleName));

это, по крайней мере, позволило мне динамически добавлять столбцы из C++, хотя и не из архитектуры модели/представления. Решение Йоанна намного лучше, чем это.

8
c++ qml qt qtquick2

2 ответов

вы можете создать динамически столько TableViewColumn как вам нужно, с помощью resources свойства TableView.

вам нужно будет добавить метод в свой пользовательский класс модели, который даст вам имена роли, которые вы хотите отобразить.

QML:

Component
{
    id: columnComponent
    TableViewColumn{width: 100 }
}

TableView {
    id: view
    anchors.fill: parent
    resources:
    {
        var roleList = myModel.customRoleNames
        var temp = []
        for(var i=0; i<roleList.length; i++)
        {
            var role  = roleList[i]
            temp.push(columnComponent.createObject(view, { "role": role, "title": role}))
        }
        return temp
    }

    model: myModel

MyModel.h:

class MyModel: public QAbstractListModel
{
    Q_OBJECT
    Q_PROPERTY(QStringList userRoleNames READ userRoleNames CONSTANT)

public:
    explicit MyModel(QObject *parent = 0);

    enum MyModelRoles {
        UserRole1 = Qt::UserRole + 1,
        UserRole2,
        ...
    };

    QStringList userRoleNames();
    int rowCount(const QModelIndex & parent = QModelIndex()) const;
    QVariant data(const QModelIndex & index, int role = Qt::DisplayRole) const;
    ...

private:
    QHash<int, QByteArray> roleNames() const;
    ...

};

MyModel.cpp:

...
...

QHash<int, QByteArray> MyModel::roleNames() const {
    QHash<int, QByteArray> roles = QAbstractListModel::roleNames ();
    roles[UserRole1] = "whatever";
    roles[UserRole2] = "youwant";
    return roles;
}

QStringList MyModel::userRoleNames() // Return ordered List of user-defined roles
{
    QMap<int, QString> res;
    QHashIterator<int, QByteArray> i(roleNames());
    while (i.hasNext()) {
        i.next();
        if(i.key() > Qt::UserRole)
            res[i.key()] = i.value();
    }
    return res.values();
}

...
...
11

решение с ресурсами не работает для меня (Qt 5.6). TableView не обновляется.

это работает для меня:

Component{
    id: columnComponent
    TableViewColumn{width: 30 }
}

TableView {
    id: tableView
    model: listModel
    property var titles: somethingDynamic
    property var curTitles: {
        var t=[]
        for(var i=0;i<columnCount;i++){
            t.push(getColumn(i).title)
        }
        return t
    }
    onTitlesChanged:{
        for(var i=0;i<titles.length;i++){
            if(curTitles.indexOf(titles[i])==-1){
                var column = addColumn(columnComponent) 
                column.title=titles[i]
                column.role=titles[i]                   
            }
        }
        for(var i=curTitles.length-1;i>=0;i--){
            if(titles.indexOf(curTitles[i])==-1){
                removeColumn(i)
            }
        }
    }
}

}

Он также правильно обновляет столбцы с перетаскиванием.

1